STEP 7 V5.0. Программирование
Подождите немного. Документ загружается.
Создание исходных файлов на AWL
Программирование с помощью STEP 7 версии 5.0
11-18 C79000-G7076-C562-02
VAR_OUT // Выходная переменная
OUTPUT1: STRUCT // OUTPUT1 имеет тип данных STRUCT
var1 : BOOL; // 1-й элемент структуры
var2 : DWORD; // 2-й элемент структуры
END_STRUCT; // Конец структуры
END_VAR
11.6.2 Пример организационных блоков в исходных файлах на AWL
ORGANIZATION_BLOCK OB1
TITLE = Пример ОВ1 с различными вызовами блоков
//Три сегмента иллюстрируют вызовы блоков
//с параметрами и без параметров
{S7_m_c := 'true'} //Системный атрибут для блоков
AUTHOR Siemens
FAMILY Пример
NAME Test_OB
VERSION 1.1
VAR_TEMP
Interim value : INT; // Промежуточное значение, буфер
END_VAR
BEGIN
NETWORK
TITLE = Вызов функции с передачей параметров
// Передача параметров в одной строке
CALL FC1 (param1 :=I0.0,param2 :=I0.1);
NETWORK
TITLE = Вызов функционального блока
// с передачей параметров
// Передача параметров в более чем одной строке
CALL Traffic light control , DB6 ( // Имя FB (Управление светофором), экземплярный
// блок данных
dur_g_p := S5T#10S, // Присваивание фактических значений параметрам
del_r_p := S5T#30S,
starter := TRUE,
t_dur_y_car := T 2,
t_dur_g_ped := T 3,
t_delay_y_car := T 4,
Создание исходных файлов на AWL
Программирование с помощью STEP 7 версии 5.0
C79000-G7076-C562-02
11-19
t_dur_r_car := T 5,
t_next_red_car := T 6,
r_car := "re_main", // Кавычки показывают символические
y_car := "ye_main", // имена, введенные в таблице символов
g_car := "gr_main",
r_ped := "re_int",
g_ped := "gr_int");
NETWORK
TITLE = Вызов функционального блока
// с передачей параметров
// Передача параметров в одной строке
CALL FB10, DB100 (para1 :=I0.0,para2 :=I0.1);
END_ORGANIZATION_BLOCK
11.6.3 Пример функций в исходных файлах на AWL
FUNCTION FC1: VOID
// Только должна быть вызвана
VAR_INPUT
param1 : bool;
param2 : bool;
END_VAR
begin
end_function
FUNCTION FC2 : INT
TITLE = Увеличение количества деталей
// Пока передаваемое значение < 1000, эта функция
// увеличивает передаваемое значение. Если число деталей
// превышает 1000, через возвращаемое значение для функции
// (RET_VAL) возвращается "-1".
Создание исходных файлов на AWL
Программирование с помощью STEP 7 версии 5.0
11-20 C79000-G7076-C562-02
AUTHOR Siemens
FAMILY Контроль производительности
NAME : INCR_ITEM_NOS
VERSION : 1.0
VAR_IN_OUT
ITEM_NOS : INT; // Текущее количество изготовленных деталей
END_VAR
BEGIN
NETWORK
TITLE = Увеличение количества деталей на 1
// Пока текущее количество предметов меньше 1000,
// счетчик может быть увеличен на 1
L ITEM_NOS; L 1000; // Пример более одного
> I; JC ERR; // оператора в строке.
L 0; T RET_VAL;
L ITEM_NOS; INC 1; T ITEM_NOS; BEU;
ERR: L -1;
T RET_VAL;
END_FUNCTION
FUNCTION FC3 {S7_m_c := 'true'} : INT
TITLE = Увеличение количества деталей
// Пока передаваемое количество < 1000, эта функция
//увеличивает передаваемое значение. Если количество деталей
//превышает 1000, через возвращаемое значение для функции
// (RET_VAL) возвращается "-1".
//
//RET_VAL здесь имеет системный атрибут для параметров
AUTHOR : Siemens
FAMILY : Контроль производительности
NAME : INCR_ITEM_NOS
VERSION : 1.0
VAR_IN_OUT
ITEM_NOS {S7_visible := 'true'}: INT; // Текущее количество произведенных деталей
//Системные атрибуты для параметров
Создание исходных файлов на AWL
Программирование с помощью STEP 7 версии 5.0
C79000-G7076-C562-02
11-21
END_VAR
BEGIN
NETWORK
TITLE = Увеличение количества деталей на 1
// Пока текущее количество деталей меньше 1000,
// счетчик может быть увеличен на 1
L ITEM_NOS; L 1000; // Пример более чем одного
> I; JC ERR; // оператора в строке.
L 0; T RET_VAL;
L ITEM_NOS; INC 1; T ITEM_NOS; BEU;
ERR: L -1;
T RET_VAL;
END_FUNCTION
11.6.4 Пример функциональных блоков в исходных файлах на AWL
FUNCTION_BLOCK FB6
TITLE = Простое переключение светофора
// Управление светофором на пешеходном переходе
// на главной улице
{S7_m_c := 'true'} //Системный атрибут для блоков
AUTHOR : Siemens
FAMILY : Светофор
NAME : Светофор01
VERSION : 1.3
VAR_INPUT
starter : BOOL := FALSE; // Запрос на переход от пешехода
t_dur_y_car : TIMER; // Длительность зеленого для пешеходов
t_next_r_car : TIMER; // Интервал между красными фазами для автомобилей
t_dur_r_car : TIMER;
END_VAR
VAR_OUTPUT
Создание исходных файлов на AWL
Программирование с помощью STEP 7 версии 5.0
11-22 C79000-G7076-C562-02
g_car : BOOL := FALSE; // ЗЕЛЕНЫЙ для автомобилей
number {S7_server := 'alarm_archiv'; S7_a_type := 'alarm_8'} :DWORD;
// Количество автомобилей
// number имеет системные атрибуты для параметров
END_VAR
VAR
condition : BOOL := FALSE; // Условие красного для автомобилей
END_VAR
BEGIN
NETWORK
TITLE = Условие красного для движения по главной улице
// По истечении минимального интервала, запрос на зеленый свет на
// пешеходном переходе образует условие включения красного сигнала
// для движения по главной улице
A(;
A #starter; // Запрос на зеленый на пешеходном переходе и
A #t_next_r_car; // время между красными фазами превышено
O #condition; // или условие для красного
);
AN #t_dur_y_car; // И в настоящее время свет не красный
= #condition; // Условие для красного
NETWORK
TITLE = Зеленый свет для движения по главной улице
AN #condition; // Нет условия для красного для движения по главной
// улице
= #g_car; // ЗЕЛЕНЫЙ для движения по главной улице
NETWORK
TITLE = Длительность желтой фазы для автомобилей
// Дополнительная программа, необходимая для управления
// светофорами
END_FUNCTION_BLOCK
FUNCTION_BLOCK FB10
VAR_INPUT
para1 : bool;
para2: bool;
end_var
begin
Создание исходных файлов на AWL
Программирование с помощью STEP 7 версии 5.0
C79000-G7076-C562-02
11-23
end_function_block
data_block db10
FB10
begin
end_data_block
data_block db6
FB6
begin
end_data_block
11.6.5 Пример блоков данных в исходных файлах на AWL
Блок данных:
DATA_BLOCK DB10
TITLE = DB Пример 10
STRUCT
aa : BOOL; // Переменная aa типа BOOL
bb : INT; // Переменная bb типа INT
cc : WORD;
END_STRUCT;
BEGIN // Присваивание начальных значений
aa := TRUE;
bb := 1500;
END_DATA_BLOCK
Создание исходных файлов на AWL
Программирование с помощью STEP 7 версии 5.0
11-24 C79000-G7076-C562-02
Блок данных с соответствующим типом данных, определенным
пользователем:
DATA_BLOCK DB20
TITLE = DB (UDT) Пример
UDT 20 // Соответствующий тип данных, определенный
// пользователем
BEGIN
start := TRUE; // Присваивание начальных значений
setp. := 10;
END_DATA_BLOCK
Замечание
Используемый UDT должен находиться в исходном файле до блока данных.
Блок данных с соответствующим функциональным блоком:
DATA_BLOCK DB30
TITLE = DB (FB) Пример
FB30 // Соответствующий функциональный блок
BEGIN
start := TRUE; // Присваивание начальных значений
setp. := 10;
END_DATA_BLOCK
Замечание
Соответствующий функциональный блок должен находиться в исходном
файле до блока данных.
11.6.6 Пример типов данных, определенных пользователем, в
исходных файлах на AWL
TYPE UDT20
STRUCT
start : BOOL; //Переменная типа BOOL
setp. : INT; // Переменная типа INT
value : WORD; // Переменная типа WORD
END_STRUCT;
END_TYPE
Создание исходных файлов на AWL
Программирование с помощью STEP 7 версии 5.0
C79000-G7076-C562-02
11-25
Программирование с помощью STEP 7 версии 5.0
C79000-G7076-C562-02
12-1
12 Обзор имеющихся в распоряжении
справочных данных
12.1 Обзор имеющихся в распоряжении справочных
данных
12.1.1 Обзор имеющихся в распоряжении справочных данных
Вы можете создавать и анализировать справочные данные, чтобы облегчить
отладку и модификацию своей пользовательской программы. Справочные
данные используются в следующих целях:
• Как обзор вашей пользовательской программы в целом
• Как основа для изменений и тестирования
• Как дополнение к вашей программной документации
Следующая таблица показывает, какую информацию вы можете извлечь из
отдельных видов справочных данных:
Вид Назначение
Список перекрестных ссылок Обзор адресов в областях памяти I, Q, M, P, T, C и DB,
используемых в программе пользователя.
Используя команду меню View > Cross References for Address
[Вид > Перекрестные ссылки для адресов]
, вы можете
отобразить все перекрестные ссылки, включая перекрывающийся
доступ к выбранным адресам.
Список назначений для входов,
выходов и меркеров (I,Q,M)
Список назначений для
таймеров и счетчиков (T/C)
Обзор того, какие биты адресов в областях памяти I, Q и M и какие
таймеры и счетчики (T и C) уже заняты в программе пользователя;
образует важную основу для поиска ошибок или изменений в
программе пользователя
Структура программы
Иерархия вызовов блоков внутри программы пользователя и
обзор используемых блоков и их уровней вложенности
Неиспользуемые символы
Обзор всех символов, определенных в таблице символов, но не
использованных в разделах программы пользователя, для
которых доступны справочные данные
Адреса, не имеющие символов Обзор всех абсолютных адресов, которые используются в
разделах программы пользователя, для которых доступны
справочные данные, но для которых не были определены
символы в таблице символов
Справочные данные для выбранной программы пользователя включают в
себя все списки, перечисленные в таблице. Имеется возможность создавать