Справочник по языку программирования MQL5

Подождите немного. Документ загружается.

Основы языка

десятичный код

'\d'

десятичное число от

0 до 65535

Если за обратной косой чертой следует символ, отличный от перечисленных, результат не

определен.

Пример

void OnStart()

{

//--- объявим символьные константы

int a='A';

int b='$';

int c='©'; // код 0xA9

int d='\xAE'; // код символа ®

//--- выведем константы на печать

Print(a,b,c,d);

//--- добавим символ в строку

string test="";

StringSetCharacter(test,0,a);

Print(test);

//--- заменим символ в строке

StringSetCharacter(test,0,b);

Print(test);

//--- заменим символ в строке

StringSetCharacter(test,0,c);

Print(test);

//--- заменим символ в строке

StringSetCharacter(test,0,d);

Print(test);

//--- представим символы в виде числа

int a1=65;

int b1=36;

int c1=169;

int d1=174;

//--- добавим символ в строку

StringSetCharacter(test,1,a1);

Print(test);

//--- заменим символ в строке

StringSetCharacter(test,1,b1);

Print(test);

//--- заменим символ в строке

StringSetCharacter(test,1,c1);

Print(test);

//--- заменим символ в строке

StringSetCharacter(test,1,d1);

Print(test);

}

Как уже говорилось выше, значение символьной константы (или переменной) представляет собой

индекс в таблице символов, а так как индекс является целым числом, то допустимо его

записывать разными способами.

Основы языка

void OnStart()

{

//---

int a=0xAE; // код символа ® соответствует литералу '\xAE'

int b=0x24; // код символа $ соответствует литералу '\x24'

int c=0xA9; // код символа © соответствует литералу '\xA9'

int d=0x263A; // код символа O соответствует литералу '\x263A'

//--- выведем значения

Print(a,b,c,d);

//--- добавим символ в строку

string test="";

StringSetCharacter(test,0,a);

Print(test);

//--- заменим символ в строке

StringSetCharacter(test,0,b);

Print(test);

//--- заменим символ в строке

StringSetCharacter(test,0,c);

Print(test);

//--- заменим символ в строке

StringSetCharacter(test,0,d);

Print(test);

//--- коды мастей

int a1=0x2660;

int b1=0x2661;

int c1=0x2662;

int d1=0x2663;

//--- добавим символ пикей

StringSetCharacter(test,1,a1);

Print(test);

//--- добавим символ червей

StringSetCharacter(test,2,b1);

Print(test);

//--- добавим символ бубей

StringSetCharacter(test,3,c1);

Print(test);

//--- добавим символ треф

StringSetCharacter(test,4,d1);

Print(test);

//--- Пример символьных литералов в строке

test="Дама\x2660Туз\x2662";

printf("%s",test);

}

Внутреннее представление символьного литерала - тип ushort. Символьные константы могут

принимать значения от 0 до 65535.

Смотри также

StringSetCharacter(), StringGetCharacter(), ShortToString(), ShortArrayToString(),

StringToShortArray()

Основы языка

Тип datetime

Тип datetime предназначен для хранения даты и времени в виде количества секунд, прошедших с

01 января 1970 года. Занимает в памяти 8 байт.

Константы даты и времени могут быть представлены в виде литеральной строки, которая состоит

из 6 частей, представляющих числовое значение года, месяца, числа (либо числа, месяца, года),

часа, минуты и секунды. Константа обрамляется одинарными кавычками и начинается с символа

Может опускаться либо дата (год, месяц, число), либо время (часы, минуты, секунды), либо все

вместе. Диапазон значений от 1 января 1970 года до 31 декабря 3000 года.

Примеры:

D'2004.01.01 00:00' // Новый Год

D'1980.07.19 12:30:27'

D'19.07.1980 12:30:27'

D'19.07.1980 12' //равнозначно D'1980.07.19 12:00:00'

D'01.01.2004' //равнозначно D'01.01.2004 00:00:00'

D'12:30:27' //равнозначно D'[дата компиляции] 12:30:27'

D'' //равнозначно D'[дата компиляции] 00:00:00'

Смотри также

Структура даты, Дата и время, TimeToString, StringToTime

Основы языка

Тип color

Тип color предназначен для хранения информации о цвете и занимает в памяти 4 байта. Первый

байт не учитывается, остальные 3 байта содержат RGB-составляющие.

Цветовые константы могут быть представлены тремя различными способами: литерально,

целочисленно или при помощи имени (только для именованных Web-цветов).

Литеральное представление состоит из трех частей, представляющих числовые значения

интенсивности трех основных компонент цвета: красной (red), зеленой (green), синей (blue).

Константа начинается с символа C и обрамляется одинарными кавычками. Числовые значения

интенсивности компоненты цвета лежат в диапазоне от 0 до 255.

Целочисленное представление записывается в виде шестнадцатеричного или десятичного числа.

Шестнадцатеричное число имеет вид 0x00BBGGRR, где RR - значение интенсивности красной

компоненты цвета, GG - зеленной, а BB - синей. Десятичные константы не имеют прямого

отражения в RGB. Они представляют собой десятичное значение шестнадцатеричного

целочисленного представления.

Именованные цвета отражают так называемый набор Web-цветов.

Примеры:

//--- литералы

C'128,128,128' // серый

C'0x00,0x00,0xFF' // синий

//названия цветов

clrRed // красный

clrYellow // желтый

clrBlack // черный

//--- целочисленные представления

0xFFFFFF // белый

16777215 // белый

0x008000 // зеленый

32768 // зеленый

Смотри также

Набор Web-цветов, ColorToString, StringToColor, Приведение типов

Основы языка

Тип bool

Тип bool предназначен для хранения логических значений true (истина) или false (ложь), числовое

представление которых 1 или 0 соответственно.

Примеры:

bool a = true;

bool b = false;

bool c = 1;

Внутреннее представление – целое число размером 1 байт. Необходимо отметить, что в

логических выражениях допустимо использовать вместо типа bool другие целые или

вещественные типы или выражения этих типов, компилятор не выдаст ошибки. В таком случае

значение ноль будет интерпретировано как false, а все остальные значения как true.

Примеры:

int i=5;

double d=-2.5;

if(i) Print("i = ",i," и имеет значение true");

else Print("i = ",i," и имеет значение false");

if(d) Print("d = ",d," и имеет значение true");

else Print("d = ",d," и имеет значение false");

i=0;

if(i) Print("i = ",i," и имеет значение true");

else Print("i = ",i," и имеет значение false");

d=0.0;

if(d) Print("d = ",d," и имеет значение true");

else Print("d = ",d," и имеет значение false");

//--- результаты выполнения

// i= 5 и имеет значение true

// d= -2.5 и имеет значение true

// i= 0 и имеет значение false

// d= 0 и имеет значение false

Смотри также

Логические операции, Приоритеты и порядок операций

Основы языка

Перечисления

Данные перечислимого типа enum относятся к некоторому ограниченному множеству данных.

Определение перечислимого типа:

enum имя_перечислимого_типа

{

список_значений

};

Список значений представляет из себя список идентификаторов именованных констант,

разделенных запятыми.

Пример:

enum months // перечисление именованных констант

{

January,

February,

March,

April,

May,

June,

July,

August,

September,

October,

November,

December

};

После объявления перечисления появляется новый целочисленный 4-байтовый тип данных.

Объявление нового типа данных позволяет компилятору строго контролировать типы

передаваемых параметров, так как перечисление вводит новые именованные константы. В

приведенном примере именованная константа January имеет значение 0, February имеет значение

1, December имеет значение 11.

Правило: если именованной константе - члену перечисления явно не присвоено конкретное

значение, то ее значение будет сформировано автоматически. Если это первый член

перечисления, то будет присвоено значение 0. Для всех последующих членов значения будет

вычисляться на основе значения предыдущего члена путем прибавления единицы.

Пример:

enum intervals // перечисление именованных констант

{

month=1, // интервал в один месяц

two_months, // два месяца

quarter, // три месяца - квартал

halfyear=6, // полугодие

year=12, // год - 12 месяцев

Основы языка

};

Примечания

В отличие от C++, размер внутреннего представления перечислимого типа в MQL5 всегда

составляет 4 байта. То есть, sizeof(months) вернет значение 4.

В отличие от C++, в MQL5 нельзя объявить анонимное перечисление. То есть, после ключевого

слова enum всегда должно быть указано уникальное имя.

Смотри также

Приведение типов

Основы языка

Вещественные типы (double, float)

Вещественные типы (или типы с плавающей точкой) представляют значения, имеющие дробную

часть. В языке MQL5 есть два типа для чисел с плавающей точкой. Способ представления

вещественных чисел в машинной памяти определен стандартом IEEE 754 и не зависит от

платформ, операционных систем и языков программирования.

Тип

Размер в

байтах

Минимально

положитель

ное

значение

Максимальн

ое значение

Точность

представле

ния

Аналог в С+

float

1.175494351

e-38

3.402823466

e+38

7 значащих

цифр

float

double

2.225073858

5072014e-

308

1.797693134

8623158e+30

15 значащих

цифр

double

Имя double означает, что точность этих чисел вдвое превышает точность чисел типа float. В

большинстве случаев тип double является наиболее удобным. Ограниченной точности чисел float

во многих случаях попросту недостаточно. Причина, по которой тип float все еще используется, -

экономия памяти при хранении (это важно для больших массивов вещественных чисел).

Константы с плавающей точкой состоят из целой части, точки (.) и дробной части. Целая и

дробная части представляют собой последовательности десятичных цифр.

Примеры:

double a=12.111;

double b=-956.1007;

float c =0.0001;

float d =16;

Существует научный способ записи вещественных констант, зачастую этот способ записи более

компактный, чем традиционный.

Пример:

double c1=1.12123515e-25;

double c2=0.000000000000000000000000112123515; // 24 нуля после десятичной точки

Print("1. c1 = ",DoubleToString(c1,16));

// Результат: 1. c1 = 0.0000000000000000

Print("2. c1 = ",DoubleToString(c1,-16));

// Результат: 2. c1 = 1.1212351499999999e-025

Print("3. c2 = ",DoubleToString(c2,-16));

// Результат: 3. c2 = 1.1212351499999999e-025

Необходимо помнить, что вещественные числа хранятся в памяти компьютера с некоторой

ограниченной точностью в двоичной системе счисления, в то время как общепринятой в

использовании является десятичная система счисления. Поэтому многие числа, которые точно

Основы языка

записываются в десятичной системе, в двоичной системе можно записать только в виде

бесконечной дроби.

Например, числа 0.3 и 0.7 представлены в компьютере бесконечными дробями, в то время как

число 0.25 хранится точно, так как представляет из себя степень двойки.

В связи с этим, категорически не рекомендуется сравнивать между собой два вещественных

числа на равенство, так как такое сравнение не является корректным.

Пример:

void OnStart()

{

//---

double three=3.0;

double x,y,z;

x=1/three;

y=4/three;

z=5/three;

if(x+y==z) Print("1/3 + 4/3 == 5/3");

else Print("1/3 + 4/3 != 5/3");

// Результат: 1/3 + 4/3 != 5/3

}

Если все же необходимо сравнить на равенство два вещественных числа, то можно сделать это

двумя разными способами. Первый способ заключается в сравнении разницы между двумя

числами с какой-то малой величиной, задающей точность сравнения.

Пример:

bool EqualDoubles(double d1,double d2,double epsilon)

{

if(epsilon<0) epsilon=-epsilon;

//---

if(d1-d2>epsilon) return false;

if(d1-d2<-epsilon) return false;

//---

return true;

}

void OnStart()

{

double d_val=0.7;

float f_val=0.7;

if(EqualDoubles(d_val,f_val,0.000000000000001)) Print(d_val,"equals",f_val);

else Print("Different: d_val = ",DoubleToString(d_val,16),

" f_val = ",DoubleToString(f_val,16));

// Результат: Different: d_val= 0.7000000000000000 f_val= 0.6999999880790710

}

Необходимо отметить, что значение параметра epsilon в приведенном примере не может быть

меньше предопределенной константы DBL_EPSILON. Значение этой константы

2.2204460492503131e-016. Для типа float соответствующая константа FLT_EPSILON =

1.192092896e-07. Смысл этих значений таков, что это наименьшее значение, удовлетворяющее

условию 1.0+DBL_EPSILON != 1.0 (для чисел типа float 1.0+FLT_EPSILON != 1.0).

Второй способ предполагает сравнивать нормализованную разность двух вещественных чисел с

нулевым значением. Сравнивать разность нормализованных чисел с нулём бесполезно, так как в

Основы языка

результате любой математической операции с нормализованными числами результат получается

ненормализованным.

Пример:

bool CompareDoubles(double number1,double number2)

{

if(NormalizeDouble(number1-number2,8)==0) return(true);

else return(false);

}

void OnStart()

{

double d_val=0.3;

float f_val=0.3;

if(CompareDoubles(d_val,f_val)) Print(d_val,"equals",f_val);

else Print("Different: d_val = ",DoubleToString(d_val,16),

" f_val = ",DoubleToString(f_val,16));

// Результат: Different: d_val= 0.3000000000000000 f_val= 0.3000000119209290

}

В результате некоторых операций математического сопроцессора может получиться

недействительное вещественное число, которое нельзя использовать в математических

операциях и операциях сравнения, так как результат выполнения операций над

недействительными вещественными числами неопределен. Например, при попытке вычислить

арксинус от 2, результатом будет минус бесконечность.

Пример:

double abnormal = MathArcsin(2.0);

Print("MathArcsin(2.0) =",abnormal);

// Результат: MathArcsin(2.0) = -1.#IND

Кроме минус бесконечности существуют плюс бесконечность и NaN (не число). Чтобы определить,

что данное число недействительно, можно использовать функцию MathIsValidNumber(). По

стандарту IEEE они имеют специальное машинное представление. Например, плюс бесконечность

для типа double имеет битовое представление 0x7FF0 0000 0000 0000.

Примеры: