Руководство по программированию, создание блоков для PCS 7 SIMATIC
Подождите немного. Документ загружается.
Руководство по программированию, создание блоков для PCS 7
A5E00122559-01
1-23
1.4 Временные зависимости
Если Ваш блок выполняется по временному прерыванию в режиме реального
времен и и при этом для выполнения операций с временной зависимостью
необхо димо рассчитывать периоды времени (например, блоки контроллеров),
то должен быть определен параметр ввода (например, SAMPLE_T) типа
REAL, в который будет записываться длина временного интервала.
В зависимости от циклического прерывания OB, в котором вызыва ется Ваш
блок этим па раметрам будут присваиваться новые значения. Это
гарантирует, что алгоритм Вашего блока всегда будет исполняться с
правильным временем.
Если Вы определите для этого параметра системный атрибут
S7_sampletime, и установите его в значение 'true [истина]', то CFC
автоматически установит значение, соответствующее вызывающему OB.
Также учитывается скорость сканирования. Вы также должны определить для
параметра системные атрибуты
S7_visible и S7_link и установить для ни х
значение 'false [ложь]'. Тогда параметр будет невидим и для него нельзя
будет установить соединение в схеме CFC, что позволит предотвратить
случайное из менение значения пользователем.
Однако автоматичес кое присвоение значений параметру функциями схемы
CFC будет осуществляться только если при компиляции программы была
активизирована флаговая кнопка "Update sampling time [Обновить время
выборки]".
Руководство по программированию, создание бл оков дл я PCS 7
1-24 A5E00122559-01
В следующей части блока-примера приведена реализация операции с
временной зависимостью. С помощью параметра SUPPTIME в блоке может
быть определено время ожидания. Изменение значения на входе SUPP_IN
через заданное время ожидания передается на выход SUPP_OUT.
/***************************************************************************************
// Область объявлений: параметры блока
//**************************************************************************************
VAR_INPUT
SAMPLE_T {S7_sampletime:= 'true' // Временной парам. выборки для блока (=цикл задачи)
S7_visible:='false'; // параметр невидим
S7_link:= 'false' // параметр нельзя связать
} :REAL := 1; // время выборки [сек] (по умолчанию 1 секунда)
....
END_VAR
//**************************************************************************************
// Область объявлений: статические переменные
//**************************************************************************************
VAR
....
sSUPP_IN :REAL := 0; // старое значение ввода задержки выборки
ACT_TIME :REAL := 0; // счетчик времени
....
END_VAR
VAR_OUTPUT
....
SUPP_OUT :REAL := 0; // выходное значение для задержки выборки
....
END_VAR
//**********************************************************************************
// Технологическая область
//**********************************************************************************
IF (SUPP_IN <> sSUPP_IN) THEN
ACT_TIME := SUPPTIME; // Счетчик времени инициализации
sSUPP_IN := SUPP_IN;
END_IF;
IF (ACT_TIME > 0) THEN // Если время ожидания еще не закончилось
ACT_TIME := ACT_TIME-SAMPLE_T; // Уменьшить время ожидания
ELSE
SUPP_OUT := SUPP_IN; // Соединить вход с выходом
END_IF;
....
Руководство по программированию, создание блоков для PCS 7
A5E00122559-01
1-25
1.5 Асинхронный запуск и обработка блоков OB
ошибок
Если происходит асинхронное событие, такое как горячая перезагрузка,
вставка/удаление модуля, сбой корзины или похожие события, то ПЛК
вызывает асинхронный OB. Если Вы хотите, чтобы Ваш блок реагировал на
такие события, то Вы должны инсталлировать Ваш блок в соответствующем
OB и в теле блока проверять не произошло ли такое событие.
Инсталляция в асинхронном OB
Чтобы инсталлировать Ваш блок в определенном ОВ используйте систе мный
атрибут "S7_tasklist". В качестве зна чения этого атрибута Вы можете указать
все необходимые блоки OB (например, S7_tasklist := 'OB80,OB100'). При
вставке блока в схему CFC, CFC автоматически инсталлирует блок в текущий
OB циклических прерываний и во все OB, определенные в S7_tasklist.
Проверка вызыва ющих OB
Чтобы определить OB, в котором исполняется Ваш блок на данный момент,
Вы дол жны в алгоритме Вашего блока вызвать SFC6 (RD_SINFO). Она читает
загрузочную информацию Вашего блока и предоставляет информацию о
текущем активно м OB (параметр TOP_SI) и о пос леднем вызываемом OB
запуска (параметр START_UP_SI).
Два параметра имеют идентичную структуру и оба должны быть определены
в Ваших временных переменны х. Элементы структуры имеют следующие
значения:
Таблица 1-3: Параметры TOP_SI и START_UP_SI
Элемент
структуры
Тип данных Описание
EV_CLASS BYTE [БАЙТ] Биты с 0 по 3: ID события
Биты с 4 по 7: Класс события
EV_NUM BYTE [БАЙТ] Номер события
PRIORITY BYTE [БАЙТ] Номер класса приоритета
NUM BYTE [БАЙТ] Номер вызывающего OB
TYP2_3 BYTE [БАЙТ] ID данных для ZI2_3
TYP1 BYTE [БАЙТ] ID данных для ZI1
ZI1 WORD
[СЛОВО]
Дополнительная информация 1
ZI2_3 DWORD
[ДВОЙНОЕ
СЛОВО]
Дополнительная информация 2_3
Руководство по программированию, создание бл оков дл я PCS 7
1-26 A5E00122559-01
В пределах описания элементы структуры соответствуют временным
переменным вызывающего OB. Однако в зависимости от OB они могут иметь
различные имен а и типы данных. Это означает, что Вы должны присваивать
отдельные элементы структуры друг другу и обрабатывать их в соответствии
с описанием OB (см. "STEP 7 - System and Standard Functions manual
[Руководство по системным и стандартным функциям STEP 7]"). Это показано
в следую щей таблице и в фрагменте блока-примера на примере OB80
(ошибка времени).
Таблица 1-4: Назначение элементов информации о запуске TOP_SI
вре менным переменным OB80
TOP_SI / STARTUP_SI OB80
Элемент
структуры
Тип
данных
Временная переменная Тип
данных
EV_CLASS BYTE
[БАЙТ]
OB80_EV_CLASS BYTE
[БАЙТ]
EV_NUM BYTE
[БАЙТ]
OB80_FLT_ID BYTE
[БАЙТ]
PRIORITY BYTE
[БАЙТ]
OB80_PRIORITY BYTE
[БАЙТ]
NUM BYTE
[БАЙТ]
OB80_OB_NUMBR BYTE
[БАЙТ]
TYP2_3 BYTE
[БАЙТ]
OB80_RESERVED_1 BYTE
[БАЙТ]
TYP1 BYTE
[БАЙТ]
OB80_RESERVED_2 BYTE
[БАЙТ]
ZI1 WORD
[СЛОВО]
OB80_ERROR_INFO WORD
[СЛОВО]
OB80_ERR_EV_CLASS BYTE
[БАЙТ]
OB80_ERR_EV_NUM BYTE
[БАЙТ]
OB80_OB_PRIORITY BYTE
[БАЙТ]
ZI2_3 DWORD
[ДВОЙНОЕ
СЛОВО]
OB80_OB_NUM BYTE
[БАЙТ]
Примечание:
•
В каждой временной переменной каждый OB содержит дату и время
вызова. Однако они не включаются в данные о запуске, которые
читаются с помощью SFC6.
• PCS 7 совместимые блоки не инсталлир уются в OB горячего перезапуска
(OB101).
Руководство по программированию, создание блоков для PCS 7
A5E00122559-01
1-27
Ниже представлен фрагмент блока-примера, в котором показан порядок
обработки OB:
//**************************************************************************************
//
Область кода
//**************************************************************************************
CASE WORD_TO_INT(BYTE_TO_WORD(TOP_SI.NUM)) OF
//************************************************************************************
// OB обработки ошибок
//************************************************************************************
// OB80: ошибка времени
80:
QH_ALM := 0; // сброс выходов ошибок
QL_ALM := 0;
//************************************************************************************
// Startup
//************************************************************************************
// OB100: теплая перезагрузка
100:
QH_ALM := 0; // сброс выходов ошибок
QL_ALM := 0;
siRUNUPCNT := RUNUPCYC; // сохранить значение RUNUPCYC
ELSE
Руководство по программированию, создание бл оков дл я PCS 7
1-28 A5E00122559-01
1.6 Операторское у правление, мониторинг и
сообщения
Блоки, за параметрами которых можно наблюдать и которыми можно
управлять
с ОС, должны быть подготовлены для соединения с ОС. Этот
процесс включает определение как требуемых параметров, та к и самого
блока.
Операторско е управление
Если Вы хотите управлять значением параметра исключительно с ОС, то Вам
необ ходим параметр ввода-вывода или только ввода для управляемого
значения (с системным атрибутом
S7_m_c).
Но если Вы хоти те иметь возмож ность получать значение параметра из
другого блока или устанавливать значение на ОС и хотите , чтобы
переключение со свя занного значения на зна чение, задаваемое
пользователем, было безударным, Вам необходимо всего три параметра:
• Параметр ввода для переключения между операторским значением и
связанным значением
• Параметр ввода для связанного значения
• Параметр ввода-вывода для уп равляемого пользователем значения (с
системным атрибутом
S7_m_c ). Этот параметр должен быть параметром
ввода-вывода, так как связанное значение для безударного переключения
из алгоритма блока на задаваемое пользователем зна чение должно
записываться обратно в течение того времени, которое выбрано
связанное значение .
Все функции операторского ввода должны обрабатываться с помощью
блоков операторского управления библиотеки "PCS 7 Technological Blocks
[Техн о ло гичес кие блоки PCS 7]" и соответствующих им методов
операторского ввода на ОС. В них определены все требуемые блокировки и
(безударное) переключение между значением вводимым оператором и
связанным значением (например, для ручного/автоматического
переключения). Вы можете инсталлировать блок операторского управления в
Ваш блок с помощью многоэкземплярной технологии.
В PCS 7, например, может использоваться блок
OP_A_LIM (operation analog
limited [ограниченный аналоговый ввод]).
Блок OP_A_LIM накладывает ограничение на операторский ввод. В качестве
альтернативы Вы можете использовать блок OP_A_RJC, который отклоняет
операторский ввод, если таким образом будет нарушена уставка. Если Вам
не требуется проверка значения, то можно использовать блок OP_A.
Примечание:
Блок ПЛК и экранная панель работают асинх ронно; другими словами когда
оператор вводит значение на экранной панели, значение записываетс я в
копию базы данных блока ПЛК и позже обрабатывается блоком ПЛК. Так как
к этому времени уставки могут уже измениться, то значение, введенное
оператором следует проверить как на ПЛК так и на ОС.
Руководство по программированию, создание блоков для PCS 7
A5E00122559-01
1-29
Для двоичного операторского ввода Вы можете использовать блоки OP_D
(FB48), OP_D3 (FB49) и OP_TRIG (FB50) библиотеки PCS 7 "Technological
Blocks [Технологические блоки]" (более подробную информацию Вы можете
найти в интерактивной помощи).
В следующем примере приведено описание операторского ввода:
//**********************************************************************************
//
Ввод оператором уставки SP_OP (действительное значение) или связывание уставки SP_EXT
//**********************************************************************************
// Вызов многоэкземплярного OP_A_LIM (значение параметров для OP_A_LIM смотрите в
// интерактивной справке к нему)
OP_A_LIM_1(U := SP_OP, U_HL:= SP_HLM, U_LL:= SP_LLM, OP_EN:= SP_OP_ON, BTRACK:=
SPBUMPON, LINK_ON:= SP_EXTON, LINK_U:= SP_EXT);
OK := OK AND ENO; // Разрешение вывода флага OK блока OP_A_LIM
Q_SP_OP := OP_A_LIM_1.QOP_EN; // 1: разрешение операторского ввода SP
SP_OP := OP_A_LIM_1.U; // Перезапись уставки
QOP_ERR := OP_A_LIM_1.QOP_ERR; // 1: Ошибка оператора
QSP_HLM := OP_A_LIM_1.QVHL; // 1: верхняя граница
QSP_LLM := OP_A_LIM_1.QVLL; // 1: нижняя граница
SP := OP_A_LIM_1.V; // Действующая уставка
Сообщения
Если Вы хотите, чтобы Ваш блок мог посылать на ОС сообщения и/или
события, то Вы можете определить в статич еских переменных
многоэкземплярный блок аварий [alarm block]. Свойства инсталлированного
блока аварий определяют сообщение, квитированный отклик, а также
передачу вспомогательных значений
.
"Standard Library [Стандартна я библиотек а]" содержит готовые блоки аварий как
SFB.
Они могут быть следующими:
ALARM SFB33
Наблюдение сигнала с 1-10 вспомогательными значениями
с
запросом квитирования
ALARM_8 SFB34 Мониторинг до 8 сигналов
ALARM_8P SFB35 Мониторинг до 8 сигналов с 1-10 вспомогательными
значениями
NOTIFY SFB36
Мониторинг сигнала с 1-10 вспомогательными значениями
без
запроса квитирования
Руководство по программированию, создание бл оков дл я PCS 7
1-30 A5E00122559-01
Установки в заголо в ке блока
Чтобы разрешить управление и/или мониторинг на ОС , сначала в списке
системных атрибутов заголовка блока для системного атрибута "S7_m_c"
установите значение 'true [ис тина ]'. Это также касается сообщений. Чтобы
вызвать диалоговое окно сообщений в заголовке блока установите атрибу т
S7_alarm_ui := '1' (если Вы установите значение '0', то вызовется STEP 7
совместимое диалоговое окно).
Установки в области объявлений
Чтобы разрешить управление и наблюдение параметров блока на ОС, для
каждого параметра Вашего блока, которым Вы хотите управлять и за которым
Вы хотите наблюдать, установите значение системного атрибута "S7_m_c" в
'true [истина]'.
Если Вы хотите, чтобы Ваш блок мог посылать сообщения и/или события на
ОС, то определите ввод с типом данных DWORD [Двойное слово] (здесь:
EV_ID). В экземплярном DB это му вводу будет присвоен номер сообщ ения,
автоматически присвоенн ый системой (сервером сообщений).
Номер сообщения во всем проекте S7 является уникальным, поэтому в
проектах, содержащих несколько ПЛК и операторс ких станций, коллизий не
будет. Номер отдельного сообщ ения, требуемый WinCC, образуется от
номера этого сообщения во время передачи данных.
Для такого ввода определите системный атрибут "S7_server" со значением
'alarm_archiv' и системный атрибут "S7_a_type" со значением 'alarm_8p' (в
зависимости от блока сообщений, который Вы инсталлиро вали).
В целях избежания случайного изменения данных, определенных системой,
этот вход не должен быть видимым в схеме CFC и не должно быть
возможности соединить или присвоить параметры этому входу.
Руководство по программированию, создание блоков для PCS 7
A5E00122559-01
1-31
В следующем фрагменте блока-примера показано использование системных
атрибутов в
заголовке блока и для ввода EV_ID, котор ый будет принимать
сообщение.
//**************************************************************************************
//
Заголовок блока
//**************************************************************************************
FUNCTION_BLOCK "CONTROL"
TITLE= 'CONTROL'
{ // Список системных атрибутов
S7_tasklist:= 'OB80,OB100'; // Блок вызывается в случае ошибки и теплой перезагрузки
S7_m_c:= 'true'; // Блоком можно управлять и наблюдать за ним
S7_alarm_ui:= '1' // Параметры для диалога сообщений PCS 7 ('0'=стандартный
диалог)
}
AUTHOR: ABC
NAME: CONTROL
VERSION: '0.01'
FAMILY: XYZ
KNOW_HOW_PROTECT
//**************************************************************************************
// Область объявлений: параметры блока
//**************************************************************************************
VAR_INPUT
.... // Параметр EVENT ID для номера сообщения
EV_ID {S7_visible:='false'; // Параметр невидим в CFC
S7_link:='false'; // Параметр нельзя связать в CFC
S7_param :='false'; // Параметр не может быть задан в CFC
S7_server:='alarm_archiv'; // Номер сообщения, определяемый сервером
S7_a_type:='alarm_8p' // Сигналы блок реализованы с помощью ALARM_8P
} :DWORD := 0; // ID сообщения
...
END_VAR
Входы блока ALARM [Аварий], которые не требуются в блоке, могут быть
объявлены в интерфейсе блока, чтобы их можно было в дальнейшем
использовать для сообщений. Если дальнейшие действия не
осуществляются, то эти сообщения обрабатываются как сообщения системы
управления процессом и могут быть отключены толь ко системой сообщения
ОС. Это также относится к н еиспользованным вспомогательным значениям.
Вы можете позже использовать их в сообщениях так, как описано в
разделе 1.7.
Руководство по программированию, создание бл оков дл я PCS 7
1-32 A5E00122559-01
В следующем примере приведено описание ALARM_8P:
//**************************************************************************************
// Область объявлений: параметры блока
//**************************************************************************************
....
// Свободно определяемые вспомогательные значения ALARM_8P
AUX_PR05 {S7_visible := 'false'} : ANY; // 5 вспомогательное значение
AUX_PR06 {S7_visible := 'false'} : ANY; // 6 вспомогательное значение
AUX_PR07 {S7_visible := 'false'} : ANY; // 7 вспомогательное значение
AUX_PR08 {S7_visible := 'false'} : ANY; // 8 вспомогательное значение
AUX_PR09 {S7_visible := 'false'} : ANY; // 9 вспомогательное значение
AUX_PR10 {S7_visible := 'false'} : ANY; // 10 вспомогательное значение
....
//**************************************************************************************
// Область объявлений: статические переменные
//**************************************************************************************
....
//**************************************************************************************
// Область объявлений множества экземпляров
//**************************************************************************************
OP_A_LIM_1: OP_A_LIM; // Блок операторского управления 1
ALARM_8P_1: ALARM_8P; // Создание максимум 8 сообщений с 10 вспомогат. значениями
...
//**************************************************************************************
// Сообщения ALARM_8P
//**************************************************************************************
// Переменные типа STRING не должны быть связаны с вспомог. значениями ALARM8_P
// и передаются как массив байт
FOR DUMMY := 1 TO 16
DO
sbyBA_NA[DUMMY] := 0; //Удаление массива по умолчанию
END_FOR;
DUMMY := BLKMOV (SRCBLK:= BA_NA,DSTBLK:=sbyBA_NA);
swSTEP_NO := STEP_NO; // Номер шага Batch (в соотв. с в/в вспом. знач. ALARM_8P)
sdBA_ID := BA_ID; // Batch ID (в соотв. с в/в вспом. значений ALARM_8P)
ALARM_8P_1(EN_R := TRUE, // Обновить выход ACK_STATE
ID := 16#EEEE, // Канал данных для сообщений (всегда 16#EEEE)
EV_ID:= EV_ID, // Количество сообщений > 0
SIG_1:= M_SUP_AH AND QH_ALM, // Набл. сигнал 1 -> сообщ. верх. аварийной уставки
SIG_2:= M_SUP_AL AND QL_ALM, // Набл. сигнал 2 -> сообщ. нижн. аварийной уставки
SIG_3:= 0, // Наблюдаемый сигнал 3 -> нет сообщений
SIG_4:= 0, // Наблюдаемый сигнал 4
SIG_5:= 0, // Наблюдаемый сигнал 5
SIG_6:= 0, // Наблюдаемый сигнал 6
SIG_7:= 0, // Наблюдаемый сигнал 7
SIG_8:= 0, // Наблюдаемый сигнал 8
SD_1 := sbyBA_NA, // Вспомогательное значение 1
SD_2 := swSTEP_NO, // Вспомогательное значение 2
SD_3 := sdBA_ID, // Вспомогательное значение 3
SD_4 := PV_IN, // Вспомогательное значение 4
SD_5 := AUX_PR05, // Вспомогательное значение 5
SD_6 := AUX_PR06, // Вспомогательное значение 6
SD_7 := AUX_PR07, // Вспомогательное значение 7
SD_8 := AUX_PR08, // Вспомогательное значение 8
SD_9 := AUX_PR09, // Вспомогательное значение 9
SD_10:= AUX_PR10); // Вспомогательное значение 10
QMSG_ERR := ALARM_8P_1.ERROR; // Параметр состояния ERROR
MSG_STAT := ALARM_8P_1.STATUS; // Параметр состояния STATUS
MSG_ACK := ALARM_8P_1.ACK_STATE; // Текущее состояние подтверждения ОС
....