Справочник по языку программирования MQL5

Подождите немного. Документ загружается.

Пользовательские индикаторы

721

Все цветовые версии стилей отличаются от базовых тем, что позволяют задавать цвет для каждой

части графического построения. Минимальной частью построения является бар, поэтому можно

сказать, что цветовые версии позволяют задавать цвет построения на каждом баре.

Для того, чтобы задавать цвет построения на каждом баре, в цветовые версии стилей был

добавлен дополнительный специальный буфер для хранения индекса цвета. Эти индексы

указывают на номер цвета в специальном массиве, содержащем заранее определенный набор

цветов. Размер массива цветов – 64. Это означает, что каждая цветовая версия стиля позволяет

раскрасить графическое построение 64-мя различными цвета.

Набор и количество цветов в специальном массиве цветов можно задавать директивой

компилятора #property indicator_color, где через запятую указываются все необходимые цвета.

Например, такая запись в индикаторе:

//--- зададим 8 цветов для раскраски свечей (они хранятся в специальном массиве)

#property indicator_color1 clrRed,clrBlue,clrGreen,clrYellow,clrMagenta,clrCyan,clrLime,clrOrange

Здесь указано, что для графического построения номер 1 заданы 8 цветов, которые будут

помещены в специальный массив. Далее в программе мы будем указывать не сам цвет, которым

будет отображаться графическое построение, а только его индекс. Если мы хотим задать для

бара красный цвет, то для этого необходимо установить в цветовом буфере индекс красного

цвета из массива. Красный цвет задан в директиве первым первым, ему соответствует индекс

номер 0.

//--- зададим цвет свечи clrRed

col_buffer[buffer_index]=0;

Набор цветов для раскрашивания не является раз и навсегда заданным, его можно менять

динамически с помощью функции PlotIndexSetInteger(). Пример:

//--- установим цвет для каждого индекса как свойство PLOT_LINE_COLOR

PlotIndexSetInteger(0, // номер графического стиля

PLOT_LINE_COLOR, // идентификатор свойства

plot_color_ind, // индекс цвета, куда запишем цвет

color_array[i]); // новый цвет

Свойства индикатора и графических построений

Для графических построений свойства можно устанавливать как с помощью директив

компилятора, так и с помощью соответствующих функций. Подробней об этом написано в разделе

Связь между свойствами индикатора и функциями. Динамическое изменение свойств индикатора

с помощью функций позволяет создавать более гибкие пользовательские индикаторы.

Начало отрисовки индикатора на графике

Во многих случаях по условиям алгоритма расчет значений индикатора невозможно начать сразу

же с текущего бара, требуется обеспечить минимальное количество предыдущих доступных баров

в истории. Например, многие виды сглаживания подразумевают, что берется массив цен за

предыдущие N баров, и на основании этих значений рассчитывается значение индикатора для

Пользовательские индикаторы

722

текущего бара.

В таких случаях либо нет возможности рассчитать значения индикатора на N самых первых барах,

либо эти значения не предназначены для отображения на графике и являются только

вспомогательными для расчета последующих значений. Чтобы отказаться от визуализации

индикатора на первых N барах истории, следует установить свойству PLOT_DRAW_BEGIN

значение N для соответствующего графического построения:

//--- связывание массивов с индикаторными буферами под японские свечи

PlotIndexSetInteger(номер_графического_построения,PLOT_DRAW_BEGIN,N);

Здесь:

номер_графического_построения – значение от нуля до indicator_plots-1 (нумерация

графических построений начинается с нуля).

N – количество первых в истории баров, на которых индикатор не должен отображаться на

графике.

Пользовательские индикаторы

723

DRAW_NONE

Стиль DRAW_NONE предназначен для тех случаев, когда значения буфера необходимо

рассчитывать и показывать в "Окне данных", но само отображение на графике не требуется. Для

настройки точности отображения используйте в функции OnInit() выражение IndicatorSetInteger

(INDICATOR_DIGITS,количество_знаков):

int OnInit()

{

//--- indicator buffers mapping

SetIndexBuffer(0,InvisibleBuffer,INDICATOR_DATA);

//--- установим точность, с которой значение будет показываться в Окне данных

IndicatorSetInteger(INDICATOR_DIGITS,0);

//---

return(0);

}

Количество требуемых буферов для построения DRAW_NONE — 1.

Пример индикатора, который показывает в "Окне данных" номер бара, на котором находится

мышка. Нумерация соответствует таймсерии, то есть текущий незавершенный бар имеет нулевой

индекс, а самый старый бар имеет самый большой индекс.

Обратите внимание, что несмотря на то, что для графического построения №1 указан красный

цвет отображения, индикатор ничего не рисует на графике.

//+------------------------------------------------------------------+

//| DRAW_NONE.mq5 |

//| http://www.mql5.com |

Пользовательские индикаторы

724

//+------------------------------------------------------------------+

#property link "http://www.mql5.com"

#property version "1.00"

#property indicator_chart_window

#property indicator_buffers 1

#property indicator_plots 1

//--- plot Invisible

#property indicator_label1 "Bar Index"

#property indicator_type1 DRAW_NONE

#property indicator_style1 STYLE_SOLID

#property indicator_color1 clrRed

#property indicator_width1 1

//--- indicator buffers

double InvisibleBuffer[];

//+------------------------------------------------------------------+

//| Custom indicator initialization function |

//+------------------------------------------------------------------+

int OnInit()

{

//--- связывание массива и индикаторного буфера

SetIndexBuffer(0,InvisibleBuffer,INDICATOR_DATA);

//--- установим точность, с которой значение будет показываться в "Окне данных"

IndicatorSetInteger(INDICATOR_DIGITS,0);

//---

return(0);

}

//+------------------------------------------------------------------+

//| Custom indicator iteration function |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

const int prev_calculated,

const datetime &time[],

const double &open[],

const double &high[],

const double &low[],

const double &close[],

const long &tick_volume[],

const long &volume[],

const int &spread[])

{

static datetime lastbar=0;

//--- если это первый расчет индикатора

if(prev_calculated==0)

{

//--- перенумеруем бары в первый раз

CalcValues(rates_total,close);

//--- запомним время открытия текущего бара в lastbar

Пользовательские индикаторы

725

lastbar=(datetime)SeriesInfoInteger(_Symbol,_Period,SERIES_LASTBAR_DATE);

}

else

{

//--- если появился новый бар, время его открытия не совпадает с lastbar

if(lastbar!=SeriesInfoInteger(_Symbol,_Period,SERIES_LASTBAR_DATE))

{

//--- перенумеруем бары заново

CalcValues(rates_total,close);

//--- обновим время открытия текущего бара в lastbar

lastbar=(datetime)SeriesInfoInteger(_Symbol,_Period,SERIES_LASTBAR_DATE);

}

//--- return value of prev_calculated for next call

return(rates_total);

}

//+------------------------------------------------------------------+

//| нумерует бары как в таймсерии |

//+------------------------------------------------------------------+

void CalcValues(int total,double const &array[])

{

//--- зададим индикаторному буферу индексацию как в таймсерии

ArraySetAsSeries(InvisibleBuffer,true);

//--- заполним каждому бару его номер

for(int i=0;i<total;i++) InvisibleBuffer[i]=i;

}

Пользовательские индикаторы

726

DRAW_LINE

Стиль DRAW_LINE рисует заданным цветом линию по значениям индикаторного буфера. Толщину,

цвет и стиль отображения линии можно задавать как директивами компилятора, так и

динамически с помощью функции PlotIndexSetInteger(). Динамическое изменение свойств

графического построения позволяет создавать "живые" индикаторы, которые меняют свой вид в

зависимости от текущей ситуации.

Количество требуемых буферов для построения DRAW_LINE — 1.

Пример индикатора, рисующего линию ценам закрытия баров Close. Цвет, толщина и стиль линии

меняются случайным образом каждые N=5 тиков.

Обратите внимание, первоначально для графического построения plot1 со стилем DRAW_LINE

свойства задаются с помощью директивы компилятора #property, а затем в функции OnCalculate()

эти три свойства задаются случайным образом. Параметр N вынесен во внешние параметры

индикатора для возможности ручной установки (закладка "Параметры" в окне свойств

индикатора).

//+------------------------------------------------------------------+

//| DRAW_LINE.mq5 |

//| http://www.mql5.com |

//+------------------------------------------------------------------+

#property link "http://www.mql5.com"

#property version "1.00"

#property description "Индикатор для демонстрации DRAW_LINE"

#property description "Рисует линию заданным цветом по ценам Close"

#property description "Цвет, толщина и стиль линии меняется случайным образом"

Пользовательские индикаторы

727

#property description "через каждые N тиков"

#property indicator_chart_window

#property indicator_buffers 1

#property indicator_plots 1

//--- свойства линии заданы с помощью лиректив компилятора

#property indicator_label1 "Line" // название построения для "Окна данных"

#property indicator_type1 DRAW_LINE // тип графического построения - линия

#property indicator_color1 clrRed // цвет линии

#property indicator_style1 STYLE_SOLID // стиль линии

#property indicator_width1 1 // толщина линии

//--- input параметр

input int N=5; // кол-во тиков для изменения

//--- индикаторный буфер для построения

double LineBuffer[];

//--- массив для хранения цветов

color colors[]={clrRed,clrBlue,clrGreen};

//--- массив для хранения стилей отрисовки линии

ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};

//+------------------------------------------------------------------+

//| Custom indicator initialization function |

//+------------------------------------------------------------------+

int OnInit()

{

//--- связывание массива и индикаторного буфера

SetIndexBuffer(0,LineBuffer,INDICATOR_DATA);

//--- инициализация генератора псевдослучайных чисел

MathSrand(GetTickCount());

//---

return(0);

}

//+------------------------------------------------------------------+

//| Custom indicator iteration function |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

const int prev_calculated,

const datetime &time[],

const double &open[],

const double &high[],

const double &low[],

const double &close[],

const long &tick_volume[],

const long &volume[],

const int &spread[])

{

static int ticks=0;

//--- считаем тики для изменения стиля, цвета и толщины линии

ticks++;

Пользовательские индикаторы

728

//--- если накопилось критическое число тиков

if(ticks>=N)

{

//--- меняем свойства линии

ChangeLineAppearance();

//--- сбрасываем счетчик тиков в ноль

ticks=0;

}

//--- блок расчета значений индикатора

for(int i=0;i<rates_total;i++)

{

LineBuffer[i]=close[i];

}

//--- вернем значение prev_calculated для следующего вызова функции

return(rates_total);

}

//+------------------------------------------------------------------+

//| изменяет внешний вид отображаемой линии в индикаторе |

//+------------------------------------------------------------------+

void ChangeLineAppearance()

{

//--- строка для формирования информации о свойствах линии

string comm="";

//--- блок изменнения цвета линии

//--- получим случайное число

int number=MathRand();

//--- делитель числа равен размеру массива colors[]

int size=ArraySize(colors);

//--- получим индекс для выбора нового цвета как остаток от целочисленного деления

int color_index=number%size;

//--- установим цвет как свойство PLOT_LINE_COLOR

PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);

//--- запишем цвет линии

comm=comm+(string)colors[color_index];

//--- блок изменения толщины линии

number=MathRand();

//--- получим толщину как остаток от целочисленного деления

int width=number%5; // толщина задается от о до 4

//--- установим цвет как свойство PLOT_LINE_WIDTH

PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);

//--- запишем толщину линии

comm=comm+", Width="+IntegerToString(width);

//--- блок изменения стиля линии

number=MathRand();

Пользовательские индикаторы

729

//--- делитель числа равен размеру массива styles

size=ArraySize(styles);

//--- получим индекс для выбора нового стиля как остаток от целочисленного деления

int style_index=number%size;

//--- установим цвет как свойство PLOT_LINE_COLOR

PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);

//--- запишем стиль линии

comm=EnumToString(styles[style_index])+", "+comm;

//--- выведем информацию на график через комментарий

Comment(comm);

}

Пользовательские индикаторы

730

DRAW_SECTION

Стиль DRAW_SECTION рисует заданным цветом отрезки по значениям индикаторного буфера.

Толщину, цвет и стиль отображения линии можно задавать так же, как и для стиля DRAW_LINE –

директивами компилятора или динамически с помощью функции PlotIndexSetInteger().

Динамическое изменение свойств графического построения позволяет "оживить" индикаторы,

чтобы они меняли свой вид в зависимости от текущей ситуации.

Секции рисуются от одного непустого значения до другого непустого значения индикаторного

буфера, пустые значения пропускаются. Чтобы указать, какое значение следует считать "пустым",

установите это значение в свойстве PLOT_EMPTY_VALUE. Например, если индикатор должен

рисоваться отрезками по ненулевым значениям, то нужно задать нулевое значение в качестве

пустого:

//--- значение 0 (пустое значение) не будет участвовать в отрисовке

PlotIndexSetDouble(индекс_построения_DRAW_SECTION,PLOT_EMPTY_VALUE,0);

Всегда явно заполняйте значениями все элементы индикаторного буфера, неотрисовываемым

элементам задавайте пустое значение.

Количество требуемых буферов для построения DRAW_SECTION — 1.

Пример индикатора, рисующего отрезки между ценами High и Low. Цвет, толщина и стиль всех

секций меняются случайным образом каждые N тиков.

Обратите внимание, первоначально для графического построения plot1 со стилем DRAW_SECTION

свойства задаются с помощью директивы компилятора #property, а затем в функции OnCalculate()

эти три свойства задаются случайным образом. Параметр N вынесен во внешние параметры

индикатора для возможности ручной установки (закладка "Параметры" в окне свойств

индикатора).

//+------------------------------------------------------------------+