Sтер 7 Lite. Программирование в Sтер 7 Lite V2.0
Подождите немного. Документ загружается.
Приложение
Программирование в Step7 Lite V.2.0
A5E00142284-01
A-85
A.4.5.4 Создание FB двигателя
Что требуется от FB?
FB двигателя содержит следующие логические функции:
• Имеются входы запуска и останова.
• Ряд блокировок разрешает работу устройств (насо сов и двигателя
мешалки). Состояние блокировок хранится во временных локальных
данных (L-стек) блока OB1 (”Motor_enable", ”Valve_enable"), и эти
значения логически складываются со значениями входов пуска и
останова во время обработки FB двигателя.
• Сигнал обратной связи от устройств должен появляться в течение
заданного времени. Иначе предполагается, что произошла ошибка
или отказ. И в этом случае функция останавливает двигатель.
• Момент времени и длительность ответного сигнала или цикл
ошибки/погрешности должны быть определены.
• По нажатии кнопки запуска включается двигатель, установка
переходит в режим работы и работает до нажатия кнопки останова.
• Как только устройство включается, начинает работать таймер. Если
ответный сигнал от устройства не получен до истечения времени
таймера, устройство останавливается.
Определение входов и выходов
На следующей схеме показаны входы и выходы общего FB двигателя.
Start
Stop
Reset_Maint
Response
Timer_No
Start_Dsp
Fault
Stop_Dsp
Response_Time
Motor
Maint
Motor
[Двигатель]
Приложение
Программирование в Step7 Lite V.2.0
A-86 A5E00142284-01
Определение параметров FB
Если Вы используете мультиэкземплярный FB для двигателя (для
управления как насосами, так и двигателем), Вы должны определить
общие имена входных и выходных параметров.
Для FB двигателя необходимо следующее:
• Он должен получать сигналы от станции оператора, чтобы
останавливать и запускать двигатель и насосы.
• Он должен получать ответных сигналов от двигателя и насосов,
означающих что двигатель работает.
• Он должен вычислять время между передачей сигнала на запуск и
получением ответного сигнала. Если за это время ответный синал не
получен, двигатель должен быть выключен.
• Он должен включатьи выключать индикаторы на станции оператора.
• Он выдает сигнал для включения двигателя.
Выполнение эти х требований можно обеспечить с помощью входов и
выходов FB. Следующая таблица содержит параметры FB двигателя,
описанного процесса.
Имя параметра Входные Выходные Входные-
выходные
Start n
Stop n
Response n
Reset_maint n
Timer_No n
Response_Time n
Fault
n
Start_Dsp
n
Stop_Dsp
n
Maint
n
Motor
n
Приложение
Программирование в Step7 Lite V.2.0
A5E00142284-01
A-87
Объявление переменных FB двигателя
Входные, выходные и входные-выходные параметры FB двигателя
должны быть объявлены.
Адрес Описание Имя Тип Начальное
значение
0.0 in Start BOOL FALSE
0.1 in Stop BOOL FALSE
0.2 in Response BOOL FALSE
0.3 in Reset_Maint BOOL FALSE
2.0 in Timer_No TIMER
4.0 in Response_Time S5TIME S5T#0MS
6.0 out Fault BOOL FALSE
6.1 out Start_Dsp BOOL FALSE
6.2 out Stop_Dsp BOOL FALSE
6.3 out Maint BOOL FALSE
8.0 in_out Motor BOOL FALSE
10.0 stat Timer_bin WORD W#16#0
12.0 stat Timer_BCD WORD W#16#0
14.0 stat Starts INT 0
16.0 stat Start_Edge BOOL FALSE
В FB входные, выходные, входные-выходные и статические переменные
сохраняются в DB, определяемом в команде вызова. Временные
переменные сохраняются в L-стеке.
Программирование FB двигателя
В STEP 7 Lite вызываемый блок должен быть создан раньше
вызывающего блока. Поэтому FB двигателя должен быть создан до OB1.
Код FВ1 на языке программирования STL выглядит следующим образом:
Сегмент 1 Запуск, останов и блокировка
A(
O #Start
O #Motor
)
AN #Stop
= #Motor
Приложение
Программирование в Step7 Lite V.2.0
A-88 A5E00142284-01
Сегмент 2 Запуск мониторинга
A #Motor
L #Response_Time
SD #Timer_No
AN #Motor
R #Timer_No
L #Timer_No
T #Timer_bin
LC #Timer_No
T #Timer_BCD
A #Timer_No
AN #Response
S #Fault
R #Motor
Сегмент 3 Сброс индикаторов запуска и ошибок
A #Response
= #Start_Dsp
R #Fault
Сегмент 4 Остановка индикатора
AN #Response
= #Stop_Dsp
Сегмент 5 Подсчет запусков
A #Motor
FP #Start_Edge
JCN lab1
L #Starts
+ 1
T #Starts
lab1: NOP 0
Сегмент 6 Индикатор эксплуатации
L #Starts
L 50
>=I
= #Maint
Сегмент 7 Сброс счетчика количества запусков
A #Reset_Maint
A #Maint
JCN END
L 0
T #Starts
END: NOP 0
Создание экземпляра блока данных
Чтобы созд ать три блока данных, выберите для каждого из них команду
меню Insert [Вставка] > Block [Блок]. Выберите опцию "Data Block [Блок
Данных]" и введите соответстующие номера блоков данных. В соседнем
выпадающем списке "Reference [Ссылка]" выберите функциональный блок
"FB1". Теперь блоки данных определены как экземпляры блоков данных
для FB1.
Приложение
Программирование в Step7 Lite V.2.0
A5E00142284-01
A-89
A.4.5.5 Создание FC клапанов
Требования к FC?
Функция для впускного, подающего и дренажного клапанов содержит
следующие логические функции:
• Имеется вход для открытия и вход для закрытия клапанов.
• Открытие клапанов управляется блокировками. Значения состояний
блокировок сохраняются во временных локальных данных (L-стек)
блока OB1 (”Valve_enable"), и во время обработки FC клапанов эти
значения логически складываются с входами открытия и закрытия.
В следующей таблице показаны параметры, передаваемые в FC.
Парамет ры для клапанов Входные Выходные Входные-
выходные
Open
"
Close
"
Dsp_Open
"
Dsp_Closed
"
Valve
"
Определение входов и выходов
На следующей схеме показаны входы и выходы общего для клапанов FC.
Механизмы, вызывающие FB двигателя, передают входные параметры.
FC клапанов возвращает выходные параметры.
Valve
[Êëàï àí ]
û
Open
Close
Dsp_Open
Valve
Dsp_Closed
Приложение
Программирование в Step7 Lite V.2.0
A-90 A5E00142284-01
Объявление переменных FC клапанов
Так же, как и для FB двигателя, Вы должны объявить входные, выходные
и вхо дные-выходные параметры для FC клапанов (см. следующую
таблицу объявления переменных).
Адрес Описание Имя Тип Начальное
значение
0.0 in Open BOOL FALSE
0.1 in Close BOOL FALSE
2.0 out Dsp_Open BOOL FALSE
2.1 out Dsp_Closed BOOL FALSE
4.0 in_out Valve BOOL FALSE
Для FC временные переменные хранятся в L-стеке. Входные, выходные и
входные-вы ходные переменные хранятся в виде указателей на
логический блок, который вызвал FC. Для этих переменных используется
дополнительная область памяти в L-стеке (после временных
переменных).
Программирование FC клапанов
Функция FC1 клапанов должна быть создана до OB1, потому что
вызываемые блоки должны быть созданы до вызывающих их блоков.
Область кода FC1 на языке программирования STL выглядит следующим
образом:
Сегмент 1 Открытие, закрытие и блокировка
A(
O #Open
O #Valve
)
AN #Close
= #Valve
Сегмент 2 Индикация "клапан открыт"
A #Valve
= #Dsp_Open
Сегмент 3 Индикация "клапан закрыт"
AN #Valve
= #Dsp_Closed
Приложение
Программирование в Step7 Lite V.2.0
A5E00142284-01
A-91
A.4.5.6 Создание OB1
OB1 определяет структуру программы. А также содержит параметры,
которые передаются разным функциям, например:
• STL сегменты для подающих насосов и двигателя мешалки
обеспечивают FB двигателя входными параметрами для запуска
("Start"), останова ("Stop"), отклика ("Response") и для сброса
отображения состояния эксплуатации ("Reset_Maint"). FB двигателя
обрабатывается в каждом цикле ПЛК.
• При обработке FB двигателя входы Timer_No и Response_Time
сообщают функции об используемом таймера и о промежутке
времени, который должен измеряться.
• FC клапанов и FB двигателей обрабатываются в каждом программном
цикле программируемого контроллера, так как они вызываются в OB1.
Для обработки задач управления подающими насосами и двигателем
мешалки програма использует FB двигателя с различными экземплярами
DB.
Объявление переменных для OB1
Ниже показана таблица объявления переменных для OB1. Первые 20
байтов содержат начальную информацию о OB1 и не должны быть
изменяться.
Адрес Описание Имя Тип
0.0 temp OB1_EV_CLASS BYTE
1.0 temp OB1_SCAN1 BYTE
2.0 temp OB1_PRIORITY BYTE
3.0 temp OB1_OB_NUMBR BYTE
4.0 temp OB1_RESERVED_1 BYTE
5.0 temp OB1_RESERVED_2 BYTE
6.0 temp OB1_PREV_CYCLE INT
8.0 temp OB1_MIN_CYCLE INT
10.0 temp OB1_MAX_CYCLE INT
12.0 temp OB1_DATE_TIME DATE_AND_TIME
20.0 temp Enable_motor BOOL
20.1 temp Enable_valve BOOL
20.2 temp Start_fulfilled BOOL
20.3 temp Stop_fulfilled BOOL
20.4 temp Inlet_valve_A_open BOOL
20.5 temp Inlet_valve_A_closed BOOL
20.6 temp Feed_valve_A_open BOOL
20.7 temp Feed_valve_A_closed BOOL
21.0 temp Inlet_valve_B_open BOOL
21.1 temp Inlet_valve_B_closed BOOL
21.2 temp Feed_valve_B_open BOOL
21.3 temp Feed_valve_B_closed BOOL
21.4 temp Open_drain BOOL
21.5 temp Close_drain BOOL
21.6 temp Valve_closed_fulfilled BOOL
Приложение
Программирование в Step7 Lite V.2.0
A-92 A5E00142284-01
Создание программы для OB1
В STEP 7 Lite вызываемый б локом должен быть созд ан раньше
вызывающего блока. Поэтому в примере программы Вы должны создать
FB двигателя и FC клапанов до написания программы OB1.
Блоки FB1 и FC1 вызываются в OB1 не один раз; FB1 вызывается с
разными экземплярами DB:
Подающий насос
инг
р
едиента В
OB 1
Впускной
клапан A
Подающий
клапан A
Двигатель
мешалки
Дренажный
клапан
Подающий
клапан B
FB 1
Экземпляр DB 1
FB 1
Экземпляр DB 2
FB 1
Экземпляр DB 3
FC 1
FC 1
FC 1
FC 1
FC 1
Операционная
система
Подающий насос
ингридиента A
Впускной
клапан B
Переключатель для
изме
р
ения
уровня резервуара
Область кода OB1 на языке программирования STL выглядит следующим
образом:
Приложение
Программирование в Step7 Lite V.2.0
A5E00142284-01
A-93
Сегмент 1 Блокировки для подающего насоса A
A "EMER_STOP_off"
A "Tank_below_max"
AN "Drain"
= #Enable_Motor
Сегмент 2 Вызов FB двигателя для ингредиента A
A "Feed_pump_A_start"
A #Enable_Motor
= #Start_Fulfilled
A(
O "Feed_pump_A_stop"
ON #Enable_Motor
)
= #Stop_Fulfilled
CALL "Motor_block", "DB_feed_pump_A"
Start :=#Start_Fulfilled
Stop :=#Stop_Fullfilled
Response :="Flow_A"
Reset_Maint :="Reset_maint"
Timer_No :=T12
Reponse_Time:=S5T#7S
Fault :="Feed_pump_A_fault"
Start_Dsp :="Feed_pump_A_on"
Stop_Dsp :="Feed_pump_A_off"
Maint :="Feed_pump_A_maint"
Motor :="Feed_pump_A"
Сегмент 3 Задержка включения насоса для ингредиента A
A "Feed_pump_A"
L S5T#1S
SD T 13
AN "Feed_pump_A"
R T 13
A T 13
= #Enable_Valve
Сегмент 4 Управление впускным клапаном для ингр едиента A
AN "Flow_A"
AN "Feed_pump_A"
= #Close_Valve_Fulfilled
CALL "Valve_block"
Open :=#Enable_Valve
Close :=#Close_Valve_Fulfilled
Dsp_Open :=#Inlet_Valve_A_Open
Dsp_Closed:=#Inlet_Valve_A_Closed
Valve :="Inlet_Valve_A"
Приложение
Программирование в Step7 Lite V.2.0
A-94 A5E00142284-01
Сегмент 5 Управление подающим клапаном для ингредиента A
AN "Flow_A"
AN "Feed_pump_A"
= #Close_Valve_Fulfilled
CALL "Valve_block"
Open :=#Enable_Valve
Close :=#Close_Valve_Fulfilled
Dsp_Open :=#Feed_Valve_A_Open
Dsp_Closed:=#Feed_Valve_A_Closed
Valve :="Feed_Valve_A"
Сегмент 6 Блокировки для подающего насоса B
A "EMER_STOP_off"
A "Tank_below_max"
AN "Drain"
= #Enable_Motor
Сегмент 7 Вызов FB двигателя для ингредиента B
A "Feed_pump_B_start"
A #Enable_Motor
= #Start_Fulfilled
A(
O "Feed_pump_B_stop"
ON #Enable_Motor
)
= #Stop_Fulfilled
CALL "Motor_block", "DB_feed_pump_B"
Start :=#Start_Fulfilled
Stop :=#Stop_Fulfilled
Response :="Flow_B"
Reset_Maint :="Reset_maint"
Timer_No :=T14
Reponse_Time:=S5T#7S
Fault :="Feed_pump_B_fault"
Start_Dsp :="Feed_pump_B_on"
Stop_Dsp :="Feed_pump_B_off"
Maint :="Feed_pump_B_maint"
Motor :="Feed_pump_B"
Сегмент 8 Задержка включения насоса для ингредиента B
A "Feed_pump_B"
L S5T#1S
SD T 15
AN "Feed_pump_B"
R T 15
A T 15
= #Enable_Valve