Кирютенко Ю.А., Савельев В.А. Объектно-ориентированное программирование. Язык Smalltalk

Подождите немного. Документ загружается.

190 Глава 11. Основы строительства

так уж часто будете. Исключение составляет класс Object — суперкласс для

всех других классов, и класс ViewManager — суперкласс для окон прило-

жений, о котором пойдет речь в разделе 16.2.

Все это означает, что, когда вы создаете собственные повторно исполь-

зуемые классы, вы сначала должны задуматься о том, как пользователь бу-

дет работать с их экземплярами, а уж потом о том, как он сможет из них

наследовать. Проектирование наследования — достаточно сложная задача.

Формирование объектов из частей, разработанных для совместного ис-

пользования, позволяет обойти ограничение системы, связанное с одиноч-

ным наследованием (каждый класс имеет точно один непосредственный

суперкласс, а не комбинацию многих родительских классов). Каждая часть

составного объекта имеет собственное место в иерархии наследования. По-

пытка найти в иерархии место для такого класса, экземпляр которого пред-

ставлял бы объект, эквивалентный составному, всегда будет приводить к

компромиссу.

Но на одних пожеланиях повторно используемого класса не создашь.

Каким еще правилам стоит следовать? Наиболее очевидно, что всегда на-

до стараться создавать код общего вида. Возможности, предоставляемые

системой Смолток, основаны на том, что язык Смолток — это язык «без

типов» (“typeless”). Если в интерфейсе создаваемого класса не нужно огра-

ничивать тип объекта, то и не ограничивайте его. Если ограничения необхо-

димы, старайтесь сделать их минимальными. Например, если метод прини-

мает в качестве параметра набор, пишите код, работающий с максимально

большим числом разных наборов, а не только с массивами.

Один из способов сделать класс общим со стоит в том, чтобы избегать в

теле методов прямого использования констант. Если подобное имеет смысл,

встраивайте их в интерфейс в качестве методов. Конечно, это несколько

усложнит интерфейс класса, поэтому надо стараться создавать более про-

стые версии методов с меньшим числом параметров. А эти методы, возмож-

но, будут вызывать более сложные методы со значениями по умолчанию

для некоторых параметров. Такой прием часто используется в иерархии

классов системы, где он иногда проходит много уровней все возрастающей

общности (и возрастающего числа параметров), пока не возникнет метод,

который фактически вызывается для исполнения и выполняет всю работу.

Старайтесь разрабатывать классы так, чтобы пользователи знали только о

тех возможностях, которые они реально используют.

В заключение стоит еще сказать, что только опыт эксплуатации создан-

ного класса расставит все по своим местам. Нельзя предсказать будущее.

Но если класс удовлетворяет основным требованиям, не стоит «на предви-

дение» тратить время.

11.3. Использование отладчика 191

Наверное, вы уже обратили внимание, что от общих правил, относя-

щихся к классу в целом, мы незаметно перешли к частным правилам, отно-

сящимся к вопросам создания кода, то есть непосредственно к реализации

класса. Чтобы наш разговор об этом был более содержательным и более

понятным, давайте его продолжим в конце этой части после того, как по-

строим несколько классов.

11.3. Использование отладчика

Век вывихнут. О злобный жребий мой!

Век вправить должен я своей рукой. . .

Шекспир. «Гамлет»

11.3.1. Определение класса WordIndex

Чтобы получить некоторый опыт отладки создаваемого кода, построим

новый класс, преднамеренно допустив ошибки в коде методов, и постара-

емся найти их

. Таким образом, в этом параграфе мы акцентируем внима-

ние не на особенностях создания класса (этому мы посвятим все остальные

примеры), а именно на поиске ошибок с помощью отладчика.

Определим новый класс с именем WordIndex, экземпляры которого поз-

волят нам создавать базу данных документов, опираясь на те слова, которые

они содержат. Документы (текстовые файлы) рассматриваются как цепоч-

ки слов, состоящие из алфавитно-цифровых символов и разделенные не

алфавитно-цифровыми символами. Запрос к базе данных состоит из мас-

сива строк (экземпляров класса String), при этом каждая строка представ-

ляет слово. В ответ на запрос экземпляр класса WordIndex должен возвра-

щать набор имен файлов, тексты которых содержат все указанные в запросе

слова. Например, таким способом можно определить по характеристикам,

хранящимся в компьютере отдела кадров, тех служащих, характеристики

которых содержат слова «объектно-ориентированное программирование».

Каждый экземпляр класса WordIndex будет иметь следующие перемен-

ные экземпляра:

documents — множество строк, каждая из которых представляет путь к

файлу, содержащему тот документ, слова которого будут введены в

экземпляр класса.

Этот пример взят из документации, поставляемой разработчиком вместе с си-

стемой Smalltalk Express.

192 Глава 11. Основы строительства

words — словарь, каждый ключ которого есть слово, а каждое значение

является множеством, содержащим пути к тем документам из базы

данных, которые содержат слово-ключ.

Итак, откройте окно просмотра иерархии классов и добавьте в систему

новый класс, определение которого имеет следующий вид:

Object subclass: #WordIndex

instanceVariableNames: ’documents words ’

classVariableNames: ’ ’

poolDictionaries: ’ ’

Определите в WordIndex следующие шесть методов экземпляра:

addDocument: pathName

"Добавить вс е слова из документа, описанного строкой pathName, к

словарю слов."

| word wordStream |

(documents includes: pathName)

ifTrue: [self removeDocument: pathName].

wordStream := File pathName: pathName.

documents add: pathName.

[(word := wordStream nextWord) == nil]

whileFalse: [self addWord: word asLowerCase to: pathName].

wordStream close

addWord: wordString for: pathName

"Добавить wordString к словарю слов для документа,

описанного именем pathName."

(words at: wordString) add: pathName

initialize

"Инициализировать новый экземпляр класса WordIndex."

documents := Set new.

words := Dictionary new

locateDocuments: queryWords

"Возвратить множество, содержащее имена тех документов,

которые содержат все слова из массива queryWords."

| answer bag |

bag := Bag new.

answer := Set new.

queryWords do: [:word |

bag addAll: (documents at: word ifAbsent: [#( )] )].

bag asSet do: [:document |

queryWords size = (bag occurrencesOf: document)

11.3. Использование отладчика 193

ifTrue: [answer add: document]].

^ answer asSortedCollection asArray

removeDocument: pathName

"Удалить из словаря words строку pathName, описывающую

документ."

words do: [ :docs | docs remove: pathName].

self removeUnusedWords

removeUnusedWords

"Удалить из словаря words все слова, имеющие пустой набор

документов."

| newWords |

newWords := Dictionary new.

words associationsDo: [ :anAssoc | anAssoc value isEmpty

ifFalse: [newWords add: anAssoc]].

words := newWords

Чтобы добавить определение класса WordIndex и его методы в образ

системы Smalltalk Express, можно воспользоваться готовым файлом, кото-

рый поставляется вместе с системой, выполняя, например, в рабочем окне

выражение:

(File pathName: ’tutorial\wrdindx8.st’) fileIn; close

Чтобы имя нового класса появилось в иерархии, надо из меню Classes

окна просмотра иерархии классов выбрать пункт Update (Обновить).

11.3.2. Отладка класса WordIndex

Давайте рассмотрим класс WordIndex в терминах сообщений, которые

создают экземпляр класса WordIndex и посылают запросы. Напомним, что

преднамеренно в приведенных текстах методов сделаны ошибки.

Итак, предположим, что класс работает так, как надо, и посмотрим, что

он делает. Чтобы воспользоваться экземпляром класса, его сначала надо

создать; для этого следует выполнить выражение:

MyIndex := WordIndex new initialize

Объект MyIndex создается как новая глобальная переменная, которая

ссылается на новый экземпляр класса WordIndex. Метод initialize ини-

циализирует все переменные экземпляра WordIndex: теперь переменная

documents содержит пустое множество, а переменная words содержит пу-

стой словарь. При выполнении этого выражения ошибка не возникла.

Далее добавим файлы chapter.5 и chapter.6, поставляемые с системой,

как документы экземпляра MyIndex. Это делает метод addDocument:, ко-

194 Глава 11. Основы строительства

торый создает файловый поток, чтобы просмотреть документ, многократно

посылая файловому потоку сообщение nextWord, которое получает сле-

дующее слово, а затем использует метод addWord:for: для ввода каждой

пары «слово/документ» в словарь words. Значит, чтобы добавить слова из

файлов chapter.5, chapter.6 в экземпляр, надо выполнить следующие два

выражения:

MyIndex addDocument: ’tutorial\chapter.5’.

MyIndex addDocument: ’tutorial\chapter.6’.

Возникает окно Walkback, значит есть какая-то ошибка. В данном слу-

чае метка окна Walkback информирует нас о том, что сообщение add-

Word:to: не было понято (addWord:to: not understood), в то время как

верхняя строка в текстовой панели показывает WordIndex как класс, объ-

ект которого не понял сообщение.

Как уже отмечалось выше, можно предпринять одно из трех действий.

В этом случае, чтобы установить причину ошибки, достаточно информации

из окна Walkback. Посмотрите на код в классе WordIndex, используя окно

просмотра иерархии классов. Там определен метод с именем addWord:for:,

а в методе addDocument: послано сообщение addWord:to:, которое и не

было понято. Чтобы исправить ошибку, закройте окно Walkback и, поль-

зуясь окном просмотра иерархии классов, исправьте метод addDocument:,

вставляя addWord:for: вместо addWord:to:.

Пробуем снова добавить файлы обучающей программы, используя те же

выражения. На этот раз возникает новое окно Walkback, заголовок которого

сообщает: Key is missing (Ключ отсутствует). Так как причина ошибки не

столь очевидна, получим более подробную информацию, открывая окно

Debugger, для чего в окне Walkback нажмем на кнопку Debug.

Левая верхняя панель (списковая панель) окна Debugger повторяет ин-

формацию из окна Walkback, и ее можно использовать для того, чтобы

выбирать в ней строки посланных сообщений (Walkback-строки), получая

в других панелях окна связанную с выбранной строкой информацию.

Чтобы понять причину ошибки, сначала выберем в левой верхней пане-

ли строку WordIndex>>addDocument:. В нижней текстовой панели появит-

ся текст метода addDocument: из класса WordIndex с выделенным текстом

self addWord: word asLowerCase for: pathName.

Это означает, что данное сообщение было послано, но его выполнение не

было завершено. Просматривая значения всех переменных в средней верх-

ней панели, убеждаемся в том, что здесь все в порядке. Теперь выберем

в левой верхней панели строку WordIndex>>addWord:for:, в нижней тек-

стовой панели появится текст метода addWord:for: с выделенным текстом

words at: wordString. Со значениями переменных здесь тоже все в порядке.

11.3. Использование отладчика 195

Поднимемся в левой верхней панели еще на строчку и выберем Dictio-

nary>>at:. Текстовая панель внизу окна отобразит исходный текст метода

at: класса Dictionary:

at: aKey

"Возвратить из получателя значение пары key/value, ключ

которой равен aKey. Если ключа нет, сообщить об ошибке."

| answer |

^ (answer := self lookUpKey: aKey) == nil

ifTrue: [self errorAbsentKey]

ifFalse: [answer value]

c выделенным текстом self errorAbsentKey, который является текущим вы-

ражением, выполнение которого в этом методе не было завершено к момен-

ту останова. Метод at: возвращает значение той пары key/value из словаря,

ключ которой равняется аргументу aKey. Если ключ отсутствует, вызыва-

ется метод errorAbsentKey, приводящий к инициализации окна Walkback.

В верхней средней панели найдем self, аргумент aKey и временную

переменную answer. Выбрав self, видим в панели справа его значение —

пустой словарь. Теперь выберем аргумент aKey, его значение — строка

’tutorial’, первое слово в файле. Таким образом, мы пытались производить

поиск в пустом словаре.

Возвратимся к строке WordIndex>>addWord:for:, выберем параметр

wordString. Как и раньше, это строка ’tutorial’. Таким образом, мы обра-

щались к словарю words, но не проверили, присутствует ли в словаре за-

данный ключ. Исправим метод addWord:for: в нижней текстовой панели

окна Debugger так, чтобы он выглядел следующим образом:

addWord: wordString for: pathName

"Добавить wordString к словарю слов для документа,

описанного именем пути pathName."

(words includesKey: wordString)

ifFalse: [words at: wordString put: Set new].

(words at: wordString) add: pathname.

Сохраним новую редакцию метода и посмотрим, что произошло в окне

Debugger. Строки списковой панели, расположенные выше строки Word-

Index>>addWord:for:, исчезли, так как был изменен метод, с которым они

были связаны, а сама ст рока WordIndex>>addWord:for: стала выделенной.

Выберем пункт Restart из меню Debugger, выполнение возобновится,

снова посылая выделенное сообщение. Поскольку ошибка исправлена, окно

Debugger исчезнет, а метод наконец-то выполнится.

Чтобы послать запрос объекту MyIndex, надо воспользоваться сообще-

нием locateDocuments:. Каждый запрос должен возвращать массив ст рок,

196 Глава 11. Основы строительства

содержащий пути к тем документам, в которых есть все слова, перечислен-

ные в аргументе этого сообщения.

Метод locateDocuments: сложнее остальных методов в классе. Он ис-

пользует экземпляр класса Bag, чтобы в нем накапливать пути для всех

файлов, содержащих каждое слово из запроса. Напомним, что экземпляры

класса Bag, в отличие от множеств, могут содержать дубликаты объектов.

Затем экземпляр класса Bag исследуется с целью отыскать в нем все те

документы, которые повторяются столько раз, сколько слов в запросе; это

именно те документы, которые содержат все слова.

Итак, пробуем послать запрос, выполняя выражение:

MyIndex locateDocuments: #(’show’ ’class’).

Снова возникает окно Walkback, информируя о том, что сообщение

at:ifAbsent:, посланное экземпляру класса Set, не было им понято. Откроем

окно Debugger, выберем в левой верхней панели строку

Set(Object) >> doesNotUnderstand:

Затем выберем self из списка временных переменных. Его значение рав-

но Set(’tutorial\chapter.6’ ’tutorial\chapter.5’).

Теперь выберем строку [ ] WordIndex>>locateDocuments: (3-ю сверху).

Посмотрим на исходный текст метода, в котором внутри блока выделено

незавершенное сообщение at:ifAbsent:, и исследуем значения временных

переменных. В сообщении в качестве получателя используется переменная

экземпляра documents — экземпляр класса Set. Значение, распечатанное

выше, подтверждает это, поскольку содержит пути к документам. Следова-

тельно, или мы послали неправильное сообщение объекту documents, или

documents — неправильный получатель сообщения. Но код

bag addAll: (documents at: word ifAbsent: [#()])

пытается добавить в переменную bag все документы, которые включают

строку, содержащуюся в переменной word. Такая информация содержится в

переменной words. Значит, неправильным является получатель сообщения.

Следует использовать словарь words:

bag addAll: (words at: word ifAbsent: [#()]).

Используя текстовую панель окна Debugger, изменим метод locateDocu-

ments:, сохраним измененный метод и повторим запрос. Приложение долж-

но работать корректно. Отладка завершена.

11.3.3. О кнопках Hop, Skip и Jump

Теперь, когда мы отладили класс WordIndex, давайте попробуем ис-

пользовать отладчик Debugger для того, чтобы увидеть, как функционирует

приложение, непосредственно наблюдая за посылкой сообщений. Откроем

11.3. Использование отладчика 197

окно Walkback, а из него окно Debugger, выполняя вместе следующие два

выражения:

self halt. "Контрольная точка — вызов окна Walkback."

MyIndex locateDocuments: #(’each’ ’talk’).

Нажатие кнопок Hop, Skip и Jump, как уже отмечалось, вызывает вы-

полнение порции кода. Дважды нажмите кнопку Hop и понаблюдайте за

изменениями окна Debugger. Первое нажатие выделит выражение MyIndex

locateDocuments: #(’each’ ’talk’). По сле второго нажатия кнопки выраже-

ние начнет выполняться, и выделенным окажется первое выражение мето-

да locateDocuments:, то есть Bag new. Нажмите Hop снова. Выполнение

сделает следующий шаг и перейдет в метод new класса Bag, и так далее.

Обращаясь к панелям переменных, можно исследовать состояние объектов

после каждого шага Hop.

Теперь нажмите несколько раз кнопку Skip. Обратите внимание, что вы-

деляемый код является частью того же самого метода до тех пор, пока вы-

полнение метода не закончится. Это позволяет сконцентрировать внимание

на пошаговом выполнении данного метода и проигнорировать вычисление

всех сообщений, посылаемых этим методом.

Jump выполняет наиболее «длинные» шаги из всех трех пошаговых кно-

пок. Если не устанавливались контрольные точки, Jump выполняет весь

код до конца отлаживаемого выражения. Следовательно, нажимая во вре-

мя отладки один раз Jump, мы завершим выполнение выражения MyIndex

locateDocuments: #(’each’ ’talk’).

ГЛАВА 12

ДОМАШНЯЯ БУХГАЛТЕРИЯ

. . . И был глубокий эконом . . .

А. Пушкин. «Евгений Онегин»

Приведем простой пример класса, в котором для хранения информа-

ции используются словари. Назовем наш класс FinancialBook (Финансовая-

Книга). Основные идеи примера взяты из книги [5] (в ней он назывался

FinancialHistory), но мы его немного изменили для того, чтобы в одном

примере охватить больше деталей и создать модель для построения прило-

жения с графическим интерфейсом пользователя.

12.1. Цель и определение класса

Нам хотелось бы в своих семьях ве сти строгий учет и контроль над по-

ступлениями и тратами денежных средств. Деньги зарабатываются всеми

членами семьи, причем каждый может работать в нескольких местах, то

есть может иметь несколько источников. И мы хотим знать, какая сумма

денег приходит в семью из каждого такого источника. Чтобы не усложнять

данную учебную модель, мы будем учитывать не начисленные, а реальные

суммы, которые попадают в семью за вычетом всех налогов. Все суммы

будем задавать в рублях и копейках, принудительно округляя числа до двух

знаков после запятой. В расходовании денежных средств (expenditures) так-

же принимают участие все члены семьи, причем причины расходования

средств (на еду, на одежду, на книги и тому подобное) не зависят от того,

кто конкретно их тратит. Нас интересует не то, кто сколько тратит денег,

а на что тратятся деньги.

Данный класс мы строим для того, чтобы в любой момент иметь воз-

можность, во-первых, внести в нашу семейную книгу учета новую инфор-

мацию о доходах и расходах и, во-вторых, получить информацию о том,

сколько денег сейчас в наличии, какова сумма доходов и сумма расходов за

весь прошедший период ведения книги учета, какова сумма, полученная из

каждого источника, какова сумма, потраченная по каждой причине. Таким

образом, проектируемый класс должен отвечать на следующие сообщения:

receive: amount from: source запоминает, что получили сумму amount из

источника source; в качестве источника договоримся использовать его

текстовое описание (строку); возвращает финансовую книгу;

12.2. Создание нового экземпляра 199

totalReceivedFrom: source возвращает сумму денег, полученную из источ-

ника source;

sources возвращает набор всех источников поступления денег;

spend: amount for: reason запоминает, что сумму amount израсходовали по

причине reason; причины тоже будем представлять описывающими

их строками; возвращает финансовую книгу;

totalSpentFor: reason возвращает сумму денег, потраченную по причине

reason;

reasons возвращает набор всех причин расходования средств.

totalIncome возвращает сумму доходов;

totalExpenditure возвращает сумму расходов;

cashOnHand возвращает наличную сумму денег.

Хранение числовых значений со строками в качестве ключей реализуем

в виде словарей. Хотя обычно в бухгалтерии источники доходов и причины

расходов формализуют как счета учета и хранят вместе, мы в этом примере

для простоты заведем два различных словаря incomes и expenditures для

доходов и расходов, соответственно.

Общие суммы доходов и расходов можно всегда вычислить. Но посколь-

ку записей в соответствующих словарях может быть много, т акое вычис-

ление может стать неэффективным. В то же время, если общие суммы до-

ходов и расходов хранить в переменных объекта и обязанность изменять

общие суммы возложить на методы добавления новых доходов и расхо-

дов, накладные затраты будут ничтожны. Поэтому заведем еще две число-

вые переменные totalIncome и totalExpenditure. При такой структуре сумму

наличных денег вычислить всегда просто: от суммы доходов надо отнять

сумму расходов. Из всего сказанного следует такое определение класса:

Object subclass: #FinancialBook

instanceVariableNames:

’incomes expenditures totalIncome totalExpenditure ’

classVariableNames: ’ ’

poolDictionaries: ’ ’

12.2. Создание нового экземпляра

Как мы уже знаем, основные методы класса — это методы, создающие

новый экземпляр с разумной инициализацией переменных. В этом клас-

се создадим два метода: один с нулевой стартовой суммой денег (new), а

другой с задаваемой аргументом стартовой суммой денег (newWith:).