Ковалев Сергей. Программирование на алгоритмическом языке MQL4
Подождите немного. Документ загружается.
241
Обратите внимание, решение подобных задач невозможно без обращения к значениям
массивов-таймсерий. Эксперт, определяющий минимальную и максимальную цену среди
заданного количества последних баров, может иметь следующее решение
(extremumprice.mq4):
//--------------------------------------------------------------------
// extremumprice.mq4
// Предназначен для использования в качестве примера в учебнике MQL4.
//--------------------------------------------------------------------
extern int Quant_Bars=30; // Количество баров
//--------------------------------------------------------------------
int start() // Спец. функция start
{
int i; // Номер бара
double Minimum=Bid, // Минимальная цена
Maximum=Bid; // Максимальная цена
for(i=0;i<=Quant_Bars-1;i++) // От нуля (!) до..
{ // ..Quant_Bars-1 (!)
if (Low[i]< Minimum) // Если < известного
Minimum=Low[i]; // то оно и будет мин
if (High[i]> Maximum) // Если > известного
Maximum=High[i]; // то оно и будет макс
}
Alert("За последние ",Quant_Bars, // Вывод на экран
" баров Min= ",Minimum," Max= ",Maximum);
return; // Выход из start()
}
//--------------------------------------------------------------------
В программе extremumprice.mq4 используется простой алгоритм. Количество баров,
предназначенных для анализа, задано во внешней переменной Quant_Bars. В начале
программы искомым значениям Minimum и Maximum присваиваются значения текущей
цены. Поиск минимального и максимального значений выполняется в операторе цикла:
for(i=0;i<=Quant_Bars-1;i++) // От нуля (!) до..
{ // ..Quant_Bars-1 (!)
if (Low[i]< Minimum) // Если < известного
Minimum = Low[i]; // то оно и будет мин
if (High[i]> Maximum) // Если > известного
Maximum = High[i]; // то оно и будет макс
}
242
Здесь показательным является интервал значений индексов (целая переменная i)
обрабатываемых элементов массивов-таймсерий Low[i] и High[i]. Обратите внимание на
Выражение_1 и Условие в заголовке оператора цикла:
for(i=0;i<=Quant_Bars-1;i++) // От нуля (!) до..
На первой итерации вычисления производятся с нулевыми значениями индексов. Это
значит, что в расчётах на первой итерации анализируются значения нулевого бара. Таким
образом гарантируется, что самые последние значения цены, появившиеся в окне
финансового инструмента, тоже принимаются во внимание. В разделе Предопределённые
переменные указано правило, в соответствии с которым значения всех предопределённых
переменных, в том числе и массивов-таймсерий, обновляются в момент запуска на
исполнение специальных функций. Таким образом, ни одно значение цены не может быть
пропущено или не учтено.
Последним индексом элементов таймсерий, обрабатываемых в цикле, является индекс, на
1 меньший, чем количество обрабатываемых баров. В нашем примере указано количество
баров, равное 30. Это значит, что максимальное значение индекса должно быть равно 29.
Таким образом, в цикле будут обработаны значения элементов таймсерий с индексами от
0 до 29, т.е. всего для 30 баров.
Легко понять и смысл вычислений в теле оператора цикла:
if (Low[i]< Minimum) // Если < известного
Minimum = Low[i]; // то оно и будет мин
if (High[i]> Maximum) // Если > известного
Maximum = High[i]; // то оно и будет макс
Если текущее значение Low[i] (т.е. в период текущей итерации с текущим значением
индекса) оказывается меньше известного минимального значения, то оно и становится
минимальным значением. Аналогично вычисляется и максимальное значение. К моменту
окончания цикла переменные Minimum и Maximum получат искомые значения. В
последующих строках эти значения выводятся на экран.
Запустив эту программу на выполнение можно получить результат, аналогичный
следующему:
243
Рис. 63. Результаты работы эксперта extremumprice.mq4.
Обратите внимание, эксперт может работать бесконечно долго, показывая правильный
результат, причём в программе всё время используются одни и те же значения индексов (в
данном случае от 0 до 29). При этом значения элементов массивов-таймсерий с
ненулевыми индексами будут изменяться в момент появления нового бара, а значения
элементов массивов-таймсерий, характеризующих нулевой бар, могут поменяться на
любом следующем тике (за исключением значений Open[0] и Time[0], которые на нулевом
баре не изменяются).
В некоторых случаях требуется выполнить какие-то действия, начиная с момента, когда
очередной бар только что полностью сформировался. Это бывает важно, например, для
реализации алгоритмов, основанных на свечном анализе. При этом обычно во внимание
принимаются только полностью сформировавшиеся бары.
Задача 27.В начале каждого бара 1 раз вывести на экран минимальное и
максимальное значения цены среди последних сформировавшихся n
баров.
Чтобы решить задачу, прежде всего необходимо определить факт начала нового бара, т.е.
выявить первый тик на нулевом баре. Для этой цели существует очень простой и
244
надёжный способ - анализировать время открытия нулевого бара. Время открытия
нулевого бара - это такая характеристика бара, которая не изменяется в течение времени
его формирования. Новые тики, поступающие в процессе развития нулевого бара, могут
изменить его максимальную цену High[0], минимальную цену Low[0], цену закрытия
Close[0] и объём Volume0]. Но такие характеристики нулевого бара, как цена открытия
Open[0] и время открытия Time[0], не изменяются.
Поэтому достаточно запомнить время открытия нулевого бара и на каждом тике
сравнивать это значение с последним известным временем открытия нулевого бара. Как
только обнаружится несовпадение, это будет означать факт образования нового бара (и
завершение предыдущего). В эксперте newbar.mq4 алгоритм обнаружения нового бара
реализован в виде пользовательской функции:
//--------------------------------------------------------------------
// newbar.mq4
// Предназначен для использования в качестве примера в учебнике MQL4.
//--------------------------------------------------------------------
extern int Quant_Bars=15; // Количество баров
bool New_Bar=false; // Флаг нового бара
//--------------------------------------------------------------------
int start() // Спец. функция start
{
double Minimum, // Минимальная цена
Maximum; // Максимальная цена
//--------------------------------------------------------------------
Fun_New_Bar(); // Обращение к ф-ии
if (New_Bar==false) // Если бар не новый..
return; // ..то уходим
//--------------------------------------------------------------------
int Ind_max =ArrayMaximum(High,Quant_Bars,1);// Индекс бара макс.ц.
int Ind_min =ArrayMinimum(Low, Quant_Bars,1);// Индекс бара мин. ц.
Maximum=High[Ind_max]; // Искомая макс цена
Minimum=Low[Ind_min]; // Искомая мин. цена
Alert("За последние ",Quant_Bars, // Вывод на экран
" баров Min= ",Minimum," Max= ",Maximum);
return; // Выход из start()
}
//--------------------------------------------------------------------
void Fun_New_Bar() // Ф-ия обнаружения ..
{ // .. нового бара
static datetime New_Time=0; // Время текущего бара
New_Bar=false; // Нового бара нет
if(New_Time!=Time[0]) // Сравниваем время
{
245
New_Time=Time[0]; // Теперь время такое
New_Bar=true; // Поймался новый бар
}
}
//--------------------------------------------------------------------
В программе используется глобальная переменная New_Bar. Полагается, что если её
значение равно true, то это означает, что последний известный тик - это первый тик
нового бара. Если же значение New_Bar равно false, то последний известный тик появился
в период развития текущего нулевого бара.
Флаг - это переменная, значение которой ставится в соответствие каким-либо событиям
или фактам.
Использование флагов в программе очень удобно. Значение флага может быть определено
в одном месте, а использоваться в разных местах. Иногда в программе используется
алгоритм, в котором принимается решение в зависимости от сочетания значений
различных флагов. В эксперте newbar.mq4 в качестве флага используется переменная
New_Bar, значение которой находится в прямой зависимости от факта образования нового
бара.
Вычисления, касающиеся выявления факта образования нового бара, сосредоточены в
пользовательской функции Fun_New_Bar(). В первых строках этой функции определена
статическая переменная New_Time (напомним, что статические переменные не теряют
своё значение после окончания исполнения функции). При каждом обращении к функции
значение глобальной переменной New_Bar устанавливается равным false. Собственно
обнаружение нового бара осуществляется в операторе if:
if(New_Time != Time[0]) // Сравниваем время
{
New_Time = Time[0]; // Теперь время такое
New_Bar = true; // Поймался новый бар
}
Если значение переменной New_Time (вычисленное в предыдущей истории), не равно
времени открытия нулевого бара Time[0], то это означает факт образования нового бара. В
этом случае управление передаётся в тело оператора if, где запоминается новое значение
времени открытия нового нулевого бара и переменной New_Bar присваивается значение
true (условно можно сказать, что флаг устанавливается в положение вверх).
246
При решениях подобных задач важно учитывать специфику использования различных
флагов. В данном случае особенность состоит в том, что значение переменной New_Bar
(положение флага) должно быть обновлено раньше, чем оно будет использоваться в
вычислениях (в данном случае - в специальной функции start()). Поскольку значение
переменной New_Bar определяется в пользовательской функции, значит обращение к ней
должно быть выполнено как можно раньше в программе, а именно, до первых
вычислений, в которых используется переменная New_Bar. Специальная функция start()
так и составлена: обращение к пользовательской функции осуществляется сразу после
объявления переменных.
Вычисление искомых значений имеет смысл только в том случае, если специальная
функция start() запущена тиком, на котором и образовался новый бар. Поэтому в функции
start(), сразу после определения факта образования нового бара, производится анализ
положения флага (значения переменной New_Bar):
if (New_Bar == false) // Если бар не новый..
return; // ..то уходим
Если последний тик, запустивший на исполнение специальную функцию start(), не
образовал новый бар, то управление передаётся оператору, завершающему исполнение
функции start(). И только в том случае, если новый бар образовался, управление
передаётся в последующие строки для вычисления искомых значений (что и требуется по
условию задачи).
Вычисление максимального и минимального значений осуществляется с помощью
стандартных функций ArrayMaximum() и ArrayMinimum(). Каждая из этих функций
возвращает индекс элемента массива (соответственно максимального и минимального
значения) для заданного интервала индексов. По условию задачи необходимо исследовать
только полностью сформировавшиеся бары, поэтому в качестве граничных значений
индексов выбраны значения 1 и Quant_Bars - заданное количество баров (нулевой бар не
сформировался, т.е. в решении данной задачи не учитывается). Для получения подробной
информации о работе этих и других функций доступа к таймсериям обратитесь к
справочной документации на сайте производителя (http://docs.MQL4.com/ru) или к разделу
"Справка" в редакторе MetaEditor.
На Рис. 64 можно проследить, как менялись минимальное и максимальное значения цены
на заданном интервале в период исполнения программы:
247
Рис. 64. Результаты работы эксперта newbar.mq4.
9 Практическое программирование на языке MQL4
Во второй части рассматриваются: порядок проведения торговых операций, принципы
построения и использования простых скриптов, экспертов и индикаторов, а также
стандартные функции, часто используемые при составлении программ. Все разделы
содержат примеры программ, готовых к использованию, но имеющих ограниченную
область применения.
В разделе "Построение обычных программ" представлен пример программы, который
может быть принят за основу при проектировании собственного обычного эксперта для
использования в реальной торговле.
Все приведенные торговые критерии используются в учебных целях и не должны
рассматриваться как руководство к действию при торговле на реальном счёте.
9.1 Программирование торговых операций
При программировании торговых операций необходимо учитывать требования и
ограничения, связанные с характеристиками ордеров и правилами, принятыми в
дилинговом центре, а также особенности технологии исполнения торговых приказов. В
248
разделе подробно рассматривается порядок проведения торговых операций и приводится
достаточно примеров, поясняющих назначение всех торговых функций, с помощью
которых формируются различные торговые приказы. Представлено несколько готовых к
использованию скриптов, ориентированных на узкую область применения.
9.1.1 Общий порядок проведения торговых операций
Все вычисления и различные действия, осуществляемые в связи с выполнением
прикладной программы, по месту их исполнения можно разделить на две группы:
исполняемые внутри компьютера пользователя и исполняемые на сервере. Значительная
часть вычислений производится на компьютере пользователя. К этой группе относится
исполнение прикладных программ. Торговые операции относятся ко второй группе.
Осуществление торговых операций предполагает обязательное преобразование
информации на сервере.
Рассматривая торговые операции, мы будем различать следующие понятия:
Рыночный ордер - исполненный торговый приказ на покупку или продажу активов по
финансовому инструменту. Рыночный ордер отображается в окне финансового
инструмента до тех пор, пока не выполнен приказ на закрытие ордера.
Отложенный ордер - торговый приказ на покупку или продажу активов по финансовому
инструменту при достижении заданного значения цены. Отложенный ордер отражается в
окне финансового инструмента до тех пор, пока он не преобразуется в рыночный ордер
либо будет удалён.
Торговый приказ - приказ, сформированный программой или трейдером с целью
осуществления торговой операции.
Торговая операция - открытие, закрытие или модификации рыночных и отложенных
ордеров.
9.1.1.1 Схема проведения торговых операций
В проведении торговых операций принимают участие три составляющих - прикладная
программа, клиентский терминал и сервер (см. рис. 65). В программе формируется
торговый приказ (ранее уже было указано, что любые прикладные программы могут
249
исполняться только в компьютере трейдера; никакие прикладные программы не
устанавливаются на сервере). Торговый приказ, сформированный программой, передаётся
клиентскому терминалу, который, в свою очередь, отправляет приказ на сервер. На
сервере принимается решение об исполнении или отклонении торгового приказа.
Информация о фактически полученных результатах сообщается сервером в клиентский
терминал и далее в программу.
Рис. 65. Схема передачи торговых приказов при проведении торговых операций.
9.1.1.2 Формирование торговых приказов
Торговый приказ может быть сформирован трейдером или программой. Для создания
торговых приказов по инициативе трейдера в составе клиентского терминала имеется
панель управления ордерами (см. описание клиентского терминала). Формирование
торговых приказов в программе происходит в соответствии с алгоритмом в результате
исполнения торговых функций. Нигде в других местах (ни в клиентском терминале, ни на
сервере) торговые приказы самопроизвольно не формируются.
9.1.1.3 Свойства программы
В зависимости от исполняемого алгоритма программа может формировать различные
торговые приказы - приказы на открытие, закрытие или модификацию рыночных и
отложенных ордеров. Для формирования торговых приказов в программе используются
следующие торговые функции:
OrderSend() - для открытия рыночных и отложенных ордеров;
OrderClose() и OrderCloseBy() - для закрытия рыночных ордеров;
OrderDelete() - для удаления отложенных ордеров;
OrderModify()- для модификации рыночных и отложенных ордеров.
250
Указанные торговые функции могут использоваться только в экспертах и скриптах;
использование этих функций в индикаторах запрещено (см. также Таблицу 2).
Существуют и другие функции, относящиеся к торговым (см. справку в редакторе
MetaEditor и раздел Торговые функции), однако их исполнение связано с обращением к
информационной среде клиентского терминала с целью получения справочной
информации и не приводит к формированию торговых приказов и обращению к серверу.
9.1.1.4 Свойства клиентского терминала
Торговый приказ, сформированный программой в результате исполнения торговой
функции, передаётся для обработки в клиентский терминал. Клиентский терминал
анализирует содержание торгового приказа и выполняет одно из двух действий: либо
отправляет приказ на сервер с целью его исполнения на сервере, либо отклоняет приказ и
ничего не отправляет на сервер.
Клиентский терминал позволяет отправлять на сервер только корректные торговые
приказы. Если программа составлена таким образом, что формирует, например, приказ на
открытие ордера по несуществующей цене, то клиентский терминал не отправит этот
торговый приказ на сервер. Если же программа формирует корректный торговый приказ
(открытие и закрытие ордеров по последней известной цене, стоимость ордеров находится
в пределах ограничений дилингового центра и т.д.), то такой приказ будет отправлен на
сервер.
Для осуществления торговых операций в клиентском терминале предусмотрен всего один
поток. Это значит, что клиентский терминал может работать одновременно только с
одним торговым приказом. Если в клиентском терминале запущено несколько торгующих
экспертов или скриптов и при этом один из них передал клиентскому терминалу торговый
приказ, то торговые приказы остальных экспертов и скриптов будут отклоняться до тех
пор, пока клиентский терминал не закончит работу с текущим торговым приказом, то есть
пока не освободится торговый поток.
9.1.1.5 Свойства сервера
Информация об истории торговли по каждому счёту (открытие, закрытие и модификация
ордеров) в обязательном порядке строго учитывается на сервере и имеет более высокий