Кирютенко Ю.А., Савельев В.А. Объектно-ориентированное программирование. Язык Smalltalk

Подождите немного. Документ загружается.

200 Глава 12. Домашняя бухгалтерия

new

"Создает новый экземпляр с нулевой стартовой суммой."

^ super new setInitialBalans: 0

newWith: amount

"Создает новый экземпляр со стартовой суммой amount."

^ super new setInitialBalans: amount

Обратим внимание на то, что методы создания экземпляров (newWith:

и new) не имеют прямого доступа к переменным создаваемого экземпляра,

поскольку выполняются не классом, которому принадлежат новые экзем-

пляры, а метаклассом класса. Поэтому методы создания экземпляра сна-

чала создают экземпляр с неинициализированными переменными, а потом

посылают ему сообщение инициализации setInitialBalance:. Метод для это-

го сообщения находится в классе FinancialBook среди методов экземпляра.

Он уже «умеет» присваивать переменным экземпляра те значения, которые

обеспечивают правильное поведение созданного объекта.

Сообщения инициализации, как правило, не рассматриваются как часть

доступного интерфейса экземпляра. Обычно такие сообщения посылаются

только методами класса и рассматриваются как частные. Если реализация

поддерживает категории методов, то такой метод должен находиться в кате-

гории частных методов экземпляра (private). Если такой поддержки нет, как

в Smalltalk Express, то предназначение метода рекомендуется подчеркивать

словом «Частный», расположенным в самом начале комментария к методу.

setInitialBalans: amount

"Частный. Инициализирует все переменные нового экземпляра."

(amount isNumber and: [amount > 0])

ifTrue: [totalIncome := amount roundTo: 0.01]

ifFalse: [totalIncome := 0].

totalExpenditure := 0.

incomes := Dictionary new.

expenditures := Dictionary new

12.3. Методы доступа к информации

Чтобы вносить в книгу учета новую информацию и получать из этой

книги нужные нам сведения, необходимы методы доступа к переменным

экземпляра, которые позволяют получать (get-методы) и определять (put-

методы) значения переменных. Не всегда и не ко всем переменным поль-

зователь может обращаться и/или изменять их значения. В данном классе

все переменные экземпляра будут получать свои значения в процессе до-

12.3. Методы доступа к информации 201

бавления в экземпляр новой информации о доходах и расходах. Поэтому

put-методы пока определять не будем. Что же касается get-методов, то, по

нашему мнению, методы, возвращающие значения переменных totalIncome

и totalExpenditure, должны входить в интерфейс экземпляра класса, а ме-

тоды, возвращающие словари incomes и expenditures — нет, и мы их тоже

не станем пока определять. Не имея графиче ского интерфейса, представить

полное содержание словарей весьма затруднительно (они могут оказаться

достаточно большими). Всегда лучше думать не о переменных, а об атри-

бутах объекта, которым могут соответствовать (а могут и не соответство-

вать) переменные. Итак, из всех методов, возможных в этом классе, сначала

определим только три следующих:

totalExpenditure

"Возвращает общую сумму всех расходов."

^ totalExpenditure

totalIncome

"Возвращает общую сумму доходов."

^ totalIncome

cashOnHand

"Возвращает сумму наличных денег."

^ totalIncome - totalExpenditure

Работа со словарями должна быть согласована с изменением итоговых

значений, поэтому мы не будем предост авлять доступа к самим словарям,

а лишь обеспечим достаточную информацию об их содержимом.

sources

"Возвращает множество вс ех источников поступления денег."

^ incomes keys

totalReceivedFrom: source

"Возвращает общую сумму, полученную из источника

source. Если такого источника нет, возвращает 0."

(incomes includesKey: source)

ifTrue: [^ incomes at: source]

ifFalse: [^ 0]

reasons

"Возвращает множество причин расходов."

^ expenditures keys

202 Глава 12. Домашняя бухгалтерия

totalSpentFor: reason

"Возвращает общую сумму, потраченную по причине reason.

Если по указанной причине деньги не т ратились, возвращает 0."

(expenditures includesKey: reason)

ifTrue: [^ expenditures at: reason]

ifFalse: [^ 0]

12.4. Методы ввода информации

Для ввода новой информации нужны всего два метода: один для измене-

ния доходной части, а другой — расходной. Если ключи уже есть в словаре,

новую сумму надо добавить к старой, а если нет, создать по данным новую

пару и поместить ее в словарь. Кроме того, необходимо еще изменить ито-

говое значение. Оба метода должны возвращать получателя сообщения, то

есть экземпляр класса FinancialBook.

В следующей части мы напишем интерфейс пользователя для нашей

книги учета доходов и расходов и на него возложим проверку правильности

ввода информации пользователем. Здесь же будем считать, что все данные

введены правильно.

receive: amount from: source

"Запоминает, что из источника source получена сумма amount."

incomes at: source

put: (self totalReceivedFrom: source) + amount roundTo: 0.01.

totalIncome := totalIncome + amount roundTo: 0.01

spend: amount for: reason

"Запоминает, что по причине reason потрачена сумма amount."

expenditures at: reason

put: (self totalSpentFor: reason) + amount roundTo: 0.01.

totalExpenditure := totalExpenditure + amount roundTo: 0.01

Создание класса для решения поставленных выше задач завершено.

Можно создать книгу учета доходов и расходов семьи, выполняя, напри-

мер, следующие выражения:

Smalltalk at: #FamilyFinancialBook1999 put: nil.

FamilyFinancialBook1999 := FinancialBook new.

Внесем в эту книгу некоторую информацию:

FamilyFinancialBook1999 receive: 500 from: ’Зарплата Жены’;

receive: 400 from: ’Зарплата Мужа’;

receive: 300 from: ’Пенсия Тещи’;

receive: 100 from: ’Стипендия Сына’.

12.5. Задания для самостоятельной работы 203

FamilyFinancialBook1999 spend: 150.50 for: ’На Питание’;

spend: 49.50 for: ’На Книги’;

spend: 300 for: ’На Одежду’.

Теперь на основании введенных данных из книги учета можно получить

полезную информацию:

FamilyFinancialBook1999 cashOnHand → 800.00

Чтобы сохранить этот объект для дальнейшей работы, следует сохра-

нить образ системы.

12.5. Задания для самостоятельной работы

1. В классе FinancialBook определите все оставшиеся методы доступа к

переменным экземпляра, указывая в комментарии на то, что это частные

методы. Они нам потребуются в главе 18.

2. Перепишите класс FinancialBook так, чтобы он хранил не только итого-

вые суммы доходов и расходов, итоговые суммы для каждой статьи доходов

и расходов, но и каждую конкретную сумму и дату выполнения операции

по каждой статье доходов и расходов.

3. Перепишите класс FinancialBook так, чтобы он мог безопасно работать в

многопоточной среде.

4. Перепишите класс FinancialBook так, чтобы он мог хранить информацию

и о том, кто тратит деньги.

ГЛАВА 13

КЛАССЫ TRIANGLE И NUMBERARRAY

13.1. Постановка задачи

Теперь все внимание мы направим на технологию создания нового клас-

са. Следующая наша задача будет связана со школьной математикой. Всем

хорошо известно, что такое треугольник. Все, надеемся, хорошо помнят,

сколько разнообразных задач, связанных с «решением треугольников», нам

пришлось перерешать на протяжении наших школьных лет. Вот мы и созда-

дим класс с именем Triangle, экземплярами которого будут треугольники,

а сообщения к ним позволят вычислять по имеющимся данным его новые

характеристики.

Вначале договоримся об обозначениях, которые будем применять в по-

следующих рассуждениях и формулах. Углы будем всегда измерять в радиа-

нах и обозначать буквами A, B, C. Стороны т реугольника будем называть по

противолежащим им углам и их длины обозначать буквами a, b, c, соответ-

ственно. Высоты и медианы, если они нам понадобятся, будем обозначать

по углу. Например, β

— биссектриса угла A, h

— высота треугольника,

опущенная из угла A на сторону a, m

— медиана, проведенная из угла A

в середину стороны a. Площадь треугольника будем обозначать через S, а

полупериметр треугольника — через p, то есть 2p = a+ b+ c.

Пользуясь этими обозначениями, напомним три основные теоремы для

треугольников общего вида и формулы вычисления основных его характе-

ристик (см., например, [27, с. 277, 364–367]):

Теорема косинусов: a

= b

+ c

−2bccosA.

Теорема синусов:

sinA

sinB

sinC

Теорема (формула) Герона: S =

p(p−a)(p−b)(p−c).

Радиус описанного круга: R =

abc

Радиус вписанного круга: r = S



Длина биссектрисы: β

b+ c

bcp(p−a).

Длина медианы: m

+ 2c

−a

Длина высоты: h

= 2S



a = bsinC = csinB.

13.2. Поведение объектов NumberArray 205

Основная задача состоит в том, чтобы по известным данным суметь вы-

числить неизвестные, а анализ приведенных формул показывает, что наи-

более универсальным будет представление треугольника длинами трех его

сторон. Обозначая длины сторон треугольника через sideA, sideB, sideC,

дадим следующее определение класса Triangle:

Object subclass: #Triangle

instanceVariableNames: ’sideA sideB sideC’

classVariableNames: ’ ’

poolDictionaries: ’ ’

При анализе приведенных выше формул нетрудно заметить, что нам

следует уметь вычислять сумму и произведение длин всех сторон треуголь-

ника, полезно знать наименьшую и наибольшую длину его сторон, то есть

работать с набором длин его сторон. Этот набор представим в виде число-

вого массива, с которым и будем производить требуемые вычисления. Но

в Smalltalk Express нет числовых массивов. Поэтому определим еще один

класс, необходимый нам для решения поставленной задачи. Назовем его

NumberArray. Нетрудно заметить, что разумнее всего такой класс сделать

подклассом класса Array. Отличительной особенностью класса NumberAr-

ray от созданных нами ранее классов будет то, что определяется он с по-

мощью сообщения, первое ключевое слово которого variableSubclass:, а не

subclass:. Это означает, что экземпляры данного класса будут иметь индек-

сированные переменные. Определение этого класса будет таким:

Array variableSubclass: #NumberArray

instanceVariableNames: ’ ’

classVariableNames: ’ ’

poolDictionaries: ’ ’

Других новых классов для решения задачи нам определять не нужно.

Сначала займемся вспомогательным классом NumberArray.

13.2. Поведение объектов NumberArray

Так же, как и во всех языках программирования, перед тем как исполь-

зовать объект, необходимо убедиться в том, что все его переменные ини-

циализированы должным образом. Напомним, что система автоматиче ски

инициализирует все переменные значением nil. Но когда они должны иметь

другие, более осмысленные значения, об этом следует позаботиться явно.

В нашем случае экземпляры класса NumberArray должны вести себя так

же, как и все массивы, но состоять только из чисел. Следовательно, при-

дется переопределить методы, создающие новый экземпляр класса. Кроме

206 Глава 13. Классы Triangle и NumberArray

этого, экземпляры будут обладать новым поведением. Например, они долж-

ны уметь вычислять наибольший и наименьший элемент массива, вычис-

лять сумму и произведение всех своих элементов. Это тот минимум новых

свойств, которые нам потребуются при решении основной задачи.

Начнем с метода класса, определяющего новый экземпляр. Как извест-

но, при создании нового массива с помощью сообщения new: aSize, созда-

ется экземпляр класса Array, все элементы которого равны nil. Просматри-

вая иерархию класса NumberArray, нетрудно убедиться, что все остальные

наследуемые методы создания экземпляра (например, with:) используют это

сообщение. У нас же при инициализации элементов массива должны ис-

пользоваться только числа. Поэтому надо изменить реализацию только это-

го наследуемого сообщения.

new: aSize with: aNumber

"Создает числовой набор, инициализированный числом aNumber."

^ (self basicNew: aSize) atAllPut: aNumber.

Частным случаем этого метода будет метод, по умолчанию определяю-

щий вс е элементы равными нулю:

new: aSize

"Создает числовой набор, инициализированный числом 0."

^ (self basicNew: aSize) atAllPut: 0.

Но почему все элементы набора должны быть равными? Можно при-

думать более сложные способы задания элементов. Напишем такой метод

создания нового экземпляра, который вычисляет элементы с помощью бло-

ка с одним аргументом, когда аргумент по порядку совпадает с индексом

определяемого элемента.

new: aSize accordingTo: aBlock

"Создает числовой набор, инициализированный числами,

которые получаются при выполнении одноаргументного

блока aBlock, когда его аргумент — индекс элемента."

| array |

array := self basicNew: aSize.

1 to: aSize do: [:i | array at: i put: (aBlock value: i)].

^ array.

Можно определять элемент массива и с помощью блока с двумя аргу-

ментами, первый из которых — произвольно задаваемое число, а второй —

индекс элемента. Этот метод нам пригодится при построении матриц.

new: aSize accordingTo: aBlock with: aNumber

"Создает числовой набор, инициализированный числами, которые

получаются при выполнении двухаргументного блока, его первый

аргумент — aNumber, а второй — индекс элемента."

13.2. Поведение объектов NumberArray 207

| array |

array := self basicNew: aSize.

1 to: aSize do: [:k | array at: k

put:(aBlock value: aNumber value: k)].

^ array.

Обратимся к методам экземпляра. Сначала по той же причине, что и

выше, переопределим сообщение at:put:, которое размещает в числовом

массиве новый элемент:

at: index put: aNumber

"Проверяет, что aNumder число, и, если это так,

размещает его в указанной позиции index."

(aNumber isNumber)

ifTrue: [^ self basicAt: index put: aNumber]

ifFalse: [^ 0].

Расширим функциональные возможности числовых массивов и опреде-

лим новые методы экземпляра, которые позднее применим при работе с

треугольниками.

max

"Возвращает наибольший элемент числового массива."

| max |

max := self at: 1.

self do: [:a | max < a ifTrue: [max := a]].

^ max.

min

"Возвращает наименьший элемент числового массива."

| min |

min:= self at: 1.

self do: [:a | min > a ifTrue: [min := a]].

^ min.

mult

"Возвращает произведение всех элементов числового массива."

| mult |

mult := 1.

self do: [:a | mult := mult * a].

^ mult.

sum

"Возвращает сумму всех элементов числового массива."

| sum |

208 Глава 13. Классы Triangle и NumberArray

sum := 0.

self do: [:a | sum := sum + a].

^ sum.

maybeSidesOfTriangle

"Возвращает true, если элементы числового массива могут служить

длинами сторон треугольника. Иначе возвращает false."

(self size = 3) not ifTrue: [^ false].

(self min <= 0) ifTrue: [^ false].

(self sum <= self max * 2) ifTrue: [^ false].

^ true.

Чтобы было удобно работать с числовыми массивами, надо создать ме-

тоды, которые позволяли бы производить с ними простейшие арифметиче-

ские операции, вести в них поиск нужной информации.

+ aNumberOrANumberArray

"Прибавляет к каждому элементу приемника или число,

или соответствующий элемент числового массива."

| temp |

(aNumberOrANumberArray isNumber)

ifTrue: [temp := NumberArray new: self size

with: aNumberOrANumberArray]

ifFalse: [temp := aNumberOrANumberArray].

1 to: (self size min: temp size) do: [:i |

self at: i put: (self at: i) + (temp at: i)].

multiplyFrom: index on: aNumber

"Умножает, начиная с index, все числа приемника на

aNumber, если aNumber число. Иначе ничего не делает."

(aNumber isNumber)

ifTrue: [index to: self size do: [:i |

self at: i put: (self at: i) * aNumber]]

ifFalse: [^self].

* aNumber

"Умножает каждый элемент приемника на aNumber,

если aNumber число. Иначе ничего не делает."

self multiplyFrom: 1 on: aNumber.

– aNumberOrANumberArray

"Отнимает от каждого элемента приемника число

или соответствующий элемент числового массива."

self + (aNumberOrANumberArray * –1).

13.3. Поведение объектов Triangle 209

indexAbsMaxElementFrom: index

"Вычисляет и возвращает индекс наибольшего по абсолютной

величине элемента приемника, начиная поиск с индекса index."

| max ind el |

ind := index.

max := (self at: index) abs.

index to: self size do: [:i | el := (self at: i) abs.

(max < el) ifTrue: [max := el. ind := i]].

^ind.

Таких методов можно придумать много. Мы ограничились теми, кото-

рые будут полезны при реализации в следующей главе числовых матриц.

В случае необходимости протокол класса NumberArray можно расширить,

например, определяя операции округления элементов числового массива,

поиска индекса наименьшего элемента массива и так далее.

13.3. Поведение объектов Triangle

Начнем с протокола методов класса. Этот протокол должен содержать

методы создания нового экземпляра. Мы уже решили, что треугольник

представляется длинами трех своих сторон. Но ведь полностью определить

треугольник можно, определяя две стороны и величину угла между ними

или задавая одну сторону и величину двух прилежащих к ней углов. Есть

и другие, более «экзотические» способы задания треугольника.

Ограничимся только определением треугольника по трем сторонам, ко-

торое будет использовать частный метод экземпляра sideA:sideB:sideC:,

инициализирующий переменные (он описан далее). Обратите внимание,

что имена метода класса и метода экземпляра совпадают, но это не страш-

но: они посылаются разным объектам системы.

sideA: aNumber1 sideB: aNumber2 sideC: aNumber3

"Проверяет допустимость данных. Если они допустимы, тогда

создает треугольник со сторонами, имеющими длины, равные

аргументам. Если они не допустимы, сообщает об ошибке."

| sides |

sides := NumberArray with: aNumber1

with: aNumber2 with: aNumber3.

sides maybeSidesOfTriangle

ifTrue: [^ super new sideA: aNumber1

sideB: aNumber2 sideC: aNumber3]

ifFalse: [self error: ’It is inadmissible data for triangle.’].