Справочник по языку программирования MQL5

Подождите немного. Документ загружается.

Операции с графиками

581

Функция ChartApplyTemplate() предназначена для использования ранее сохраненного шаблона и

может использоваться в любой mql5-программе. Вторым параметром функции ChartApplyTemplate

() передается путь к имени файла, в котором находится шаблон. Поиск файла шаблона

осуществляется по следующим правилам:

если в начале пути стоит разделитель обратная косая черта "\" (пишется "\\"), то шаблон ищется

относительно пути каталог_данных_терминала\MQL5,

если обратной косой черты нет, то шаблон ищется относительно исполняемого EX5-файла, в

котором происходит вызов функции ChartApplyTemplate();

если шаблон не найден в первых двух вариантах, то поиск ведется в папке

каталог_терминала\Profiles\Templates\.

Здесь каталог_терминала означает папку, из которой запущен клиентский терминала MetaTrader

5, а каталог_данных_терминала означает папку, в которой хранятся изменяемые файлы и ее

расположение может зависеть от типа операционной системы, имени пользователя и настроек

безопасности компьютера. В общем случае это разные папки, хотя в некоторых случаях могут и

совпадать.

Расположение папок каталог_данных_терминала и каталог_терминала можно узнать с помощью

функции TerminalInfoString().

//--- каталог из которой запущен терминал

string terminal_path=TerminalInfoString(TERMINAL_PATH);

Print("Каталог терминала:",terminal_path);

//--- каталог данных терминала, в котором находится папка MQL5 с советниками и индикаторами

string terminal_data_path=TerminalInfoString(TERMINAL_DATA_PATH);

Print("Каталог данных терминала:",terminal_data_path);

Примеры записи:

//--- шаблон ищем в папке каталог_данных_терминала\MQL5\

ChartApplyTemplate(0,"\\first_template.tpl"))

//--- шаблон ищем в папке каталог_исполняемого_EX5_файла\, затем в папке каталог_данных терминала\Profiles\Templates\

ChartApplyTemplate(0,"second_template.tpl"))

//--- шаблон ищем в папке каталог_исполняемого_EX5_файла\My_templates\, затем в папке каталог_терминала\Profiles\Templates\My_templates\

ChartApplyTemplate(0,"My_templates\\third_template.tpl"))

Шаблоны не относятся к ресурсам, их нельзя включать в исполняемый файл EX5.

Пример:

Операции с графиками

582

//+------------------------------------------------------------------+

//| Script program start function |

//+------------------------------------------------------------------+

void OnStart()

{

//--- попытаемся открыть и применить шаблон my_template.tpl

if(!ChartApplyTemplate(0,"my_template"))

{

//--- не удалось применить шаблон my_template

Print("Не удалось применить шаблон 'my_template', ошибка ",GetLastError());

ResetLastError();

//--- поищем просто файл "my_template" без расширения tpl

if(FileIsExist("my_template"))

Print("Существует файл my_template, требуется же 'my_template.tpl'");

else

Print("Файл 'my_template.tpl' не найден в папке "

+TerminalInfoString(TERMINAL_PATH)

+"\\MQL5\\Files");

//--- теперь правильно передадим имя файла - с расширением *.tpl

if(ChartApplyTemplate(0,"my_template.tpl"))

Print("Применили успешно шаблон 'my_template.tpl'");

else

Print("Не удалось применить шаблон 'my_template.tpl', ошибка ",GetLastError());

}

else

{

//--- шаблон хранится в файле без расширения

Print("Применили успешно шаблон 'my_template' - файл без расширения");

}

Смотри также

Ресурсы

Операции с графиками

583

ChartWindowFind

Возвращает номер подокна, в котором находится индикатор. Существует 2 варианта функции.

1. Функция ищет на указанном графике подокно с указанным "коротким именем" индикатора

(короткое имя выводится слева вверху подокна) и в случае удачи возвращает номер подокна.

int ChartWindowFind(

long chart_id, // идентификатор графика

string indicator_shortname // короткое имя индикатора, см INDICATOR_SHORTNAME

2. Функция должна вызываться из пользовательского индикатора и возвращает номер подокна, в

котором этот индикатор работает.

int ChartWindowFind();

Параметры

chart_id

[in] Идентификатор графика. 0 означает текущий график.

indicator_shortname

[in] Короткое имя индикатора.

Возвращаемое значение

Номер подокна в случае удачи. Ноль означает главное окно графика. В случае неудачи

возвращает -1.

Примечание

Если вызывается второй вариант функции (без параметров) из скрипта или эксперта, то она

возвращает -1.

Не следует путать короткое имя индикатора и имя файла, которое указывается при создании

индикатора функциями iCustom() и IndicatorCreate(). Если короткое наименование индикатора

не задается явным образом, то при компиляции в нем указывается имя файла с исходным

кодом индикатора.

Необходимо правильно формировать короткое имя индикатора, которое с помощью функции

IndicatorSetString() записывается в свойство INDICATOR_SHORTNAME. Мы рекомендуем, чтобы

короткое имя содержало значения входных параметров индикатора, так как идентификация

удаляемого с графика индикатора в функции ChartIndicatorDelete() производится именно по

короткому имени.

Пример:

Операции с графиками

584

#property script_show_inputs

//--- input parameters

input string shortName="MACD(12,26,9)";

//+------------------------------------------------------------------+

//| сообщает номер окна графика с указанным индикатором |

//+------------------------------------------------------------------+

int GetIndicatorSubWindowNumber(long chartID=0,string short_name="")

{

int window=-1;

//---

if((ENUM_PROGRAM_TYPE)MQL5InfoInteger(MQL5_PROGRAM_TYPE)==PROGRAM_INDICATOR)

{

//--- функция вызвана из индикатора,имя не требуется

window=ChartWindowFind();

}

else

{

//--- функция вызвана из эксперта или скрипта

window=ChartWindowFind(0,short_name);

if(window==-1) Print(__FUNCTION__+"(): Error = ",GetLastError());

}

//---

return(window);

}

//+------------------------------------------------------------------+

//| Script program start function |

//+------------------------------------------------------------------+

void OnStart()

{

//---

int window=GetIndicatorSubWindowNumber(0,shortName);

if(window!=-1)

Print("Индикатор "+shortName+" находится в окне №"+(string)window);

else

Print("Индикатор "+shortName+" не найден. window = "+(string)window);

}

Смотри также

ObjectCreate(), ObjectFind()

Операции с графиками

585

ChartOpen

Открывает новый график с указанным символом и периодом.

long ChartOpen(

string symbol, // имя символа

ENUM_TIMEFRAMES period // период

);

Параметры

symbol

[in] Символ графика. NULL oзначает символ текущего графика (к которому прикреплен

эксперт).

period

[in] Период графика (таймфрейм). Может принимать одно из значений перечисления

ENUM_TIMEFRAMES. 0 означает период текущего графика.

Возвращаемое значение

При успешном открытии графика функция возвращает идентификатор графика. В противном

случае возвращает 0.

Примечание

Максимально возможное количество одновременно открытых графиков в терминале не может

быть больше, чем значение CHARTS_MAX.

Операции с графиками

586

ChartFirst

Возвращает идентификатор первого графика клиентского терминала.

long ChartFirst();

Возвращаемое значение

Идентификатор графика.

Операции с графиками

587

ChartNext

Функция возвращает идентификатор графика, следующего за указанным.

long ChartNext(

long chart_id // идентификатор графика

);

Параметры

chart_id

[in] Идентификатор графика. 0 не означает текущий график. 0 означает "вернуть

идентификатор первого графика".

Возвращаемое значение

Идентификатор графика. Если список графиков закончился, функция возвращает -1.

Пример:

//--- переменные для идентификаторов графиков

long currChart,prevChart=ChartFirst();

int i=0,limit=100;

Print("ChartFirst = ",ChartSymbol(prevChart)," ID = ",prevChart);

while(i<limit)// у нас наверняка не больше 100 открытых графиков

{

currChart=ChartNext(prevChart); // на основании предыдущего получим новый график

if(currChart<0) break; // достигли конца списка графиков

Print(i,ChartSymbol(currChart)," ID =",currChart);

prevChart=currChart;// запомним идентификатор текущего графика для ChartNext()

i++;// не забудем увеличить счетчик

}

Операции с графиками

588

ChartClose

Закрывает указанный график.

bool ChartClose(

long chart_id=0 // идентификатор графика

);

Параметры

chart_id=0

[in] Идентификатор графика. 0 означает текущий график.

Возвращаемое значение

Возвращает true в случае успеха, иначе false.

Операции с графиками

589

ChartSymbol

Возвращает имя символа указанного графика.

string ChartSymbol(

long chart_id=0 // идентификатор графика

);

Параметры

chart_id=0

[in] Идентификатор графика. 0 означает текущий график.

Возвращаемое значение

Если графика не существует, то возвращается пустая строка.

Смотри также

ChartSetSymbolPeriod

Операции с графиками

590

ChartPeriod

Возвращает значение периода указанного графика.

ENUM_TIMEFRAMES ChartPeriod(

long chart_id=0 // идентификатор графика

);

Параметры

chart_id=0

[in] Идентификатор графика. 0 означает текущий график.

Возвращаемое значение

Значение типа ENUM_TIMEFRAMES. Если графика не существует, то возвращается 0.