Ковалев Сергей. Программирование на алгоритмическом языке MQL4

911

if (Win_ind<0)return; // Если такого окна нет, уходим

//--------------------------------------------------------------- 4 --

if (Mess_Number==0) // Это происходит в каждом тике

{

if (Time_Mess==0) return; // Если уже крашено серым

if (GetTickCount()-Time_Mess>15000)// За 15 сек цвет устарел

{

for(int i=0;i<=29; i++) // Красим cтроки серым

ObjectSet( Name_Grf_Txt[i], OBJPROP_COLOR, Gray);

Time_Mess=0; // Флажок: все строки серые

WindowRedraw(); // Перерисовываем объекты

}

return; // Выход из функции

}

//--------------------------------------------------------------- 5 --

if (Mess_Number==-1) // Это происходит при deinit()

{

for(i=0; i<=29; i++) // По индексам объектов

ObjectDelete(Name_Grf_Txt[i]);// Удаление объекта

return; // Выход из функции

}

//--------------------------------------------------------------- 6 --

Nom_Mess_Graf++; // Счётчик графических сообщ.

Time_Mess=GetTickCount(); // Время последней публикации

Color_GT=Lime;

//--------------------------------------------------------------- 7 --

switch(Mess_Number) // Переход на сообщение

{

case 1:

Graf_Text="Закрыт ордер Buy "+ Number;

PlaySound("Close_order.wav"); break;

case 2:

Graf_Text="Закрыт ордер Sell "+ Number;

PlaySound("Close_order.wav"); break;

case 3:

Graf_Text="Удалён отложенный ордер "+ Number;

PlaySound("Close_order.wav"); break;

case 4:

Graf_Text="Открыт ордер Buy "+ Number;

PlaySound("Ok.wav"); break;

case 5:

Graf_Text="Открыт ордер Sell "+ Number;

PlaySound("Ok.wav"); break;

case 6:

Graf_Text="Установлен отложенный ордер "+ Number;

PlaySound("Ok.wav"); break;

912

case 7:

Graf_Text="Ордер "+Number+" преобразовался в рыночный";

PlaySound("Transform.wav"); break;

case 8:

Graf_Text="Переоткрыт ордер "+ Number; break;

PlaySound("Bulk.wav");

case 9:

Graf_Text="Частично закрыт ордер "+ Number;

PlaySound("Close_order.wav"); break;

case 10:

Graf_Text="Новая минимальная дистанция: "+ Number;

PlaySound("Inform.wav"); break;

case 11:

Graf_Text=" Не хватает денег на "+

DoubleToStr(Value,2) + " лотов";

Color_GT=Red;

PlaySound("Oops.wav"); break;

case 12:

Graf_Text="Попытка закрыть ордер "+ Number;

PlaySound("expert.wav"); break;

case 13:

if (Number>0)

Graf_Text="Попытка открыть ордер Sell..";

else

Graf_Text="Попытка открыть ордер Buy..";

PlaySound("expert.wav"); break;

case 14:

Graf_Text="Неправильный пароль. Эксперт не работает.";

Color_GT=Red;

PlaySound("Oops.wav"); break;

case 15:

switch(Number) // Переход на номер ошибки

{

case 2: Graf_Text="Общая ошибка."; break;

case 129: Graf_Text="Неправильная цена. "; break;

case 135: Graf_Text="Цена изменилась. "; break;

case 136: Graf_Text="Нет цен. Ждём новый тик.."; break;

case 146: Graf_Text="Подсистема торговли занята";break;

case 5 : Graf_Text="Старая версия терминала."; break;

case 64: Graf_Text="Счет заблокирован."; break;

case 133: Graf_Text="Торговля запрещена"; break;

default: Graf_Text="Возникла ошибка " + Number;//Другие

}

Color_GT=Red;

PlaySound("Error.wav"); break;

case 16:

Graf_Text="Эксперт работает только на EURUSD";

913

Color_GT=Red;

PlaySound("Oops.wav"); break;

default:

Graf_Text="default "+ Mess_Number;

Color_GT=Red;

PlaySound("Bzrrr.wav");

}

//--------------------------------------------------------------- 8 --

ObjectDelete(Name_Grf_Txt[29]); // 29й(верхний) объект удаляем

for(i=29; i>=1; i--) // Цикл по индексам массива ..

{ // .. графических объектов

Name_Grf_Txt[i]=Name_Grf_Txt[i-1];// Поднимаем объекты:

ObjectSet( Name_Grf_Txt[i], OBJPROP_YDISTANCE, 2+15*i);

}

Name_Grf_Txt[0]="Inform_"+Nom_Mess_Graf+"_"+Symbol(); // Имя объект

ObjectCreate (Name_Grf_Txt[0],OBJ_LABEL, Win_ind,0,0);// Создаём

ObjectSet (Name_Grf_Txt[0],OBJPROP_CORNER, 3 ); // Угол

ObjectSet (Name_Grf_Txt[0],OBJPROP_XDISTANCE, 450);// Коорд. Х

ObjectSet (Name_Grf_Txt[0],OBJPROP_YDISTANCE, 2); // Коорд. Y

// Текстовое описание объекта

ObjectSetText(Name_Grf_Txt[0],Graf_Text,10,"Courier New",Color_GT);

WindowRedraw(); // Перерисовываем все объекты

return;

}

//--------------------------------------------------------------- 9 --

В блоке 2-3 описаны используемые в функции переменные. Для хранения имён

графических объектов используется массив Name_Grf_Txt. Согласно принятому в

функции методу для вывода каждого нового сообщения создаётся новый графический

объект. Общее количество объектов - 30, каждый объект представляет текстовую надпись,

располагаемую в одной строке. В случае большого разрешения экрана количество

выводимых строк сообщений можно увеличить путём увеличения количества

создаваемых объектов.

В блоке 3-4 вычисляется номер подокна индикатора "Inform", в которое выводятся

сообщения. Если индикатор не установлен, то функция прекращает работу. Отсутствие

окна не позволяет выводить сообщения, однако это не влияет на работоспособность

эксперта - все другие функции будут работать в обычном режиме, в том числе будут

осуществляться торговые операции.

В блоке 4-5 осуществляется анализ расцветки сообщений. Обращение к функции с

параметром Mess_Number=0 выполняется в эксперте на каждом тике (см. функцию start()

914

в эксперте usualexpert.mq4). Если в предыдущей истории все объекты уже обесцвечены (т.е.

все объекты серого цвета), то функция заканчивает работу. Если же значение переменной

Time_Mess не нулевое, то изменяются свойства всех объектов, а именно всем объектам

сообщается серый цвет.

В случае (блок 5-6), если при вызове функции указан параметр Mess_Number=-1, то все

объекты, ранее созданные при исполнении функции, удаляются. Такая необходимость

возникает при отключении эксперта из окна финансового инструмента. В этом случае, в

соответствии с общим правилом, каждая прикладная программа должна удалить все

объекты, созданные ею в период исполнения (см. функцию deinit() в эксперте

usualexpert.mq4).

Если управление в программе передаётся в блок 6-7, значит, необходимо создать новый

графический объект с нужными свойствами и расположить его в нижней части подокна

индикатора (в нижней строке; здесь термин "строка" - условный, в действительности

положение графических объектов определяется заданными координатами). Каждый вновь

создаваемый объект имеет уникальное имя. Для формирования имён объектов

используется исторический порядковый номер сообщения, поэтому в блоке 6-7

установлен счётчик сообщений (в дальнейшем значение переменной Nom_Mess_Graf

используется для формирования уникального имени, блок 8-9). Здесь же учитывается

время последней публикации и устанавливается основной цвет для новых сообщений

(зелёный).

Блок 7-8 состоит из оператора switch, управление внутри которого передаётся согласно

заданному при вызове функции значению параметра Mess_Number. В каждом из

вариантов case этого оператора переменной Graf_Text присваивается новое значение,

которое и является содержанием выводимого сообщения. Для некоторых сообщений

устанавливается собственный цвет, например, в случае вывода важного предупреждения

цвет может быть красным. Все сообщения сопровождаются звуком - исполнением

стандартной функции PlaySound() (см. Звуковые файлы).

Создание нового графического объекта и перемещение уже имеющихся объектов

осуществляется в блоке 8-9. Количество объектов ограничено, поэтому при публикации

каждого нового сообщения один их графических объектов (самый старый) удаляется. Все

другие, уже имеющиеся, объекты перемещаются на одну строку выше. Перемещение

объектов выполняется путём изменения их свойств - координат по вертикали. Координаты

объектов по горизонтали остаются неизменными.

915

После того как выполнены необходимые подготовительные действия (все объекты

подняты на одну строку вверх), создаётся новый объект с новым уникальным именем и со

свойствами, частично определёнными в блоке 7-8. Тип графического объекта - текстовая

метка. Объекты этого типа позиционируются относительно окна финансового

инструмента, что позволяет пользователю произвольно перемещать ценовой график, не

затрагивая этим действием положение надписей сообщений.

Вызов функции Inform() может осуществляться из любого места программы, где по

смыслу необходимо вывести очередное сообщение. В результате длительного

использования в окне накапливаются сообщения. Пользователь может посмотреть

историю сообщений, изменив размер подокна индикатора (например, подняв его верхнюю

границу). По желанию пользователя, можно также установить высоту окна таким образом,

чтобы видимого пространства хватало для отображения необходимого количества строк

сообщений (рекомендуется три - четыре строки).

Рис. 156. Окно финансового инструмента. Сообщения в подокне индикатора.

Легко заметить, что разнообразие сообщений, выводимых функцией, может быть

увеличено. В случае если предполагается расширять программу, достаточно добавить

новый вариант case в операторе switch (блок 7-8).

13.4 Функция слежения за событиями

В период проведения торгов происходит множество различных событий. Некоторые из

них трейдер может наблюдать непосредственно в окне финансового инструмента,

916

например, динамику изменения рыночных цен или пересечение индикаторных линий.

Другие события, хотя и представляют интерес для трейдера, но в явном виде нигде не

отображаются. Значительная часть этих событий может быть вычислена и обработана

средствами языка MQL4.

Например, незадолго до выхода важных новостей или при сильном движении цен

дилинговый центр может изменить условия торговли. В подобных случаях может быть

увеличен спред или минимально допустимая дистанция для установки ордеров и

заявленных цен стоп-приказов. В случае, если это происходит, необходимо, во-первых,

обнаружить и принять во внимание новые условия торговли, и во-вторых, поставить в

известность трейдера о возникших изменениях.

Для решения этих задач в эксперте используется функция слежения за событиями.

13.4.1 Пользовательская функция Events()

int Events()

Функция вычисляет изменение минимальной дистанции для установки ордеров и их стоп-

приказов, а также изменения в составе рыночных и отложенных ордеров. Для исполнения

функции требуется применение в программе функции учёта ордеров Terminal().

Используются значения глобальных массивов:

Mas_Ord_New - массив характеристик ордеров на момент последнего исполнения

функции Terminal();

Mas_Ord_Old - массив характеристик ордеров на момент предыдущего исполнения

функции Terminal().

Используются значения глобальных переменных:

- Level_new - текущее значение минимальной дистанции;

- Level_old - предыдущее значение минимальной дистанции.

Для вывода сообщений функция предполагает использование информационной функции

Inform(). В случае, если функция Inform() не включена в эксперт, сообщения не выводятся.

Функция слежения за событиями Events() оформлена в виде включаемого файла

Events.mqh:

//--------------------------------------------------------------------

// Events.mqh

// Предназначен для использования в качестве примера в учебнике MQL4.

917

//--------------------------------------------------------------- 1 --

// Функция слежения за событиями.

// Глобальные переменные:

// Level_new Новое значение минимальной дистанции

// Level_old Предыдущее значение минимальной дистанции

// Mas_Ord_New[31][9] Массив ордеров последний известный

// Mas_Ord_Old[31][9] Массив ордеров предыдущий (старый)

//--------------------------------------------------------------- 2 --

int Events() // Пользовательская функция

{

bool Conc_Nom_Ord; // Совпадение ордеров в ..

//.. старом и новом массивах

//--------------------------------------------------------------- 3 --

Level_new=MarketInfo(Symbol(),MODE_STOPLEVEL );// Последн.известное

if (Level_old!=Level_new) // Новое не равно старому..

{ // значит изменились условия

Level_old=Level_new; // Новое "старое значение"

Inform(10,Level_new); // Сообщение: новая дистанц.

}

//--------------------------------------------------------------- 4 --

// Поиск пропавших, поменявших тип, частично закрытых и переоткрытых

for(int old=1;old<=Mas_Ord_Old[0][0];old++)// По массиву старых

{ // Исходим из того, что..

Conc_Nom_Ord=false; // ..ордера не совпадают

//--------------------------------------------------------- 5 --

for(int new=1;new<=Mas_Ord_New[0][0];new++)//Цикл по массиву ..

{ //..новых ордеров

//------------------------------------------------------ 6 --

if (Mas_Ord_Old[old][4]==Mas_Ord_New[new][4])// Совпал номер

{ // Тип ордера стал ..

if (Mas_Ord_New[new][6]!=Mas_Ord_Old[old][6])//.. другим

Inform(7,Mas_Ord_New[new][4]);// Сообщение: преобраз.:)

Conc_Nom_Ord=true; // Ордер найден, ..

break; // ..значит выходим из ..

} // .. внутреннего цикла

//------------------------------------------------------ 7 --

// Не совпал номер ордера

if (Mas_Ord_Old[old][7]>0 && // MagicNumber есть, совпал

Mas_Ord_Old[old][7]==Mas_Ord_New[new][7])//.. со старым

{ //значит он переоткрыт или частично закрыт

// Если лоты совпадают,..

if (Mas_Ord_Old[old][5]==Mas_Ord_New[new][5])

Inform(8,Mas_Ord_Old[old][4]);// ..то переоткрытие

else // А иначе это было..

Inform(9,Mas_Ord_Old[old][4]);// ..частичное закрытие

Conc_Nom_Ord=true; // Ордер найден, ..

918

break; // ..значит выходим из ..

} // .. внутреннего цикла

}

//--------------------------------------------------------- 8 --

if (Conc_Nom_Ord==false) // Если мы сюда дошли,..

{ // ..то ордера нет:(

if (Mas_Ord_Old[old][6]==0)

Inform(1, Mas_Ord_Old[old][4]); // Ордер Buy закрыт

if (Mas_Ord_Old[old][6]==1)

Inform(2, Mas_Ord_Old[old][4]); // Ордер Sell закрыт

if (Mas_Ord_Old[old][6]> 1)

Inform(3, Mas_Ord_Old[old][4]); // Отложен. ордер удалён

}

//--------------------------------------------------------------- 9 --

// Поиск новых ордеров

for(new=1; new<=Mas_Ord_New[0][0]; new++)// По массиву новых орд.

{

if (Mas_Ord_New[new][8]>0) //Это не новый,а переоткр

continue; //..или частично закрытый

Conc_Nom_Ord=false; // Пока совпадения нет

for(old=1; old<=Mas_Ord_Old[0][0]; old++)// Поищем этот ордерок

{ // ..в массиве старых

if (Mas_Ord_New[new][4]==Mas_Ord_Old[old][4])//Совпал номер..

{ //.. ордера

Conc_Nom_Ord=true; // Ордер найден, ..

break; // ..значит выходим из ..

} // .. внутреннего цикла

}

if (Conc_Nom_Ord==false) // Если совпадения нет,..

{ // ..то ордер новый :)

if (Mas_Ord_New[new][6]==0)

Inform(4, Mas_Ord_New[new][4]); // Ордер Buy открыт

if (Mas_Ord_New[new][6]==1)

Inform(5, Mas_Ord_New[new][4]); // Ордер Sell открыт

if (Mas_Ord_New[new][6]> 1)

Inform(6, Mas_Ord_New[new][4]); // Установлен отлож.ордер

}

//-------------------------------------------------------------- 10 --

return;

}

//-------------------------------------------------------------- 11 --

919

В блоке 1-2 описаны глобальные массивы и переменные, необходимые для исполнения

функции. В блоке 2-3 открыта переменная Conc_Nom_Ord, используемая в дальнейшем

коде для анализа состава ордеров.

Функция отслеживает изменение минимальной дистанции для установки ордеров и стоп-

приказов. Для этого при каждом исполнении функции (блок 3-4) сначала вычисляется

текущее значение минимальной дистанции Level_new, а затем оно сравнивается с

предыдущим значением минимальной дистанции Level_old (полученным в период

предыдущего исполнения функции). Если значения этих переменных не равны, значит

незадолго до последнего исполнения функции минимальная дистанция была изменена

дилинговым центром. В этом случае переменной Level_old присваивается текущее

значение минимальной дистанции (чтобы учесть при последующих исполнениях

функции) и исполняется функция Inform() с целью вывести необходимое сообщение.

В общем случае аналогичным способом возможно выявить и другие события, например,

изменение спреда, разрешение торгов по указанному инструменту (идентификатор

MODE_TRADEALLOWED в функции MarketInfo()), факт образования нового бара (см.

Задачу 27), факт пересечения индикаторных линий (см. Рис. 107), факт достижения

некоторого заданного времени и пр. Некоторые события можно отслеживать с целью

использования полученных значений в эксперте, другие - для того, чтобы информировать

пользователя.

В блоках 4-10 выполняется анализ состояния рыночных и отложенных ордеров.

Информация о большинстве событий, связанных с изменениями ордеров, доводится до

сведения пользователя. Анализ выполняется в два этапа. На первом этапе выявляются

изменения, касающиеся пропавших (закрытых или удалённых), поменявших тип,

частично закрытых и переоткрытых ордеров (блок 4-9). На втором этапе (блок 9-10)

осуществляется поиск новых ордеров.

В блоке 4-9 производится анализ ордеров, учтённых в массиве Mas_Ord_Old. Количество

итераций во внешнем цикл for устанавливается в соответствии с общим количеством

ордеров в этом массиве (элемент массива Mas_Ord_Old[0][0]). Для того чтобы определить,

сохранился ли ордер на текущий момент, необходимо найти аналогичный ордер в массиве

ордеров Mas_Ord_New. Этот поиск выполняется во внутреннем цикле for (блок 6-8),

количество итераций которого равно количеству ордеров в массиве (элемент массива

Mas_Ord_New[0][0]). В дальнейшем изложении массив Mas_Ord_Old именуется старым

массивом, а Mas_Ord_New - новым.

920

В блоках 6-8 выполняется поиск только тех ордеров, характеристики которых отличаются.

Например, в блоке 6-7 производится проверка ордера по его номеру (см. соответствие

индексов массивов характеристикам ордеров в Таблице 4). Если исследуемый ордер из

старого массива совпал по номеру с одним из ордеров нового массива, то этот ордер, по

крайней мере не закрыт (или удалён). При этом необходимо выяснить также, не

поменялся ли тип ордера. И если тип ордера изменился, значит отложенный ордер

преобразовался в рыночный. В этом случае с помощью функции Inform() выводится

необходимое сообщение. Независимо от факта изменения (или сохранения) типа ордера

дальнейшие исследования этого ордера прекращаются: осуществляется выход из

внутреннего цикла и, в конечном счёте, начало новой итерации внешнего цикла.

Если при исполнении блока 6-7 обнаружено, что исследуемый ордер из старого массива

не совпал по номеру ни с одним из ордеров нового массива, то управление передаётся в

блок 7-8. Здесь выясняется, есть ли у текущего ордера из нового массива ненулевой

MagicNumber (все ордера, открываемые и устанавливаемые экспертом, имеют ненулевой

MagicNumber). Если MagicNumber есть и он совпадает с MagicNumber исследуемого

ордера из старого массива, значит исследуемый ордер присутствует в торговле, но

претерпел какие-то преобразования. Преобразования, связанные с изменением номера

ордера, возникают в двух случаях.

Случай 1. Если ордер частично закрыт. Частичное закрытие рыночного ордера (для

отложенных ордеров не предусмотрено) в соответствии с технологией, принятой в среде

МТ4, выполняется в два этапа. На первом этапе полностью закрывается исходный ордер в

полном объёме. В этот же момент открывается новый рыночный ордер в объёме

остаточной стоимости, с тем же курсом открытия и заявленными ценами стоп-приказов,

что и у исходного. Этот новый ордер получает свой уникальный номер ордера, не

совпадающий с номером исходного частично закрываемого ордера.

Случай 2. Если ордер переоткрыт дилинговым центром. Некоторые банки (в связи со

специфическим порядком внутреннего учёта) в конце каждого рабочего дня

принудительно закрывают все рыночные ордера и в тот же момент открывают рыночные

ордера того же типа на то же количество лотов, но уже по текущему курсу за вычетом

свопа. Это событие не оказывает никакого влияния на экономический результат по

игровому счёту. Каждый из вновь открытых ордеров также получает свой уникальный

номер, не совпадающий с номерами закрытых ордеров.

Ковалев Сергей. Программирование на алгоритмическом языке MQL4

Подождите немного. Документ загружается.