Ковалев Сергей. Программирование на алгоритмическом языке MQL4
Подождите немного. Документ загружается.
131
{
Alert ("Сработала ф-ия init() при запуске"); // Сообщение
return; // Выход из init()
}
//--------------------------------------------------------------------
int start() // Спец. ф-ия start()
{
double Price = Bid; // Локальная перемен.
My_Function(); // Вызов польз. ф-ии
Alert("Новый тик ",Count," Цена = ",Price);// Сообщение
return; // Выход из start()
}
//--------------------------------------------------------------------
int deinit() // Спец. ф-ия deinit()
{
Alert ("Сработала ф-ия deinit() при выгрузке");// Сообщение
return; // Выход из deinit()
}
//--------------------------------------------------------------------
int My_Function() // Описание польз.ф-ии
{
Count++; // Счётчик обращений
}
//--------------------------------------------------------------------
Прежде всего, посмотрим, какие внесены изменения и какая часть кода осталась
нетронутой.
Остались без изменений:
1. Головная часть осталась без изменений.
// userfunction.mq4
// Предназначен для использования в качестве примера в учебнике MQL4.
//--------------------------------------------------------------------
int Count=0; // Глобальная перемен.
2. Специальная функция init() осталась без изменений.
int init() // Спец. ф-ия init()
{
Alert ("Сработала ф-ия init() при запуске"); // Сообщение
return; // Выход из init()
}
3. Специальная функция deinit() осталась без изменений.
132
int deinit() // Спец. ф-ия deinit()
{
Alert("Сработала ф-ия deinit() при выгрузке");// Сообщение
return; // Выход из deinit()
}
Изменения:
1. Добавилась пользовательская функция My_Function().
int My_Function() // Описание польз.ф-ии
{
Count++; // Счётчик обращений
}
2. Претерпел изменение код специальной функции start(): в нём появилось обращение к
пользовательской функции, а также отсутствует строка вычисления переменной Count.
int start() // Спец. ф-ия start()
{
double Price = Bid; // Локальная перемен.
My_Function(); // Вызов польз. ф-ии
Alert("Новый тик ",Count," Цена = ",Price);// Сообщение
return; // Выход из start()
}
В разделе Выполнение программы рассматривался порядок исполнения специальных
функций init() и deinit(). В данном примере исполнение этих функций будет происходить
так же, поэтому здесь нет необходимости останавливаться на их работе. Рассмотрим
исполнение специальной функции start() и пользовательской функции My_Function().
Описание пользовательской функции расположено за пределами всех специальных
функций, как и должно быть. Вызов пользовательской функции указан в коде
специальной функции start(), что тоже верно.
После того, как исполнится специальная функция init(), программа будет исполняться так:
31. Специальная функция start() находится в ожидании запуска клиентским терминалом. С
приходом нового тика терминал запустит функцию start() на исполнение, в результате
чего произойдут следующие события:
32 (1). В строке
double Price = Bid; // Локальная перемен.
производятся те же действия:
133
32.1(1). Инициализация локальной переменной Price (см. Виды переменных). Значение
этой локальной переменной будет доступно из любого места специальной функции start().
32.2(1). Выполнение оператора присваивания. Переменной Price будет присвоено
последнее известное значение текущей цены Bid (например, на первом тике цена
финансового инструмента окажется равной 1.2744).
33(1). Следующей записью в коде является обращение к пользовательской функции
My_Function():
My_Function(); // Вызов польз. ф-ии
Эта строка будет исполнена в рамках продолжающейся работы специальной функции
start(). Результатом выполнения этой части кода (обращение к пользовательской функции)
будет передача управления в тело (описание) пользовательской функции с последующим
возвратом управления в место вызова.
34(1). В описании пользовательской функции имеется всего один оператор:
Count++;
При первом вызове пользовательской функции значение переменной Count равно нулю. В
результате выполнения оператора Count++ значение переменной Count будет увеличено
на единицу. Исполнив этот оператор (единственный и последний) пользовательская
функция заканчивает свою работу и передаёт управление в то место, откуда она была
вызвана.
Необходимо подчеркнуть, что пользовательские функции могут быть вызваны для работы
только из специальных функций ( или из других пользовательских, которые в конечном
счёте всё равно вызваны из специальных). Поэтому справедливым является утверждение,
что в любой текущий момент работает одна из специальных функций (или специальная
функция start() может находиться в состоянии ожидания нового тика - запуска её на
исполнение клиентским терминалом), а пользовательские функции исполняются лишь в
рамках исполнения специальных функций.
В данном случае управление возвращается в (исполняющуюся) специальную функцию
start(), а именно в строку, следующую за оператором вызова функции:
35(1). В этой строке содержится вызов функции Alert():
Alert ("Новый тик ",Count," Цена = ",Price);// Сообщение
134
Функция Alert() выведет в окно сообщения все константы и переменные, перечисленные в
круглых скобках:
Новый тик 1 Цена = 1.2744
36(1). Оператор
return; // Выход из start()
заканчивает работу специальной функции start().
37. Управление передаётся клиентскому терминалу на ожидание нового тика.
При следующих исполнениях специальной функции start() переменные получат новые
значения и снова будут выведены в окно сообщения функции Alert(), т.е. программа снова
выполнится по пп 32 - 36. В том числе, при каждом исполнении функции start() (на
каждом тике) будет срабатывать обращение к пользовательской функции My_Function(), и
эта функция будет выполняться. Исполнение специальной функции start() будет
продолжаться до тех пор, пока пользователь не примет решение о прекращении работы
программы. В этом случае отработает специальная функция deinit() и программа
прекратит свою работу.
Запущенная на исполнение программа userfunction.ех4 отобразит на экране окно, в
котором будут выводиться сообщения функции Alert(). Обратите внимание, результат
работы программы будет таким же, как и результат работы простого эксперта simple.mq4.
Легко увидеть, что структура программы userfunction.mq4 составлена в соответствии с
обычным порядком расположения функциональных блоков. Если же этот порядок
изменить на другой допустимый порядок, то результат работы программы не изменится.
135
7 Операторы
В разделе представлены правила форматирования и исполнения операторов,
используемых в языке MQL4. В каждом параграфе приводятся простые примеры,
демонстрирующие исполнение операторов. С целью полного усвоения материала все
представленные программы рекомендуется скомпилировать и запустить на исполнение.
Это позволит также закрепить навыки работы с редактором MetaEditor.
7.1 Оператор присваивания
Оператор присваивания - самый простой и наиболее распространённый оператор.
7.1.1 Формат оператора присваивания
Оператор присваивания представляет собой запись, содержащую символ = (знак
равенства), слева от которого указано имя переменной, а справа - выражение. Оператор
присваивания заканчивается знаком ; (точка с запятой).
Переменная = Выражение; // Оператор присваивания
Оператор присваивания можно отличить в тексте программы по наличию знака равенства.
В качестве выражения может быть указана константа, переменная, вызов функции или
собственно выражение.
7.1.2 Правило исполнения оператора присваивания
Вычислить значение выражения справа от знака равенства и полученное
значение присвоить переменной, указанной слева от знака равенства.
Оператор присваивания, как и любой другой оператор, является исполняемым. Это
значит, что запись, составляющая оператор присваивания, исполняется в соответствии с
136
правилом. При исполнении оператора присваивания вычисляется значение в правой части,
а затем это значение присваивается переменной слева от знака равенства. В результате
исполнения оператора присваивания переменная в левой части всегда получает новое
значение; это значение может отличаться или совпадать с предыдущим значением этой
переменной. Вычисление выражения в правой части оператора присваивания
осуществляется в соответствии с порядком вычисления выражений (см. Операции и
выражения).
7.1.3 Примеры операторов присваивания
В операторе присваивания допускается объявление типа переменной слева от знака
равенства:
int In = 3; // Переменной In присвоено значение константы
double Do = 2.0; // Переменной Do присвоено значение константы
bool Bo = true; // Переменной Bo присвоено значение константы
color Co = 0x008000; // Переменной Co присвоено значение константы
string St = "sss"; // Переменной St присвоено значение константы
datetime Da= D'01.01.2004';// Переменной Da присвоено значение константы
Ранее объявленные переменные используются в операторе присваивания без указания
типа.
In = 7; // Переменной In присвоено значение константы
Do = 23.5; // Переменной Do присвоено значение константы
Bo = 0; // Переменной Bo присвоено значение константы
В операторе присваивания не допускается объявление типа переменной в правой части от
знака равенства:
In = int In_2; // Объявление типа переменных в правой части
запрещено
Do = double Do_2; // Объявление типа переменных в правой части
запрещено
В операторе присваивания не допускается повторное объявление типа переменных.
int In; // Объявление типа переменной In
int In = In_2; // Не допускается повторное объявление
переменной (In)
Примеры использования в правой части пользовательских и стандартных функций:
137
In = My_Function(); // In присвоено значение пользоват. функции
Do = Gipo(Do1,Do1); // Do присвоено значение пользоват. функции
Bo = IsConnected(); // Bo присвоено значение стандартн. функции
St = ObjectName(0); // St присвоено значение стандартн. функции
Da = TimeCurrent(); // Da присвоено значение стандартн. функции
Примеры использования в правой части выражений:
In = (My_Function()+In2)/2; // Переменной In присвоено
// ..значение выражения
Do = MathAbs(Do1+Gipo(Do2,5)+2.5); // Переменной Do присвоено
// ..значение выражения
При вычислениях в операторе присваивания применяются правила приведения типов
данных (см. Приведение типов).
7.1.4 Примеры операторов присваивания краткой формы
В MQL4 используется также краткая форма записи операторов присваивания. Это - форма
операторов присваивания, в которой используются операции присвоения, отличные от
операции присвоения = (знак равенства) (см. Операции и выражения). На операторы
краткой формы распространяются те же правила и ограничения. Краткая форма
операторов присваивания используется в коде для наглядности. Программист по своему
усмотрению может использовать ту или иную форму оператора присваивания. Любой
оператор присваивания краткой формы может быть легко переписан в полноформатный,
при этом результат исполнения оператора не изменится.
In /= 33; // Краткая форма записи оператора присваивания
In = In/33; // Полная форма записи оператора присваивания
St += "_exp7"; // Краткая форма записи оператора присваивания
St = St + "_exp7"; // Полная форма записи оператора присваивания
7.2 Условный оператор if - else
Как правило, при программировании прикладных программ возникает необходимость
закодировать в одной программе несколько вариантов решений. Для решения подобных
задач в программе может быть использован условный оператор if-else.
7.2.1 Формат оператора if-else
138
7.2.1.1 Полный формат
Полноформатный оператор if-else содержит заголовок, включающий условие, тело 1,
ключевое слово else и тело 2. Тела оператора могут состоять из одного или нескольких
операторов и обрамляются фигурными скобками.
if ( Условие ) // Заголовок оператора и
условие
{
Блок операторов 1, // Если условие истинно, то..
составляющих тело1 //..выполняются операторы тела 1
}else // А если условие ложно..
{
Блок операторов 2, // ..то выполняются..
составляющих тело 2 // ..операторы тела 2
}
7.2.1.2 Формат с отсутствующей частью else
Допускается использование оператора if-else с отсутствующей частью else. В этом случае
оператор if-else содержит заголовок, включающий условие, и тело 1, состоящее из одного
или нескольких операторов и обрамлённое фигурными скобками.
if ( Условие ) // Заголовок оператора и условие
{
Блок операторов 1, // Если условие истинно, то..
составляющих тело1 //..выполняются операторы тела 1
}
7.2.1.3 Формат с отсутствующими фигурными скобками
В случае, если тело оператора if-else состоит из одного оператора, то обрамляющие
фигурные скобки можно опустить.
if ( Условие ) // Заголовок оператора и
условие
Оператор; // Если условие истинно, то..
// ..выполняется этот оператор
139
7.2.2 Правило исполнения оператора if-else
Если условие оператора if-else является истинным, то передать
управление первому оператору тела 1, а после выполнения всех
операторов тела 1 передать управление оператору, следующему за
оператором if-else. Если условие оператора if-else является ложным, то:
- если в операторе if-else имеется ключевое слово else, то передать
управление первому оператору тела 2, а после выполнения всех
операторов тела 2 передать управление оператору, следующему за
оператором if-else;
- если в операторе if-else нет ключевого слова else, то передать
управление оператору, следующему за оператором if-else.
7.2.3 Примеры применения оператора if-else
Рассмотрим несколько примеров, демонстрирующих использование оператора if-else.
Задача 9. Составить программу, в которой реализуются следующие
условия: если цена по финансовому инструменту поднялась выше
некоторого значения, сообщить об этом трейдеру, а если нет, то не
осуществлять никаких действий.
Один из вариантов решения этой задачи может выглядеть, например, так (onelevel.mq4):
//--------------------------------------------------------------------
// onelevel.mq4
// Предназначен для использования в качестве примера в учебнике MQL4.
//--------------------------------------------------------------------
int start() // Спец. функция start
{
double
140
Level, // Сигнальный уровень
Price; // Текущая цена
Level=1.2753; // Задаём уровень
Price=Bid; // Запрашиваем цену
//--------------------------------------------------------------------
if (Price>Level) // Оператор if с условием
{
Alert("Курс превысил заданный уровень");// Сообщение трейдеру
}
//--------------------------------------------------------------------
return; // Выход из start()
}
//--------------------------------------------------------------------
Прежде всего необходимо отметить, что программа создана как эксперт. Этим полагается,
что программа будет находиться в работе достаточно долго, с тем чтобы, когда текущая
цена превысит заданный уровень, на экране появилось интересующее нас сообщение. В
программе имеется всего одна специальная функция start(). В начале функции объявлены
и прокомментированы переменные. Далее численно задаётся уровень цены и
запрашивается текущая цена.
Oператор if-else используется в следующих строках программы:
//----------------------------------------------------------------------------------
if (Price>Level) // Оператор if с условием
{
Alert("Курс превысил заданный уровень");// Сообщение трейдеру
}
//----------------------------------------------------------------------------------
С момента, когда в выполняющейся программе управление передано в оператор if-else,
начинается проверка его условия. Обратите внимание, проверка условия в операторе if-
else является его собственным свойством. Эта проверка во время исполнения оператора if-
else не может быть проигнорирована, она являет суть и смысл самого оператора и будет
выполнена обязательно. В дальнейшем, в зависимости от результата этой проверки,
управление будет передано либо в тело оператора, либо за его пределы - в оператор,
следующий за закрывающей фигурной скобкой.
На рис. 37 представлена функциональная схема, в соответствии с которой могут
развиваться события при исполнении оператора if-else.