Справочник по языку программирования MQL5

Подождите немного. Документ загружается.

Программы MQL5

341

//+------------------------------------------------------------------+

//| TestExpert.mq5 |

//| http://www.mql5.com |

//+------------------------------------------------------------------+

#property copyright "2009, MetaQuotes Software Corp."

#property link "http://www.mql5.com"

#property version "1.00"

class CTestClass

{

public:

CTestClass() { Print("CTestClass constructor"); }

~CTestClass() { Print("CTestClass destructor"); }

};

CTestClass global;

//+------------------------------------------------------------------+

//| Expert initialization function |

//+------------------------------------------------------------------+

int OnInit()

{

//---

Print("Initialisation");

//---

return(0);

}

//+------------------------------------------------------------------+

//| Expert deinitialization function |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

{

//---

Print("Deinitialisation with reason ",reason);

}

//+------------------------------------------------------------------+

//| Expert tick function |

//+------------------------------------------------------------------+

void OnTick()

{

//---

}

//+------------------------------------------------------------------+

Скрипты загружаются сразу после прикрепления к графику и выгружаются сразу после окончания

своей работы.

Смотри также

События клиентского терминала, Функции обработки событий

Программы MQL5

342

События клиентского терминала

Init

Сразу же после того, как клиентский терминал загрузит программу (эксперт или пользовательский

индикатор) и запустит процесс инициализации глобальных переменных, будет послано событие

Init, которое обрабатывается функцией OnInit(), если она есть. Это событие также генерируется

после смены финансового инструмента и/или периода графика, после перекомпиляции программы

в редакторе MetaEditor, после смены входных параметров из окна настройки эксперта или

пользовательского индикатора. Советник также инициализируется после смены счета. Для

скриптов событие Init не генерируется.

Deinit

Перед деинициализацией глобальных переменных и выгрузкой программы (эксперт или

пользовательский индикатор) клиентский терминал посылает программе событие Deinit. Событие

Deinit также генерируется при завершении работы клиентского терминала, при закрытии графика,

непосредственно перед сменой финансового инструмента и/или периода графика, при удачной

перекомпиляции программы, при смене входных параметров, а также при смене счета.

Причинудеинициализации можно получить из параметра, переданного в функцию OnDeinit().

Выполнение функции OnDeinit() ограничивается 2.5 секундами. Если за это время функция не

закончила свою работу, то ее выполнение завершается принудительно. Для скриптов событие

Deinit не генерируется.

Start

Событие Start – это специальное событие для активизации скрипта после его загрузки. Это

событие обрабатывается функцией OnStart. Событие Start экспертам и пользовательским

индикаторам не посылается.

NewTick

Событие NewTick генерируется при поступлении новых котировок, и обрабатывается функцией

OnTick() у присоединенных советников. Если при поступлении новой котировки выполнялась

функция OnTick, запущенная на предыдущей котировке, то пришедшая котировка будет

проигнорирована советником, так как соответствующее событие не будет поставлено в очередь

событий эксперта.

Все пришедшие во время выполнения программы новые котировки программой игнорируются до

тех пор, пока не завершится очередное выполнение функции OnTick(). После этого функция будет

запущена только после прихода очередной новой котировки.

Событие NewTick генерируется независимо от того, запрещена или разрешена автоматическая

торговля (кнопка "Разрешить/запретить Авто-торговлю"). Запрет автоматической торговли

означает только запрет на отправку торговых запросов из эксперта, работа эксперта не

прекращается.

Запрет автоматической торговли путем нажатия на указанную кнопку не прерывает текущее

выполнение функции OnTick(). Функция OnTick() не запускается на выполнение при открытом окне

свойств советника.

Программы MQL5

343

Calculate

Событие Calculate генерируется только для индикаторов сразу после посылки события Init и при

любом изменении ценовых данных. Обрабатывается функцией OnCalculate.

Timer

Событие Timer периодически генерируется клиентским терминалом для эксперта, который

активизировал таймер при помощи функции EventSetTimer. Обычно эта функция вызывается в

функции OnInit. Обработка события Timer производится функцией OnTimer. При завершении

работы эксперта необходимо уничтожить созданный таймер при помощи EventKillTimer, которую

обычно вызывают в функции OnDeinit.

Trade

Событие Trade генерируется при завершении торговой операции на торговом сервере. Обработка

события Trade производится функцией OnTrade() для следующих торговых операций:

установка, модификация или удаление отложенного ордера;

отмена отложенного ордера при нехватке средств либо по истечении срока действия;

срабатывание отложенного ордера;

открытие, добавление или закрытие позиции (или части позиции);

модификация открытой позиции (изменение стопов).

Tester

Событие Tester генерируется по окончании тестирования эксперта на исторических данных.

Обработка события Tester производится функцией OnTester().

ChartEvent

Событие ChartEvent генерируется клиентским терминалом при работе пользователя с графиком:

нажатия клавиатуры, когда окно графика находится в фокусе;

создание графического объекта;

удаление графического объекта;

щелчок мыши на графическом объекте, принадлежащего графику;

перемещение графического объекта при помощи мыши;

окончание редактирования текста в поле ввода графического объекта LabelEdit.

Также существует пользовательское событие ChartEvent, которое может послать эксперту любая

mql5-программа при помощи функции EventChartCustom. Событие обрабатывается функцией

OnChartEvent.

BookEvent

Событие BookEvent генерируется клиентским терминалом при изменении состояния стакана цен и

обрабатывается функцией OnBookEvent. Для того, чтобы клиентский терминал начал

генерировать события BookEvent по конкретному символу, достаточно предварительно

Программы MQL5

344

подписаться на получение этих событий для этого символа с помощью функции MarketBookAdd.

Для того, чтобы отписаться от получения события BookEvent по символу, необходимо вызывать

функцию MarketBookRelease. Событие BookEvent является широковещательным – это означает,

что достаточно одному эксперту подписаться на получение события BookEvent с помощью

функции MarketBookAdd, и все остальные эксперты, имеющие обработчик OnBookEvent, будут

получать это событие. Поэтому необходимо анализировать имя символа, которое передается в

обработчик в качестве параметра.

Смотри также

Функции обработки событий, Выполнение программ

Программы MQL5

345

Ресурсы

Использование графики и звука в программах на MQL5

Программы на MQL5 позволяют работать со звуковыми и графическими файлами:

PlaySound() воспроизводит звуковой файл;

ObjectCreate() позволяет с помощью графических объектов OBJ_BITMAP и OBJ_BITMAP_LABEL

создавать пользовательские интерфейсы.

PlaySound()

Пример вызова функции PlaySound():

//+------------------------------------------------------------------+

//| функция вызывает штатную OrderSend() и проигрывает звук |

//+------------------------------------------------------------------+

void OrderSendWithAudio(MqlTradeRequest &request, MqlTradeResult &result)

{

//--- отправим запрос на сервер

OrderSend(request,result);

//--- если запрос принят, играем звук Ok.wav

if(result.retcode==TRADE_RETCODE_PLACED) PlaySound("Ok.wav");

//--- при неудаче выдаем тревожный звук из файла timeout.wav

else PlaySound("timeout.wav");

}

В данном примере показано как проигрывать звуки из файлов Ok.wav и timeoit.wav, входящих в

стандартную поставку терминала. Эти файлы находятся в папке каталог_терминала\Sounds.

Здесь каталог_терминала означает папку, из которой запущен клиентский терминал MetaTrader

5. Программным путем из mql5-программы каталог терминала можно узнать следующим образом:

//--- Папка, в которой хранятся данные терминала

string terminal_path=TerminalInfoString(TERMINAL_PATH);

Можно использовать звуковые файлы не только из папки каталог_терминала\Sounds, но и из

любой подпапки, находящейся в папке каталог_данных_терминала\MQL5. Расположение

каталога данных терминала на компьютере можно выяснить через меню терминала

"Файл"-"Открыть каталог данных" или программным путем:

//--- Папка, в которой хранятся данные терминала

string terminal_data_path=TerminalInfoString(TERMINAL_DATA_PATH);

Например, если звуковой файл Demo.wav лежит в папке каталог_данных_терминала\MQL5\Files,

то вызов PlaySound() должен быть записан таким образом:

//--- проиграем звуковой файл Demo.wav из папки каталог_данных_терминала\MQL5\Files\Demo.wav

PlaySound("\\Files\\Demo.wav");

Обратите внимание на то, что в комментарии путь к файлу написан с использованием символа "\",

а в самой функции для разделения папок в пути используется последовательность "\\".

Программы MQL5

346

При указании пути всегда используйте только двойную обратную косую черту в качестве

разделителя, так как одиночная обратная черта является управляющим символом для

компилятора при разборе константных строк и символьных констант в исходном коде программы.

ObjectCreate()

Пример эксперта, который с помощью функции ObjectCreate() создает объект "Графическая

метка" (OBJ_BITMAP_LABEL).

string label_name="currency_label"; // имя объекта OBJ_BITMAP_LABEL

string euro ="\\Images\\euro.bmp"; // путь к файлу каталог_данных_терминала\MQL5\Images\euro.bmp

string dollar ="\\Images\\dollar.bmp"; // путь к файлу каталог_данных_терминала\MQL5\Images\dollar.bmp

//+------------------------------------------------------------------+

//| Expert initialization function |

//+------------------------------------------------------------------+

int OnInit()

{

//--- создадим кнопку OBJ_BITMAP_LABEL, если ее еще нет

if(ObjectFind(0,label_name)<0)

{

//--- попробуем создать объект OBJ_BITMAP_LABEL

bool created=ObjectCreate(0,label_name,OBJ_BITMAP_LABEL,0,0,0);

if(created)

{

//--- привяжем кнопку к правому верхнему углу графика

ObjectSetInteger(0,label_name,OBJPROP_CORNER,CORNER_RIGHT_UPPER);

//--- теперь настроим свойства объекта

ObjectSetInteger(0,label_name,OBJPROP_XDISTANCE,100);

ObjectSetInteger(0,label_name,OBJPROP_YDISTANCE,50);

//--- сбросим код последней ошибки в 0

ResetLastError();

//--- загрузим картинку для состояния кнопки "Нажата"

bool set=ObjectSetString(0,label_name,OBJPROP_BMPFILE,0,euro);

//--- проверим результат

if(!set)

{

PrintFormat("Не удалось загрузить картинку из файла %s. Код ошибки %d",euro,GetLastError());

}

ResetLastError();

//--- загрузим картинку для состояния кнопки "Отжата"

set=ObjectSetString(0,label_name,OBJPROP_BMPFILE,1,dollar);

if(!set)

{

PrintFormat("Не удалось загрузить картинку из файла %s. Код ошибки %d",dollar,GetLastError());

}

//--- отдадим графику команду на обновление, чтобы кнопка появилась сразу же, не дожидаясь тика

Программы MQL5

347

ChartRedraw(0);

}

else

{

//--- объект создать не удалось, сообщим об этом

PrintFormat("Не удалось создать объект OBJ_BITMAP_LABEL. Код ошибки %d",GetLastError());

}

//---

return(0);

}

//+------------------------------------------------------------------+

//| Expert deinitialization function |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

{

//--- удалим объект с графика

ObjectDelete(0,label_name);

}

Создание и настройка графического объекта с именем currency_label происходят в функции OnInit

(). Пути к загружаемым графическим файлам заданы в глобальных переменных euro и dollar, в

качестве разделителя использована двойная обратная косая черта:

string euro ="\\Images\\euro.bmp"; // путь к файлу каталог_данных_терминала\MQL5\Images\euro.bmp

string dollar ="\\Images\\dollar.bmp"; // путь к файлу каталог_данных_терминала\MQL5\Images\dollar.bmp

Сами файлы при этом находятся в папке каталог_данных_терминала\MQL5\Images.

Объект OBJ_BITMAP_LABEL фактически представляет собою кнопку, которая в зависимости от

состояния (нажата или отжата) может отображать одну из двух картинок: euro.bmp или dollar.

bmp.

Размеры кнопки с графическим интерфейсом автоматически устанавливаются под размер

Программы MQL5

348

отображаемой картинки. Смена изображения производится при нажатии левой кнопкой мышки на

объекте OBJ_BITMAP_LABEL (в свойствах должен быть выбрано "Отключить выделение").

Объект OBJ_BITMAP создается аналогичным образом и предназначен для создания фона с

требуемым рисунком.

Значение свойства OBJPROP_BMPFILE, которое отвечает за вид объектов OBJ_BITMAP и

OBJ_BITMAP_LABEL, можно менять динамически. Это позволяет создавать разнообразные

интерактивные пользовательские интерфейсы для mql5-программ.

Включение ресурсов в исполняемые файлы при компиляции

mql5-программ

Для работы mql5-программы может потребоваться множество разнообразных загружаемых

ресурсов в виде файлов изображений и звуков. Для того чтобы исключить необходимость

переноса всех этих файлов при передаче исполняемой программы на MQL5, следует использовать

директиву компилятора #resource:

#resource путь_к_файлу_ресурса

Команда #resource указывает компилятору, что ресурс по указанному пути

путь_к_файлу_ресурса нужно включить в исполняемый файл EX5. Таким образом, все

необходимые картинки и звуки можно поместить непосредственно в EX5-файл и для запуска

программы в другом терминале не потребуется передавать все используемые в ней отдельные

файлы. Любой EX5-файл может содержать ресурсы, и любая EX5-программа может использовать

ресурсы из другой EX5-программы.

Файлы в формате BMP и WAV перед включением в исполняемый EX5 файл автоматически

сжимаются. Это означает, что использование ресурсов не только позволяет создавать

полноценные программы на MQL5, но и уменьшает общий размер требуемых терминалу файлов

при использовании графики и звука по сравнению с обычным способом написания mql5-программ.

Размер файла ресурса не может быть больше 16 Mb.

Поиск указанных ресурсов компилятором

Ресурс вставляется командой #resource "<путь к файлу ресурса>"

#resource "<путь_к_файлу_ресурса>"

Длина константной строки <путь_к_файлу_ресурса> не должна превышать 63 символа.

Компилятор ищет ресурс по указанному пути в следующей последовательности:

если в начале пути стоит разделитель обратная косая черта "\" (пишется "\\"), то ресурс ищется

относительно каталога каталог_данных_терминала\MQL5\,

если обратной косой черты нет, то ресурс ищется относительно расположения исходного файла,

в котором этот ресурс прописывается.

В пути ресурса недопустимо использовать подстроки "..\\" и ":\\".

Программы MQL5

349

Примеры включения ресурсов:

//--- правильное указание ресурсов

#resource "\\Images\\euro.bmp" // euro.bmp находится в каталог_данных_терминала\MQL5\Images\

#resource "picture.bmp" // picture.bmp находится в том же каталоге, где и исходный файл

#resource "Resource\\map.bmp" // ресурс находится в папке каталог_исходного_файла\Resource\map.bmp

//--- неправильное указание ресурсов

#resource ":picture_2.bmp" // нельзя использовать ":"

#resource "..\\picture_3.bmp" // нельзя использовать ".."

#resource "\\Files\\Images\\Folder_First\\My_panel\\Labels\\too_long_path.bmp" //больше 63 символов

Использование ресурсов

Имя ресурса

После того как ресурс объявлен директивой #resource, его можно использовать в любой части

программы. Именем ресурса становится его путь без косой черты в начале строки, задающей путь

к ресурсу. Для использования своего ресурса в коде нужно перед именем ресурса добавлять

специальный признак "::".

Примеры:

//--- примеры указания ресурсов и их имена в комментарии

#resource "\\Images\\euro.bmp" // имя ресурса - Images\euro.bmp

#resource "picture.bmp" // имя ресурса - picture.bmp

#resource "Resource\\map.bmp" // имя ресурса - Resource\map.bmp

#resource "\\Files\\Pictures\\good.bmp" // имя ресурса - Files\Pictures\good.bmp

#resource "\\Files\\Demo.wav"; // имя ресурса - Files\Demo.wav"

#resource "\\Sounds\\thrill.wav"; // имя ресурса - Sounds\thrill.wav"

...

//--- использование ресурсов

ObjectSetString(0,bitmap_name,OBJPROP_BMPFILE,0,"::Images\\euro.bmp");

...

ObjectSetString(0,my_bitmap,OBJPROP_BMPFILE,0,"::picture.bmp");

...

set=ObjectSetString(0,bitmap_label,OBJPROP_BMPFILE,1,"::Files\\Pictures\\good.bmp");

...

PlaySound("::Files\\Demo.wav");

...

PlaySound("::Sounds\\thrill.wav");

Необходимо отметить, что при установке объектам OBJ_BITMAP и OBJ_BITMAP_LABEL

изображения из ресурса, значение свойства OBJPROP_BMPFILE уже нельзя менять вручную.

Например, пусть мы используем для создания OBJ_BITMAP_LABEL ресурсы файлов euro.bmp и

dollar.bmp.

#resource "\\Images\\euro.bmp"; // euro.bmp находится в каталог_данных_терминала\MQL5\Images\

#resource "\\Images\\dollar.bmp"; // dollar.bmp находится в каталог_данных_терминала\MQL5\Images\

Программы MQL5

350

Тогда при просмотре свойств этого объекта мы увидим, что свойства BitMap File (On) и BitMap File

(Off) имеют серый цвет и недоступны для изменения вручную:

Использование ресурсов других mql5-программ

Использование ресурсов имеет и другое преимущество – в любой mql5-программе можно

использовать ресурсы из любого файла EX5. Таким образом, ресурсы из одного файла EX5 можно

использовать во многих других mql5-программах.

Для того чтобы использовать имя ресурса из стороннего файла, его нужно указать в виде

<путь_имя_файла_EX5>::<имя_ресурса>. Например, пусть в скрипте Draw_Triangles_Script.mq5

указан ресурс на картинку в файле triangle.bmp:

#resource "\\Files\\triangle.bmp"

Тогда его имя для использования в самом скрипте будет выглядеть как "Files\triangle.bmp", а для

использования к имени ресурса нужно добавить специальный признак "::".

//--- использование ресурса в самом скрипте

ObjectSetString(0,my_bitmap_name,OBJPROP_BMPFILE,0,"::Files\\triangle.bmp");

Чтобы использовать этот же ресурс из другой программы, например, эксперта, нужно к имени

ресурса дополнительно добавить путь к EX5-файлу относительно папки

каталог_данных_терминала\MQL5\ и имя EX5-файла этого скрипта - Draw_Triangles_Script.ex5.

Пусть скрипт лежит в стандартной папке каталог_данных_терминала\MQL5\Scripts\, тогда вызов

нужно написать таким образом:

//--- использование ресурса скрипта в эксперте

ObjectSetString(0,my_bitmap_name,OBJPROP_BMPFILE,0,"\\Scripts\\Draw_Triangles_Script.ex5::Files\\triangle.bmp");

Если при обращении к ресурсу в другом EX5-файле не указать путь к этому исполняемому файлу,

то исполняемый файл ищется в той же папке, где находится и обратившаяся за ресурсом

программа. Это означает, что если в советнике запрашивается ресурс из файла