Справочник по языку программирования MQL5

Доступ к таймсериям и индикаторам

541

производится по значениям PRICE_CLOSE.

Пример:

void OnStart()

{

MqlParam params[];

int h_MA,h_MACD;

//--- create iMA("EURUSD",PERIOD_M15,8,0,MODE_EMA,PRICE_CLOSE);

ArrayResize(params,4);

//--- set ma_period

params[0].type =TYPE_INT;

params[0].integer_value=8;

//--- set ma_shift

params[1].type =TYPE_INT;

params[1].integer_value=0;

//--- set ma_method

params[2].type =TYPE_INT;

params[2].integer_value=MODE_EMA;

//--- set applied_price

params[3].type =TYPE_INT;

params[3].integer_value=PRICE_CLOSE;

//--- create MA

h_MA=IndicatorCreate("EURUSD",PERIOD_M15,IND_MA,4,params);

//--- create iMACD("EURUSD",PERIOD_M15,12,26,9,h_MA);

ArrayResize(params,4);

//--- set fast ma_period

params[0].type =TYPE_INT;

params[0].integer_value=12;

//--- set slow ma_period

params[1].type =TYPE_INT;

params[1].integer_value=26;

//--- set smooth period for difference

params[2].type =TYPE_INT;

params[2].integer_value=9;

//--- set indicator handle as applied_price

params[3].type =TYPE_INT;

params[3].integer_value=h_MA;

//--- create MACD based on moving average

h_MACD=IndicatorCreate("EURUSD",PERIOD_M15,IND_MACD,4,params);

//--- use indicators

//--- . . .

//--- release indicators (first h_MACD)

IndicatorRelease(h_MACD);

IndicatorRelease(h_MA);

}

Доступ к таймсериям и индикаторам

542

IndicatorRelease

Удаляет хэндл индикатора и освобождает расчетную часть индикатора, если ею больше никто не

пользуется.

bool IndicatorRelease(

int indicator_handle, // handle индикатора

);

Возвращаемое значение

Возвращает true в случае успеха, иначе false.

Примечание

Функция позволяет удалять хэндл индикатора, если он больше не нужен, и таким образом

позволяет экономить память. Удаление хендла производится сразу, удаление расчетной части

индикатора производится через некоторое небольшое время (если обращений к ней больше

нет).

Пример:

//+------------------------------------------------------------------+

//| Test_IndicatorRelease.mq5 |

//| http://www.mql5.com |

//+------------------------------------------------------------------+

#property copyright "2010, MetaQuotes Software Corp."

#property link "http://www.mql5.com"

#property version "1.00"

//--- input parameters

input int MA_Period=15;

input int MA_shift=0;

input ENUM_MA_METHOD MA_smooth=MODE_SMA;

input ENUM_APPLIED_PRICE price=PRICE_CLOSE;

//--- будем хранить хендл индикатора

int MA_handle=INVALID_HANDLE;

//+------------------------------------------------------------------+

//| Expert initialization function |

//+------------------------------------------------------------------+

int OnInit()

{

//--- создадим хендл индикатора

MA_handle=iMA(Symbol(),0,MA_Period,MA_shift,MA_smooth,PRICE_CLOSE);

//--- удаление глобальной переменной

if(GlobalVariableCheck("MA_value"))

GlobalVariableDel("MA_value");

//---

return(0);

}

//+------------------------------------------------------------------+

Доступ к таймсериям и индикаторам

543

//| Expert tick function |

//+------------------------------------------------------------------+

void OnTick()

{

//--- если глобальной переменной еще нет

if(!GlobalVariableCheck("MA_value"))

{

//--- получим значения индикатора на двух последних барах

if(MA_handle!=INVALID_HANDLE)

{

//--- динамический массив для получения значений индикатора

double values[];

if(CopyBuffer(MA_handle,0,0,2,values)==2 && values[0]!=EMPTY_VALUE)

{

//--- запомним в глобальной переменной значение на предпоследнем баре

if(GlobalVariableSet("MA_value",values[0]))

{

//--- освободим хэндл индикатора

if(!IndicatorRelease(MA_handle))

Print("IndicatorRelease() failed. Error ",GetLastError());

else MA_handle=INVALID_HANDLE;

}

else

Print("GlobalVariableSet failed. Error ",GetLastError());

}

//---

}

Доступ к таймсериям и индикаторам

544

CopyBuffer

Получает в массив buffer данные указанного буфера указанного индикатора в указанном

количестве.

Отсчет элементов копируемых данных (индикаторный буфер с индексом buffer_num) от стартовой

позиции ведется от настоящего к прошлому, то есть стартовая позиция, равная 0, означает

текущий бар (значение индикатора для текущего бара).

При копировании заранее неизвестного количества данных в качестве массива-приемника buffer[]

желательно использовать динамический массив, так как функция CopyBuffer() старается

распределить размер принимающего массива под размер копируемых данных. Если в качестве

принимающего массива buffer[] выступает индикаторный буфер (массив, предварительно

назначенный под хранение значений индикатора функцией SetIndexBufer()), то допускается

частичное копирование. Пример можно посмотреть в пользовательском индикаторе

Awesome_Oscillator.mq5 из стандартной поставки терминала.

Если необходимо произвести частичное копирование значений индикатора в другой массив (не

индикаторный буфер), то для этих целей необходимо использовать промежуточный массив, в

который копируется требуемое количество. И уже из этого массива-посредника произвести

поэлементное копирование нужного количества значений в нужные места принимающего массива.

Если необходимо копировать заранее известное количество данных, то лучше это делать в

статически выделенный буфер, чтобы избежать излишнего перевыделения памяти.

Неважно, какое свойство имеет приемный массив - as_series=true или as_series=false, данные

будут скопированы таким образом, что самый старый по времени элемент будет в начале

физической памяти, отведенной под массив. Существует 3 варианта функции.

Обращение по начальной позиции и количеству требуемых элементов

int CopyBuffer(

int indicator_handle, // handle индикатора

int buffer_num, // номер буфера индикатора

int start_pos, // откуда начнем

int count, // сколько копируем

double buffer[] // массив, куда будут скопированы данные

);

Обращение по начальной дате и количеству требуемых элементов

Доступ к таймсериям и индикаторам

545

int CopyBuffer(

int indicator_handle, // handle индикатора

int buffer_num, // номер буфера индикатора

datetime start_time, // с какой даты

int count, // сколько копируем

double buffer[] // массив, куда будут скопированы данные

);

Обращение по начальной и конечной датам требуемого интервала времени

int CopyBuffer(

int indicator_handle, // handle индикатора

int buffer_num, // номер буфера индикатора

datetime start_time, // с какой даты

datetime stop_time, // по какую дату

double  buffer[] // массив, куда будут скопированы данные

);

Параметры

indicator_handle

[in] Хэндл индикатора, полученный соответствующей индикаторной функцией.

buffer_num

[in] Номер индикаторного буфера.

start_pos

[in] Номер первого копируемого элемента.

count

[in] Количество копируемых элементов.

start_time

[in] Время бара, соответствующее первому элементу.

stop_time

[in] Время бара, соответствующее последнему элементу.

buffer[]

[out] Массив типа double.

Возвращаемое значение

Количество скопированных элементов массива либо -1 в случае ошибки.

Примечание

При запросе данных из индикатора, если запрашиваемые таймсерии еще не построены или их

необходимо загрузить с сервера, то функция сразу же вернет -1, но при этом сам процесс

загрузки/построения будет инициирован.

При запросе данных из эксперта или скрипта, будет инициирована загрузка с сервера, если

локально этих данных у терминала нет, либо начнется построение нужной таймсерии, если

Доступ к таймсериям и индикаторам

546

данные можно построить из локальной истории, но они еще не готовы. Функция вернет то

количество данных, которые будут готовы к моменту истечения таймаута.

Пример:

Доступ к таймсериям и индикаторам

547

//+------------------------------------------------------------------+

//| TestCopyBuffer3.mq5 |

//| http://www.mql5.com |

//+------------------------------------------------------------------+

#property copyright "2009, MetaQuotes Software Corp."

#property link "http://www.mql5.com"

#property version "1.00"

#property indicator_separate_window

#property indicator_buffers 1

#property indicator_plots 1

//---- plot MA

#property indicator_label1 "MA"

#property indicator_type1 DRAW_LINE

#property indicator_color1 clrRed

#property indicator_style1 STYLE_SOLID

#property indicator_width1 1

//--- input parameters

input bool AsSeries=true;

input int period=15;

input ENUM_MA_METHOD smootMode=MODE_EMA;

input ENUM_APPLIED_PRICE price=PRICE_CLOSE;

input int shift=0;

//--- indicator buffers

double MABuffer[];

int ma_handle;

//+------------------------------------------------------------------+

//| Custom indicator initialization function |

//+------------------------------------------------------------------+

int OnInit()

{

//--- indicator buffers mapping

SetIndexBuffer(0,MABuffer,INDICATOR_DATA);

Print("Параметр AsSeries = ",AsSeries);

Print("Индикаторный буфер после SetIndexBuffer() является таймсерией = ",

ArrayGetAsSeries(MABuffer));

//--- set short indicator name

IndicatorSetString(INDICATOR_SHORTNAME,"MA("+period+")"+AsSeries);

//--- set AsSeries(dependes from input parameter)

ArraySetAsSeries(MABuffer,AsSeries);

Print("Индикаторный буфер после ArraySetAsSeries(MABuffer,true); является таймсерией = ",

ArrayGetAsSeries(MABuffer));

//---

ma_handle=iMA(Symbol(),0,period,shift,smootMode,price);

return(0);

}

//+------------------------------------------------------------------+

//| Custom indicator iteration function |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

const int prev_calculated,

const datetime &time[],

const double &open[],

const double &high[],

const double &low[],

const double &close[],

const long &tick_volume[],

const long &volume[],

const int &spread[])

{

Доступ к таймсериям и индикаторам

548

//--- check if all data calculated

if(BarsCalculated(ma_handle)<rates_total) return(0);

//--- we can copy not all data

int to_copy;

if(prev_calculated>rates_total || prev_calculated<=0) to_copy=rates_total;

else

{

to_copy=rates_total-prev_calculated;

//--- last value is always copied

to_copy++;

}

//--- try to copy

if(CopyBuffer(ma_handle,0,0,to_copy,MABuffer)<=0) return(0);

//--- return value of prev_calculated for next call

return(rates_total);

}

//+------------------------------------------------------------------+

В вышеприведенном примере проиллюстрировано заполнение индикаторного буфера значениями

другого индикаторного буфера от индикатора на том же символе/периоде.

Смотри также

Свойствапользовательскихиндикаторов, SetIndexBuffer

Доступ к таймсериям и индикаторам

549

CopyRates

Получает в массив rates_array исторические данные структуры MqlRates указанного символа-

периода в указанном количестве. Отсчет элементов от стартовой позиции ведется от настоящего к

прошлому, то есть стартовая позиция, равная 0, означает текущий бар.

При копировании заранее неизвестного количества данных рекомендуется в качестве приемного

массива использовать динамический массив, так как если данных оказывается меньше (или

больше), чем вмещает массив, то производится попытка перераспределения массива таким

образом, чтобы запрошенные данные поместились целиком и полностью.

Если необходимо копировать заранее известное количество данных, то лучше это делать в

статически выделенный буфер, чтобы избежать излишнего перевыделения памяти.

Неважно, какое свойство имеет приемный массив - as_series=true или as_series=false, данные

будут скопированы таким образом, что самый старый по времени элемент будет в начале

физической памяти, отведенной под массив. Существует 3 варианта функции.

Обращение по начальной позиции и количеству требуемых элементов

int CopyRates(

string symbol_name, // имя символа

ENUM_TIMEFRAMES timeframe, // период

int start_pos, // откуда начнем

int count, // сколько копируем

MqlRates rates_array[] // массив, куда будут скопированы данные

);

Обращение по начальной дате и количеству требуемых элементов

int CopyRates(

string symbol_name, // имя символа

ENUM_TIMEFRAMES timeframe, // период

datetime start_time, // с какой даты

int count, // сколько копируем

MqlRates rates_array[] // массив, куда будут скопированы данные

);

Обращение по начальной и конечной датам требуемого интервала времени

Доступ к таймсериям и индикаторам

550

int CopyRates(

string symbol_name, // имя символа

ENUM_TIMEFRAMES timeframe, // период

datetime start_time, // с какой даты

datetime stop_time, // по какую дату

MqlRates rates_array[] // массив, куда будут скопированы данные

);

Параметры

symbol_name

[in] Символ.

timeframe

[in] Период.

start_time

[in] Время бара, соответствующее первому элементу.

start_pos

[in] Номер первого копируемого элемента.

count

[in] Количество копируемых элементов.

stop_time

[in] Время бара, соответствующее последнему элементу.

rates_array[]

[out] Массив типа MqlRates.

Возвращаемое значение

Количество скопированных элементов массива либо -1 в случае ошибки.

Примечание

Если интервал запрашиваемых данных полностью находится вне доступных данных на сервере,

то функция возвращает -1. В случае если запрашиваются данные за пределами

TERMINAL_MAXBARS (максимальное количество баров на графике), функция также вернет -1.

При запросе данных из индикатора, если запрашиваемые таймсерии еще не построены или их

необходимо загрузить с сервера, то функция сразу же вернет -1, но при этом сам процесс

загрузки/построения будет инициирован.

При запросе данных из эксперта или скрипта, будет инициирована загрузка с сервера, если

локально этих данных у терминала нет, либо начнется построение нужной таймсерии, если

данные можно построить из локальной истории, но они еще не готовы. Функция вернет то

количество данных, которые будут готовы к моменту истечения таймаута, но загрузка истории

будет продолжаться, и при следующем аналогичном запросе функция вернет уже больше

данных.

При запросе данных в заданном диапазоне дат возвращаются только данные, попадающие в

запрашиваемый интервал, при этом интервал задается и учитывается с точностью до секунды.

Справочник по языку программирования MQL5

Подождите немного. Документ загружается.