Ковалев Сергей. Программирование на алгоритмическом языке MQL4
Подождите немного. Документ загружается.
891
Функция Краткое описание
Ошибки
исполнения
Любая торговая операция (функции OrderSend, OrderClose,
OrderCloseBy, OrderDelete или OrderModify) по ряду причин
может завершиться неудачей и вернуть либо отрицательный
номер тикета, либо FALSE. Причину неудачи можно выяснить,
вызвав функцию GetLastError. Каждая ошибка должна быть
обработана по-своему. Ниже в таблице приведены общие
рекомендации.
OrderClose Закрытие позиции. Возвращает TRUE при успешном завершении
функции. Возвращает FALSE при неудачном завершении
функции.
OrderCloseBy Закрытие одной открытой позиции другой позицией, открытой
по тому же самому инструменту, но в противоположном
направлении. Возвращает TRUE при успешном завершении
функции. Возвращает FALSE при неудачном завершении
функции.
OrderClosePrice Возвращает цену закрытия выбранного ордера.
OrderCloseTime Возвращает время закрытия для выбранного ордера.
OrderComment Возвращает комментарий для выбранного ордера.
OrderCommission Возвращает значение рассчитанной комиссии для выбранного
ордера.
OrderDelete Удаляет ранее установленный отложенный ордер. Возвращает
TRUE при успешном завершении функции. Возвращает FALSE
при неудачном завершении функции.
892
OrderExpiration Возвращает дату истечения для выбранного отложенного ордера.
OrderLots Возвращает количество лотов для выбранного ордера.
OrderMagicNumber
Возвращает идентификационное ("магическое") число для
выбранного ордера.
OrderModify Изменяет параметры ранее открытых позиций или отложенных
ордеров. Возвращает TRUE при успешном завершении функции.
Возвращает FALSE при неудачном завершении функции.
OrderOpenPrice Возвращает цену открытия для выбранного ордера.
OrderOpenTime Возвращает время открытия выбранного ордера.
OrderPrint Выводит данные ордера в журнал.
OrderProfit Возвращает значение чистой прибыли (без учёта свопов и
комиссий) для выбранного ордера. Для открытых позиций это -
текущая нереализованная прибыль. Для закрытых ордеров -
зафиксированная прибыль.
OrderSelect Функция выбирает ордер для дальнейшей работы с ним.
Возвращает TRUE при успешном завершении функции.
Возвращает FALSE при неудачном завершении функции.
OrderSend Основная функция, используемая для открытия позиции или
установки отложенного ордера. Возвращает номер тикета,
который назначен ордеру торговым сервером или -1 в случае
неудачи.
OrdersHistoryTotal Возвращает количество закрытых позиций и удаленных ордеров
893
в истории текущего счета, загруженной в клиентском терминале.
OrderStopLoss Возвращает значение цены закрытия позиции при достижении
уровня убыточности (stop loss) для текущего выбранного ордера.
OrdersTotal Возвращает общее количество открытых и отложенных ордеров.
OrderSwap Возвращает значение свопа для текущего выбранного ордера.
OrderSymbol Возвращает наименование финансового инструмента для
текущего выбранного ордера.
OrderTakeProfit Возвращает значение цены закрытия позиции при достижении
уровня прибыльности (take profit) для текущего выбранного
ордера.
OrderTicket Возвращает номер тикета для текущего выбранного ордера.
OrderType Возвращает тип операции текущего выбранного ордера.
Для получения подробного описания этих и других функций необходимо обратиться к
справочной документации на MQL4.community, сайте MetaQuotes Software Corp. или к
разделу "Справка" в редакторе MetaEditor
Для получения подробного описания любой стандартной функции необходимо обратиться
к справочной документации на MQL4.community, сайте MetaQuotes Software Corp. или к
разделу "Справка" в редакторе MetaEditor
13 Построение обычных программ
894
Как правило, после самостоятельного программирования нескольких простых прикладных
программ на MQL4, программист переходит к более сложному проекту - созданию
удобной программы для практического использования. Простые программы в ряде
случаев не удовлетворяют потребностям трейдера-программиста по крайней мере по двум
причинам:
1. Функциональная ограниченность простых программ не позволяет в полной мере
обеспечить трейдера необходимой информацией и средствами управления торговлей, что
делает их применение недостаточно эффективным.
2. Несовершенство кода простых программ затрудняет возможность дальнейшего их
наращивания с целью получения большего сервиса.
В данном разделе представлен один из возможных вариантов реализации торгующего
эксперта, который может рассматриваться как основа для создания собственного проекта.
13.1 Структура обычной программы
Основной отличительной особенностью обычной программы является её структура,
позволяющая легко применять те или иные пользовательские функции. Обычно для
удобства пользовательские функции оформляются в виде включаемых файлов (.mqh),
которые хранятся в каталоге Каталог_терминала\experts\include.
Как правило, обычная программа содержит все три специальные функции, которые
вызывают для исполнения необходимые пользовательские функции. Пользовательские
функции, в свою очередь, могут вызывать для исполнения другие пользовательские
функции, при этом каждая из них имеет своё функционально ограниченное назначение.
В составе эксперта могут применяться пользовательские функции с самыми
разнообразными свойствами. Одни функции, например, предназначены для отслеживания
событий и удобного вывода информации, другие - для формирования торговых приказов,
третьи - для различных вычислений, например, определения торговых критериев,
вычисления стоимости ордеров и т.д. Решение о том, какие функции использовать в
программе, зависит от назначения эксперта и от того, какой сервис программа должна
предоставлять пользователю. На рис. 155 приведена структурная схема обычного
торгующего эксперта, построенного на небольшом наборе пользовательских функций.
895
Рис. 155. Структурная схема обычной программы (эксперт).
Стрелками на структурной схеме показаны связи между различными функциями.
Например, функция учёта ордеров вызывается в эксперте из специальной функции init(),
специальной функции start(), а также может быть вызвана из любого другого места
программы. В правой части схемы показаны стрелки связей, символизирующие
возможность вызова одной пользовательской функции из другой. Например, функция
определения торговых критериев не вызывается ни из одной специальной функции, но
может быть вызвана для исполнения торговой функцией. Информационная функция
вызывается из специальной функции deinit(), а также при необходимости вызывается
другими функциями, например, функцией обработки ошибок, торговыми функциями,
функцией слежения за событиями. Включаемый файл объявления переменных не
вызывается ни из одной функции, потому что имеющийся в нём код не является
описанием функции, которая может быть вызвана и исполнена. Этот файл содержит
строки объявления глобальных переменных, поэтому просто является составной частью
эксперта. Для того чтобы понять, каким образом различные части эксперта
896
взаимодействуют между собой, рассмотрим порядок создания и использования
включаемых файлов.
13.1.1 Использование включаемых файлов
Если прикладная программа содержит множество программных строк, то её отладка
бывает затруднительной - программисту приходится многократно прокручивать текст
программы, чтобы внести изменения в код в том или ином месте. В подобных случаях для
удобства программа может быть разделена на несколько фрагментов, каждый из которых
оформляется в виде отдельного включаемого файла. Включаемые файлы могут содержать
любой фрагмент кода, который предполагается использовать в программе. Обычно
каждая используемая в программе функция оформляется в виде включаемого файла. Если
несколько функций логически связаны между собой, то содержанием одного включаемого
файла может быть описание нескольких пользовательских функций.
В разделе Информация о счёте рассматривался пример защитного кода,
предотвращающего несанкционированное использование коммерческих программ. В
эксперте check.mq4 соответствующая часть программного кода представлена в виде
пользовательской функции Check(), описание которой содержится непосредственно в
исходном тексте эксперта. В эксперте usualexpert.mq4 (см. рис. 91.3) также используется
эта функция, но в этом случае функция оформлена в виде включаемого файла Check.mqh.
13.1.2 Пользовательская функция Check()
bool Check()
Функция возвращает TRUE, если соблюдены условия использования прикладной
программы, возвращает FALSE, если условия не соблюдены.
Условия использования программы считаются выполненными, если:
программа используется на демо-счёте;
счёт открыт в компании SuperBank;
при работе на реальном счёте пользователь установил правильное значение внешней
переменной Parol.
Включаемый файл Check.mqh, содержащий описание пользовательской функции Check():
897
//--------------------------------------------------------------------
// Check.mqh
// Предназначен для использования в качестве примера в учебнике MQL4.
//--------------------------------------------------------------- 1 --
// Функция проверки легальности использования программы
// Входные параметры:
// - глобальная переменная Parol
// - локальная константа "SuperBank"
// Возвращаемые значения:
// true - если условия использования соблюдены
// false - если условия использования нарушены
//--------------------------------------------------------------- 2 --
extern int Parol=12345; // Пароль для работы на реальном счёте
//--------------------------------------------------------------- 3 --
bool Check() // Пользовательская функция
{
if (IsDemo()==true) // Если это демо-счёт, то..
return(true); // .. других ограничений нет
if (AccountCompany()=="SuperBank") // Для корпоративных клиентов..
return(true); // ..пароль не нужен
int Key=AccountNumber()*2+1000001; // Вычисляем ключ
if (Parol==Key) // Если пароль верный, то..
return(true); // ..разрешаем работу на реале
Inform(14); // Сообщение о несанкц. работе
return(false); // Выход из пользов. функции
}
//--------------------------------------------------------------- 4 --
Легко заметить, что название включаемого файла совпадает с названием содержащейся в
нём функции. Правилами языка MQL4 такое требование не предусмотрено. В общем
случае название включаемого файла не обязательно должно совпадать с названием
функции, которая в нём содержится. Тем более это понятно, если учесть, что один файл
может нести описание нескольких функций или какого-либо фрагмента программы,
вообще не являющегося функцией. Однако практика присваивать включаемому файлу
имя, совпадающее с именем описанной в нём функции, оправданна. При этом значительно
облегчается труд программиста: он легко может понять, какие функции имеются в
каталоге Каталог_терминала\experts\include, ориентируясь по именам файлов. Для того
чтобы фрагмент программы, содержащийся в файле, включить в программу, используется
директива #include.
13.1.3 Директива #include
898
#include <Имя файла>
#include "Имя файла"
Директива #include может быть указана в любом месте программы, но обычно все
включения размешаются в начале файла исходного текста. Препроцессор заменяет строку
#include <имя_файла> (или строку #include "имя_файла") содержимым файла с указанным
именем.
Угловые скобки обозначают, что файл будет взят из стандартного каталога
Каталог_терминала\experts\include (текущий каталог не просматривается). Если имя
файла заключено в кавычки, то поиск производится в текущем каталоге, а именно в том, в
котором содержится основной файл исходного текста (стандартный каталог не
просматривается).
Ниже представлен обычный эксперт usualexpert.mq4. Все включаемые файлы размещены
в головной части программы.
//--------------------------------------------------------------------
// usualexpert.mq4
// Предназначен для использования в качестве примера в учебнике MQL4.
//--------------------------------------------------------------- 1 --
#property copyright "Copyright © Book, 2007"
#property link "http://AutoGraf.dp.ua"
//--------------------------------------------------------------- 2 --
#include <stdlib.mqh>
#include <stderror.mqh>
#include <WinUser32.mqh>
//--------------------------------------------------------------- 3 --
#include <Variables.mqh> // Описание переменных
#include <Check.mqh> // Проверка легальности использов. программ
#include <Terminal.mqh> // Учёт ордеров
#include <Events.mqh> // Функция слежения за событиями, обновлен.
#include <Inform.mqh> // Информационная функция
#include <Trade.mqh> // Торговая функция
#include <Open_Ord.mqh> // Открытие одного ордера заданного типа
#include <Close_All.mqh> // Закрытие всех ордеров заданного типа
#include <Tral_Stop.mqh> // Модификация StopLoss всех ордеров типа
#include <Lot.mqh> // Вычисление количества лотов
#include <Criterion.mqh> // Торговые критерии
#include <Errors.mqh> // Функция обработки ошибок.
//--------------------------------------------------------------- 4 --
int init() // Спец. функция init
{
899
Level_old=MarketInfo(Symbol(),MODE_STOPLEVEL );//Миним. дистаниция
Terminal(); // Функция учёта ордеров
return; // Выход из init()
}
//--------------------------------------------------------------- 5 --
int start() // Спец. функция start
{
if(Check()==false) // Если условия использования..
return; // ..не выполняются, то выход
PlaySound("tick.wav"); // На каждом тике
Terminal(); // Функция учёта ордеров
Events(); // Информация о событиях
Trade(Criterion()); // Торговая функция
Inform(0); // Для перекрашивания объектов
return; // Выход из start()
}
//--------------------------------------------------------------- 6 --
int deinit() // Спец. функция deinit()
{
Inform(-1); // Для удаления объектов
return; // Выход из deinit()
}
//--------------------------------------------------------------- 7 --
В блоке 2-3 с помощью директивы #include в программу включены стандартные файлы
stdlib.mqh, stderror.mqh и WinUser32.mqh. Использование этих файлов в программе бывает
необходимо не всегда. Например, файл stderror.mqh содержит определение стандартных
констант, используемых при обработке ошибок. Если в программе не предусмотрен
анализ ошибок (указанные константы не используются), то включать этот фал в исходный
текст нет необходимости. Вместе с тем, в обычной программе, как правило, требуется
использование указанных файлов.
В блоке 3-4 в программу включены несколько файлов, содержащих описание
пользовательских функций. В том числе, с помощью директивы #include, в строке:
#include <Check.mqh> // Проверка легальности использов. программ
в исходный текст программы включается пользовательская функция Check().
Программист видит исходный текст эксперта (в данном случае - usualexpert.mq4) таким,
каким он представлен выше. Однако при компиляции исходный текст программы
преобразуется, а именно: вместо каждой строки, содержащей директиву #include, в
программу вставляется текст, содержащийся в файле с указанным именем. Таким
образом, исполняемый файл .ex4 создаётся на основе полного кода эксперта, в котором
900
вместо каждой строки #include<Имя файла> (или #include "Имя файла") содержится
соответствующий фрагмент кода.
Примером включаемого файла, в котором содержится некоторый фрагмент программы, не
являющийся описанием функции, может служить файл Variables.mqh. Этот файл
включается в текст программы в строке:
#include <Variables.mqh> // Описание переменных
и содержит описание глобальных переменных, которые используются различными
пользовательскими функциями.
//--------------------------------------------------------------------
// Variables.mqh
// Предназначен для использования в качестве примера в учебнике MQL4.
//--------------------------------------------------------------- 1 --
// Описание глобальных переменных
extern double Lots = 0.0;// Количество лотов
extern int Percent = 0; // Процент выделенных средств
extern int StopLoss =100; // StopLoss для новых ордеров (пунктов)
extern int TakeProfit =40; // TakeProfit для новых ордеров (пунктов)
extern int TralingStop=100; // TralingStop для рыночных ордеров (пунк)
//--------------------------------------------------------------- 2 --
int
Level_new, // Новое значение минимальной дистанции
Level_old, // Предыдущее значение минимальной дистанции
Mas_Tip[6]; // Массив типов ордеров
// [] тип орд: 0=B,1=S,2=BL,3=SL,4=BS,5=SS
//--------------------------------------------------------------- 3 --
double
Lots_New, // Количество лотов для новых ордеров
Mas_Ord_New[31][9], // Массив ордеров текущий ..
Mas_Ord_Old[31][9]; // .. и старый
// 1й индекс = порядковый номер ордера
// [][0] не определяется
// [][1] курс откр. ордера (абс.знач.курса)
// [][2] StopLoss ордера (абс.знач.курса)
// [][3] TakeProfit ордера (абс.знач.курса)
// [][4] номер ордера
// [][5] колич. лотов орд. (абс.знач.курса)
// [][6] тип орд. 0=B,1=S,2=BL,3=SL,4=BS,5=SS
// [][7] магическое число ордера
// [][8] 0/1 факт наличия комментария
//--------------------------------------------------------------- 4 --