Кирютенко Ю.А., Савельев В.А. Объектно-ориентированное программирование. Язык Smalltalk

Подождите немного. Документ загружается.

220 Глава 14. Матрицы

row: aRow col: aColumn

"Возвращает элемент матрицы, который расположен

в строке aRow и в столбце aColumn."

^ (self at: aRow) at: aColumn.

row: aRow col: aColumn put: aNumber

"Делает число aNumber элементом матрицы, стоящим в

строке aRow и в столбце aColumn; возвращает aNumber."

^ (self at: aRow) at: aColumn put: aNumber.

row: i

"Возвращает i-ю строку матрицы."

^ super basicAt: i.

row: i put: aNumberArray

"Заменяет строку i матрицы массивом aNumberArray,

если это возможно. Если нет — ничего не делает.

Возвращает aNumberArray."

((aNumberArray isNumberArray)

and: [aNumberArray size = self cols])

ifTrue: [^super basicAt: i put: aNumberArray]

ifFalse: [^aNumberArray].

col: j

"Возвращает столбец j матрицы."

^NumberArray new: self rows

accordingTo: [:i | self row: i col: j].

at: aPoint

"Возвращает элемент матрицы, расположенный

в позиции aPoint."

^ self row: aPoint x col: aPoint y.

at: aPoint put: aNumber

"Делает число aNumber элементом матрицы, стоящим

в позиции aPoint, возвращает aNumber."

^ self row: aPoint x col: aPoint y put: aNumber.

Пользуясь созданными методами доступа, можно написать метод созда-

ния новой матрицы посредством копирования уже существующей.

copy

"Возвращает новую матрицу — копию получателя."

^ self class

rows: (self rows) cols: (self cols)

accordingTo: [:i :j | self row: i col: j].

14.3. Протоколы класса NumericalMatrix 221

14.3.4. Операции с матрицами

Приведем без ре ализации те сообщения из протокола экземпляра класса

NumericalMatrix, которые имеют дело с операциями над матрицами. Реали-

зацию мы рассмотрим в следующем разделе, чтобы не знакомые с матрица-

ми читатели могли, если захотят, «со спокойной совестью» его пропустить.

Класс NumericalMatrix Протокол экземпляра

+ aMatrix Если получатель и матрица aMatrix имеют одинаковые размеры, возвра-

щает матрицу, являющуюся суммой получателя и аргумента. Иначе сообщает

об ошибке.

* aMatrixOrNumber Возвращает матрицу, являющуюся результатом умножения по-

лучателя на аргумент aMatrixOrNumber, который может быть соответствую-

щего размера матрицей или числом. Иначе сообщает об ошибке.

roundTo: aNumber Возвращает матрицу, каждый элемент которой с точно стью

aNumber является приближенным значением соответствующего элемента по-

лучателя.

transpose Возвращает новую матрицу, транспонированную по отношению к полу-

чателю.

copyDeleteRow: aRow col: aColumn Возвращает новую матрицу, получающуюся

из получателя удалением строки aRow и столбца aColumn, если аргументы

являются допустимыми. Иначе сообщает об ошибке.

determinant Для невырожденной квадратной матрицы вычисляет и возвращает

определитель. Иначе сообщает об ошибке.

determinantRec Для невырожденной квадратной матрицы рекурсивно вычисляет и

возвращает определитель. Иначе сообщает об ошибке.

solveEquationWith: aRightSide Если аргумент aRightSide — 1×n-матрица свобод-

ных членов, а получатель сообщения — невырожденная квадратная матрица

порядка n, возвращает решение системы n линейных уравнений c n неизвест-

ными в виде n×1-матрицы. Если матрица вырожденная, возвращает nil. Если

матрица не является квадратной, сообщает об ошибке.

inverse Для невырожденной квадратной матрицы вычисляет и возвращает обрат-

ную матрицу. Если обратная матрица не существует, возвращает nil. Если

матрица не является квадратной, сообщает об ошибке.

Приведем несколько примеров, использующих сообщения из данного

протокола. Все эти примеры можно записать как методы класса с именами,

например, example1, example2 и так далее, а затем для их вызова посы-

лать соответствующее сообщение классу. Текст метода будет отличаться от

приводимого ниже кода тем, что, во-первых, в нем вместо явного имени

класса может стоять self, и, во-вторых, вместо глобальных переменных для

обозначения матриц можно использовать локальные переменные метода.

222 Глава 14. Матрицы

Но прежде, чтобы иметь возможность представлять матрицы в виде эк-

земпляра класса String, переопределим сообщение printOn:.

printOn: aStream

"Записывает в поток aStream ASCII-представление матрицы."

aStream cr; nextPutAll: ’a NumericalMatrix’; nextPut: $(.

1 to: (self rows) do: [:row | aStream cr.

1 to: (self cols) do: [:col |

aStream nextPutAll: (self row: row col: col) asString; space]].

aStream nextPut: $).

Чтобы приве сти примеры, определим две матрицы:

M1 := NumericalMatrix rows: 4 cols: 3 accordingTo:[:i :j| 1/(j+i)] →

a NumericalMatrix(

1/2 1/3 1/4

1/3 1/4 1/5

1/4 1/5 1/6

1/5 1/6 1/7)

M2 := NumericalMatrix rows: 4 cols: 3 accordingTo:[:i :j| j*i] →

a NumericalMatrix(

1 2 3

2 4 6

3 6 9

4 8 12)

Тогда можно выполнить следующие выражения:

(M1 + M2) →

a NumericalMatrix(

3/2 7/3 13/4

7/3 17/4 31/5

13/4 31/5 55/6

21/5 49/6 85/7)

M1 * M2 transpose →

a NumericalMatrix(

23/12 23/6 23/4 23/3

43/30 43/15 43/10 86/15

23/20 23/10 69/20 23/5

101/105 202/105 101/35 404/105)

(M2 deleteRow: 2 col: 2) →

a NumericalMatrix(

1 3

3 9

4 12)

14.3. Протоколы класса NumericalMatrix 223

Для примеров с квадратными матрицами определим новую матрицу:

M3 := NumericalMatrix rows: 3 cols: 3

accordingTo: [:i :j | (1/(i+j)) asFloat] →

a NumericalMatrix(

0.5 3.33333333e-1 0.25

3.33333333e-1 0.25 0.2

0.25 0.2 1.66666667e-1)

Тогда можно выполнить следующие выражения:

M3 determinant → 2.31481481e-5

M3 inverse →

a NumericalMatrix(

72.0 -240.0 180.0

-240.0 900.0 -720.0

180.0 -720.0 600.0)

(M3 solveEquationWith: (NumericalMatrix rows: 3 cols: 1

accordingTo: [:i :j | i])) →

a NumericalMatrix(

132

-600

540)

14.3.5. Реализация простых операций с матрицами

Реализации методов для сложения, умножения и транспонирования мат-

риц следуют их математическим определениям. Правда, метод для умноже-

ния матриц не прямой, а использует два частных метода для умножения

матрицы на матрицу и на число. Если операция не может быть выполнена

из-за несоответствия размеров матриц, о такой ошибке сообщает приведен-

ный первым метод errorOfCorrespondence:. Ради краткости, комментарии

в методах, вошедших в приведенный выше протокол, не приводятся.

errorOfCorrespondence: aSizeMatrix

"Частный. Сообщает об ошибке несоответствия размеров матриц."

^ self error: ’the matrix size is incompatible with recever.’

+ aMatrix

(self size = aMatrix size)

ifTrue: [^ NumericalMatrix rows: (self rows) cols: (self cols)

accordingTo: [:i :j|

(self row: i col: j) + (aMatrix row: i col: j)]]

ifFalse: [self errorOfCorrespondence: aMatrix size].

224 Глава 14. Матрицы

multiplyOnNumber: aNumber

"Частный. Возвращает результат умножения получателя на число."

^ NumericalMatrix rows: (self rows) cols: (self cols)

accordingTo: [:i :j| (self row: i col: j) * aNumber].

multiplyOnMatrix: aMatrix

"Частный. Возвращает результат умножения получателя на матрицу

aMatrix, если это возможно, иначе сообщает об ошибке."

| sum numcols |

numcols := self cols.

(numcols = aMatrix rows)

ifTrue: [^ NumericalMatrix rows:(self rows) cols:(aMatrix cols)

accordingTo: [:i :j | sum := 0.

1 to: numcols do: [:p | sum := sum +

((self row: i col: p) * (aMatrix row: p col: j))].

sum ]]

ifFalse: [self errorOfCorrespondence: aMatrix size].

* aMatrixOrNumber

(aMatrixOrNumber isNumber)

ifTrue: [^ self multiplayOnNumber: aMatrixOrNumber]

ifFalse: [^ self multiplayOnMatrix: aMatrixOrNumber].

roundTo: aNumber

^ NumericalMatrix rows: (self rows) cols: (self cols)

accordingTo: [:i :j | (self row: i col: j) roundTo: aNumber].

transpose

^ NumericalMatrix rows: (self cols) cols: (self rows)

accordingTo: [:i :j | (self row: j col: i)].

copyDeleteRow: aRow col: aColumn

^ NumericalMatrix rows:(self rows –1) cols:(self cols –1)

accordingTo: [:i :j |

self row: ((i < aRow) ifTrue: [i] ifFalse: [i+1])

col: ((j < aColumn) ifTrue: [j] ifFalse: [j+1])].

Для упрощения реализации более сложных алгоритмов линейной ал-

гебры сначала напишем несколько вспомогательных методов, реализующих

наиболее часто используемые операции с матрицами.

fromRow: ind1 subtractRow: ind2 multipliedBy: aNumber

"Преобразует матрицу, вычитая из строки ind1

строку ind2, умноженную на число aNumber."

self row: ind1

put: (self row: ind1) - ((self row: ind2) copy*aNumber).

14.3. Протоколы класса NumericalMatrix 225

multiplyRow: i fromCol: j on: aNumber

"Преобразует матрицу, умножая строку i на число

aNumber, начиная со столбца j и до конца строки."

| aRow |

aRow := self row: i.

aRow multiplyFrom: j on: aNumber.

self row: i put: aRow.

multiplyRow: i on: aNumber

"Преобразует матрицу, умножая

строку i на число aNumber."

self row: i put: (self row: i) * aNumber.

toRow: ind1 multipliedBy: aNumber addRow: ind2

"Преобразует матрицу, прибавляя к строке ind1,

умноженной на число aNumber, строку ind2."

self row: ind1

put: (self row: ind1) * aNumber + (self row: ind2).

permuteRows: index1 and: index2

"Преобразует матрицу, меняя местами

указанные аргументами строки."

|temp|

temp := self row: index1.

self row: index1 put: (self row: index2).

self row: index2 put: temp.

normalize: i

"Частный (для метода Гаусса). Преобразует элементы

квадратной подматрицы получателя с левым верхним

элементом i@i так, чтобы элемент i@i стал равным 1, а

все элементы столбца i ниже строки i стали равными 0.

Это достигается операциями умножения строк на числа

и складыванием (вычитанием) строк."

| aRow el |

self multiplyRow: i fromCol: i on: (1 /(self row: i col: i)).

aRow := self row: i.

(i+1) to: self rows do: [:k |

el := self row: k col: i.

(el = 0)

ifFalse: [self fromRow: k subtractRow: i multipliedBy: el]].

Реализацию основных алгоритмов линейной алгебры, упомянутых ра-

нее, оставляем читателю в качестве упражнения.

226 Глава 14. Матрицы

14.4. Задания для самостоятельной работы

1. Напишите метод класса, создающий матрицу указанного размера, все

элементы которой равны заданному числу.

2. Напишите методы класса, создающие квадратную матрицу указанного

порядка, все элементы которой: (1) равны нулю, (2) равны заданному числу,

(3) вычисляются с помощью блока с двумя аргументами.

3. Напишите методы, которые возвращали бы новую матрицу, представ-

ляющую собой: (1) указанную строку получателя, (2) указанный столбец

получателя.

4. Напишите методы, которые заменяли бы указанный столбец или строку

получателя на заданный подходящий аргумент.

5. Напишите методы, которые создавали бы новую матрицу, удаляя из суще-

ствующей матрицы: (1) указанную строку, (2) указанный столбец, (3) ука-

занные строку и столбец.

6. Напишите итеративные методы, которые вычисляли бы по квадратной

матрице ее: (а) определитель detA, (б) след tr(A) =

∑

i=1

7. Напишите метод, возвращающий матрицу, обратную к квадратной мат-

рице. Для вычисления обратной матрицы можно использовать метод присо-

единенной матрицы. Если A

−1



(−1)



n, n

l=1,k=1

— матрица, обратная к невы-

рожденной матрице A = (a

)

n, n

l=1,k=1

, то a

(−1)

= (−1)

l+k

detA

8. Напишите метод, который реализует известный алгоритм Гаусса и воз-

вращает решение системы линейных уравнений, если оно существует.

9. Квадратная матрица называется симметричной, если a

= a

при всех

допустимых значениях индексов. Из определения следует, что вся информа-

ция о симметричной матрице может храниться, например, только в элемен-

тах, расположенных на и выше ее главной диагонали. Создайте подкласс

класса NumericalMatrix c именем SymmetricMatrix, экземпляр которого бу-

дет занимать значительно меньше места, и переопределите необходимые

методы класс а и экземпляра.

10. Пусть в (m×n)-матрице A выбраны произвольно k строк и k столбцов

(0 ≤ k ≤min(m,n)). Элементы, стоящие на пересечении выбранных строк и

столбцов, образуют квадратную матрицу порядка k, определитель которой

называется минором k-го порядка матрицы A. Максимальный порядок r

отличных от нуля миноров произвольной матрицы A называется ее рангом.

Напишите метод rank, который вычисляет ранг матрицы

При реализации метода можно воспользоваться алгоритмом Гаусса.

14.4. Задания для самостоятельной работы 227

11. Перепишите класс NumericalMatrix, делая его подклассом класса Num-

berArray и определяя в нем две именованные переменные экземпляра:

NumberArray variableSubclass: #NumericalMatrix

instanceVariableNames: ’ row column ’

classVariableNames: ’ ’

poolDictionaries: ’ ’

В этом случае отличительной чертой экземпляра класса NumericalMatrix

является то, что все его элементы расположены линейным образом в чис-

ловом массиве, строки и столбцы из которого выделяются в соответствии

с задаваемыми размерами row и column. Имеет ли, на ваш взгляд, такая

реализация преимущества перед реализацией, приведенной выше?

12. Напишите метод determinantRec рекурсивного вычисления определите-

ля квадратной матрицы, который следует данному в начале главы опреде-

лению определителя. Сравните его с итерационным методом.

ГЛАВА 15

ОСОБЕННОСТИ СОЗДАНИЯ КОДА

Ранее мы уже рассмотрели некоторые правила создания текстов на язы-

ке Смолток. Вероятно, чит атель (о собенно тот, который хорошо знает ан-

глийский) заметил, что выражения на языке Смолток выглядят почти пра-

вильными предложениями английского языка. Это не случайно. Многие

правила, которые мы рассмотрим ниже, обсуждая «технику кодирования»,

направлены на то, чтобы смолтоковский текст был «удобочитаемым».

Итак, «. . . поговорим о странностях. . . » создания программ на языке

Смолток. Если вы примете к исполнению эти правила и соглашения, это

поможет писать понятный и эффективно выполняемый код, который легко

интегрировать в существующую библиотеку классов и использовать при

решении других задач.

15.1. Что такое смолтоковский стиль

Программирование на языке Смолток сводится к расширению суще-

ствующей библиотеки классов, которая разрабатывалась на протяжении

многих лет (начиная с 1972 года) многими программистами. За это время

появился некий «смолтоковский стиль» программирования. Большинство

принципов, о которых пойдет речь, отражают те приемы, которые исполь-

зовались опытными программистами и которые можно легко отыскать в

библиотеке — «сокровищнице» разнообразных примеров.

Смолтоковский стиль — приемы и правила, позволяющие в процессе

создания кода понятнее выразить заключенные в нем основные идеи. Это

чрезвычайно полезно, прежде всего потому, что помогает пользователю по-

нимать, что делает каждый конкретный класс или метод, только читая ис-

ходный текст.

Правило — не закон, поэтому и в библиотеке классов есть примеры

того, как одна и та же идея реализуется совершенно разными способами.

Но существенные отклонения от общепринятого стиля затрудняют пони-

мание кода. Надеемся, что нам удастся убедить вас принять выработанный

стиль, чтобы создаваемый вами текст был подобен лучшим смолтоковским

образцам. Тогда его будет легко чит ать, он будет более понятен другим

программистам, и, в случае необходимости, его легко будет изменить. Да-

же только это, при прочих равных условиях, может способствовать более

частому использованию другими именно вашего кода.

15.2. Соглашение об именах 229

15.2. Соглашение об именах

В языке Смолток существует совсем мало «законов» относительно имен

для классов, переменных и методов (а также категорий и протоколов в тех

реализациях, в которых они есть

). Имеющиеся правила мы рассмотрели

в первой части. Здесь же остановимся на соглашениях, которых следует

придерживаться программистам, подбирая имена для своих классов, пере-

менных, методов и других объектов.

Не забывайте, что имена общих переменных (глобальных переменных,

переменных пула, переменных класса) начинаются с заглавной буквы, а

имена временных переменных начинаются со строчной буквы. Кроме того,

имена не могут содержать пробелов. Поэтому, если имя состоит из несколь-

ких слов, последующее слово пишут без пробела с заглавной буквы.

Старайтесь делать имена переменных настолько описательными, на-

сколько это возможно, тем более что имена могут быть достаточно длин-

ными. Можете включить в имя информацию о назначении данной перемен-

ной. Например, occupiedRectangle, lineDelimiter, nextFourBytes. Последний

пример использует общее соглашение об указании на набор объектов: ис-

пользуется существительное во множественном числе. Если надо дать имя,

которое отражает логическое состояние, следует использовать нечто подоб-

но isNil, isChanged, wasConverted, hasBeenEdited. Используя такие имена,

вы сможете писать классические смолтоковские выражения:

occupiedRectangle hasBeenEdited ifTrue: [ "Do something" ].

Общее соглашение об именах параметров при определении метода сво-

дится к использованию типа или имени класса того объекта, который дол-

жен передаваться, с приставкой ’a ’ или ’an’ (в соответствии с правилами

английского языка). Например, anArray, aTriangle. Если параметр метода

может быть экземпляром нескольких разных классов, следует использовать

самый «нижний» общий суперкласс, например, aCollection или, в самом

общем случае, anObject. Последний пример не столь бессмысленен, как

может показаться, поскольку указывает на то, что в качестве аргумента

может передаваться экземпляр любого класса.

Так же тщательно, как имя переменной, следует выбирать и имя мето-

да (селектор), чтобы оно описывало цель метода. На длину имени метода

нет существенных ограничений. Методы, которые преследуют только цель

обращения к переменным, должны называться по имени такой перемен-

ной. Например, если есть переменная экземпляра с именем sideA, метод,

который возвращает ее значение, следует назвать sideA, а не returnSideA,

В некоторых новых реализациях используются пакеты и пространства имен.