Справочник по языку программирования MQL5

Доступ к таймсериям и индикаторам

531

//+------------------------------------------------------------------+

//| TestLoadHistory.mq5 |

//| http://www.mql5.com |

//+------------------------------------------------------------------+

#property copyright "2009, MetaQuotes Software Corp."

#property link "http://www.mql5.com"

#property version "1.02"

#property script_show_inputs

//--- input parameters

input string InpLoadedSymbol="NZDUSD"; // Symbol to be load

input ENUM_TIMEFRAMES InpLoadedPeriod=PERIOD_H1; // Period to be load

input datetime InpStartDate=D'2006.01.01'; // Start date

//+------------------------------------------------------------------+

//| Script program start function |

//+------------------------------------------------------------------+

void OnStart()

{

Print("Start load",InpLoadedSymbol+","+GetPeriodName(InpLoadedPeriod),"from",InpStartDate);

//---

int res=CheckLoadHistory(InpLoadedSymbol,InpLoadedPeriod,InpStartDate);

switch(res)

{

case -1 : Print("Unknown symbol ",InpLoadedSymbol); break;

case -2 : Print("Requested bars more than max bars in chart "); break;

case -3 : Print("Program was stopped "); break;

case -4 : Print("Indicator shouldn't load its own data "); break;

case -5 : Print("Load failed "); break;

case 0 : Print("Loaded OK "); break;

case 1 : Print("Loaded previously "); break;

case 2 : Print("Loaded previously and built "); break;

default : Print("Unknown result ");

}

//---

datetime first_date;

SeriesInfoInteger(InpLoadedSymbol,InpLoadedPeriod,SERIES_FIRSTDATE,first_date);

int bars=Bars(InpLoadedSymbol,InpLoadedPeriod);

Print("First date ",first_date," - ",bars," bars");

//---

}

//+------------------------------------------------------------------+

//| |

//+------------------------------------------------------------------+

int CheckLoadHistory(string symbol,ENUM_TIMEFRAMES period,datetime start_date)

{

datetime first_date=0;

datetime times[100];

//--- check symbol & period

if(symbol==NULL || symbol=="") symbol=Symbol();

if(period==PERIOD_CURRENT) period=Period();

//--- check if symbol is selected in the MarketWatch

if(!SymbolInfoInteger(symbol,SYMBOL_SELECT))

{

if(GetLastError()==ERR_MARKET_UNKNOWN_SYMBOL) return(-1);

SymbolSelect(symbol,true);

}

//--- check if data is present

SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date);

if(first_date>0 && first_date<=start_date) return(1);

//--- don't ask for load of its own data if it is an indicator

if(MQL5InfoInteger(MQL5_PROGRAM_TYPE)==PROGRAM_INDICATOR && Period()==period && Symbol()==symbol)

Доступ к таймсериям и индикаторам

532

return(-4);

//--- second attempt

if(SeriesInfoInteger(symbol,PERIOD_M1,SERIES_TERMINAL_FIRSTDATE,first_date))

{

//--- there is loaded data to build timeseries

if(first_date>0)

{

//--- force timeseries build

CopyTime(symbol,period,first_date+PeriodSeconds(period),1,times);

//--- check date

if(SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date))

if(first_date>0 && first_date<=start_date) return(2);

}

//--- max bars in chart from terminal options

int max_bars=TerminalInfoInteger(TERMINAL_MAXBARS);

//--- load symbol history info

datetime first_server_date=0;

while(!SeriesInfoInteger(symbol,PERIOD_M1,SERIES_SERVER_FIRSTDATE,first_server_date) && !IsStopped())

Sleep(5);

//--- fix start date for loading

if(first_server_date>start_date) start_date=first_server_date;

if(first_date>0 && first_date<first_server_date)

Print("Warning: first server date ",first_server_date," for ",symbol,

Доступ к таймсериям и индикаторам

533

" does not match to first series date ",first_date);

//--- load data step by step

int fail_cnt=0;

while(!IsStopped())

{

//--- wait for timeseries build

while(!SeriesInfoInteger(symbol,period,SERIES_SYNCRONIZED) && !IsStopped())

Sleep(5);

//--- ask for built bars

int bars=Bars(symbol,period);

if(bars>0)

{

if(bars>=max_bars) return(-2);

//--- ask for first date

if(SeriesInfoInteger(symbol,period,SERIES_FIRSTDATE,first_date))

if(first_date>0 && first_date<=start_date) return(0);

}

//--- copying of next part forces data loading

int copied=CopyTime(symbol,period,bars,100,times);

if(copied>0)

{

//--- check for data

if(times[0]<=start_date) return(0);

if(bars+copied>=max_bars) return(-2);

fail_cnt=0;

}

else

{

//--- no more than 100 failed attempts

fail_cnt++;

if(fail_cnt>=100) return(-5);

Sleep(10);

}

//--- stopped

return(-3);

}

//+------------------------------------------------------------------+

//| возвращает строкое значение периода |

//+------------------------------------------------------------------+

string GetPeriodName(ENUM_TIMEFRAMES period)

{

if(period==PERIOD_CURRENT) period=Period();

//---

switch(period)

{

case PERIOD_M1: return("M1");

case PERIOD_M2: return("M2");

case PERIOD_M3: return("M3");

case PERIOD_M4: return("M4");

case PERIOD_M5: return("M5");

case PERIOD_M6: return("M6");

case PERIOD_M10: return("M10");

case PERIOD_M12: return("M12");

case PERIOD_M15: return("M15");

case PERIOD_M20: return("M20");

case PERIOD_M30: return("M30");

case PERIOD_H1: return("H1");

case PERIOD_H2: return("H2");

case PERIOD_H3: return("H3");

case PERIOD_H4: return("H4");

Доступ к таймсериям и индикаторам

534

case PERIOD_H6: return("H6");

case PERIOD_H8: return("H8");

case PERIOD_H12: return("H12");

case PERIOD_D1: return("Daily");

case PERIOD_W1: return("Weekly");

case PERIOD_MN1: return("Monthly");

}

//---

return("unknown period");

}

Доступ к таймсериям и индикаторам

535

SeriesInfoInteger

Возвращает информацию о состоянии исторических данных. Существует 2 варианта функции.

Непосредственно возвращает значение свойства.

long SeriesInfoInteger(

string symbol_name, // имя символа

ENUM_TIMEFRAMES timeframe, // период

ENUM_SERIES_INFO_INTEGER prop_id, // идентификатор свойства

);

Возвращает true или false в зависимости от успешности выполнения функции.

bool SeriesInfoInteger(

string symbol_name, // имя символа

ENUM_TIMEFRAMES timeframe, // период

ENUM_SERIES_INFO_INTEGER prop_id, // идентификатор свойства

long& long_var // переменная для получения информации

);

Параметры

symbol_name

[in] Символ.

timeframe

[in] Период.

prop_id

[in] Идентификатор запрашиваемого свойства, значение перечисления

ENUM_SERIES_INFO_INTEGER.

long_var

[out] Переменная, в которую помещается значение запрошенного свойства.

Возвращаемое значение

Значение типа long для первого варианта вызова.

Для второго варианта вызова возвращает true, если данное свойство поддерживается и

значение было помещено в переменную long_var, иначе возвращает false. Чтобы получить

дополнительную информацию об ошибке, необходимо вызвать функцию GetLastError().

Пример:

Доступ к таймсериям и индикаторам

536

void OnStart()

{

//---

Print("Количество баров по символу-периоду на данный момент = ",

SeriesInfoInteger(Symbol(),0,SERIES_BARS_COUNT));

Print("Самая первая дата по символу-периоду на данный момент = ",

(datetime)SeriesInfoInteger(Symbol(),0,SERIES_FIRSTDATE));

Print("Самая первая дата в истории по символу на сервере = ",

(datetime)SeriesInfoInteger(Symbol(),0,SERIES_SERVER_FIRSTDATE));

Print("Данные по символу синхронизированы = ",

(bool)SeriesInfoInteger(Symbol(),0,SERIES_SYNCRONIZED));

}

Доступ к таймсериям и индикаторам

537

Bars

Возвращает количество баров в истории по соответствующему символу периоду. Существует 2

варианта функции.

Запросить количество всех баров в истории

int Bars(

string symbol_name, // имя символа

ENUM_TIMEFRAMES timeframe  // периоду

);

Запросить количество баров на заданном интервале

int Bars(

string symbol_name, // имя символа

ENUM_TIMEFRAMES timeframe, // период

datetime start_time, // с какой даты

datetime stop_time // по какую дату

);

Параметры

symbol_name

[in] Символ.

timeframe

[in] Период.

start_time

[in] Время бара, соответствующее первому элементу.

stop_time

[in] Время бара, соответствующее последнему элементу.

Возвращаемое значение

Если указаны параметры start_time и stop_time, то функция возвращает количество баров в

диапазоне дат. Если эти параметры не указаны, то функция возвращает общее количество

баров.

Примечание

Если данные для таймсерии с указанными параметрами при вызове функции Bars() еще не

сформированы в терминале, или данные таймсерии в момент вызова функции не

синхронизированы с торговым сервером, то функция вернет нулевое значение.

Пример:

Доступ к таймсериям и индикаторам

538

int bars=Bars(_Symbol,_Period);

if(bars>0)

{

Print("Количество баров в истории терминала по символу-периоду на данный момент = ",bars);

}

else //нет доступных баров

{

//--- видимо, данные по символу не синхронизированы с данными на сервере

bool synchronized=false;

//--- счетчик цикла

int attempts=0;

// сделаем 5 попыток дождаться синхронизации

while(attempts<5)

{

if(SeriesInfoInteger(Symbol(),0,SERIES_SYNCRONIZED))

{

//--- есть синхронизация, выходим

synchronized=true;

break;

}

//--- увеличим счетчик

attempts++;

//--- подождем 10 миллисекунд до следующей итерации

Sleep(10);

}

//--- вышли из цикла по факту синхронизации

if(synchronized)

{

Print("Количество баров в истории терминала по символу-периоду на данный момент = ",bars);

Print("Самая первая в истории терминала дата по символу-периоду на данный момент = ",

(datetime)SeriesInfoInteger(Symbol(),0,SERIES_FIRSTDATE));

Print("Самая первая дата в истории по символу на сервере = ",

(datetime)SeriesInfoInteger(Symbol(),0,SERIES_SERVER_FIRSTDATE));

}

//--- синхронизация данных так и не была достигнута

else

{

Print("Не удалось получить количество баров на ",_Symbol);

}

Смотри также

Функции обработки событий

Доступ к таймсериям и индикаторам

539

BarsCalculated

Возвращает количество рассчитанных данных для запрашиваемого индикатора.

int BarsCalculated(

int indicator_handle, // handle индикатора

);

Параметры

indicator_handle

[in] Хэндл индикатора, полученный соответствующей индикаторной функцией.

Возвращаемое значение

Возвращает количество рассчитанных данных в индикаторном буфере или -1 в случае ошибки

(данные еще не рассчитаны).

Примечание

Функция полезна в тех случаях, когда необходимо получить данные индикатора сразу после его

создания (получения хэндла индикатора).

Пример:

void OnStart()

{

double Ups[];

//--- установим для массивов признак таймсерии

ArraySetAsSeries(Ups,true);

//--- создадим хэндл индикатора Fractals

int FractalsHandle=iFractals(NULL,0);

//--- сбросим код ошибки

ResetLastError();

//--- попытаемся скопировать значения индикатора

int i,copied=CopyBuffer(FractalsHandle,0,0,1000,Ups);

if(copied<=0)

{

Sleep(50);

for(i=0;i<100;i++)

{

if(BarsCalculated(FractalsHandle)>0)

break;

Sleep(50);

}

copied=CopyBuffer(FractalsHandle,0,0,1000,Ups);

if(copied<=0)

{

Print("Не удалось скопировать верхние фракталы. Error = ",GetLastError(),

"i=",i," copied= ",copied);

return;

}

else

Print("Удалось скопировать верхние фракталы.",

" i = ",i," copied = ",copied);

}

else Print("Удалось скопировать верхние фракталы. ArraySize = ",ArraySize(Ups));

}

Доступ к таймсериям и индикаторам

540

IndicatorCreate

Возвращает хэндл указанного технического индикатора, созданного на основе массива

параметров типа MqlParam.

int IndicatorCreate(

string symbol, // имя символа

ENUM_TIMEFRAMES period, // период

ENUM_INDICATOR  indicator_id, // тип индикатора из перечисления ENUM_INDICATOR

int parameters_cnt=0, // количество параметров

const MqlParam& parameters_array[]=NULL, // массив параметров

);

Параметры

symbol

[in] Символьное имя инструмента, на данных которого будет вычисляться индикатор. NULL

означает текущий символ.

period

[in] Значение периода может быть одним из значений перечисления ENUM_TIMEFRAMES, 0

означает текущий таймфрейм.

indicator_id

[in] Тип индикатора, может принимать одно из значений перечисления ENUM_INDICATOR.

parameters_cnt

[in] Количество параметров, передаваемых в массиве parameters_array[]. Элементы массива

имеют специальный тип структуры MqlParam. По умолчанию нулевое значение - параметры не

передаются. Если указано ненулевое количество параметров, то параметр parameters_array

является обязательным. Можно передавать не более 256 параметров.

parameters_array[]=NULL

[in] Массив типа MqlParam, элементы которого содержат тип и значение каждого входного

параметра технического индикатора.

Возвращаемое значение

Возвращает хэндл указанного технического индикатора, в случае неудачи возвращает

INVALID_HANDLE.

Примечание

Если создается хэндл индикатора типа IND_CUSTOM, то поле type первого элемента массива

входных параметров parameters_array обязательно должен иметь значение TYPE_STRING из

перечисления ENUM_DATATYPE, а поле string_value первого элемента должно содержать имя

пользовательского индикатора. Пользовательский индикатор должен быть скомпилирован

(файл с расширением EX5) и находиться в директории MQL5/Indicators клиентского терминала

или вложенной поддиректории.

Если в пользовательском индикаторе используется первая форма вызова, то при передаче

входных параметров последним параметром можно дополнительно указать на каких данных он

будет рассчитываться. Если параметр "Apply to" не указан явно, то по умолчанию расчет

Справочник по языку программирования MQL5

Подождите немного. Документ загружается.