Справочник по языку программирования MQL5
Подождите немного. Документ загружается.
Стандартная библиотека
© 2000-2011, MetaQuotes Software Corp.
2441
ReverseShort
Выполняет операции разворота короткой позиции.
virtual bool ReverseShort(
double price, // цена
double sl, // Stop Loss
double tp // Take Profit
)
Параметры
price
[in] Цена для разворота короткой позиции.
sl
[in] Цена Stop Loss.
tp
[in] Цена Take Profit.
Возвращаемое значение
true - выполнена торговая операция, иначе - false.
Примечание
Определяет размер лота для разворота короткой позиции (вызов метода LotReverse). Если лот
не равен 0.0, производит разворот короткой позиции (вызов метода Buy объекта торговли).
Реализация
//+------------------------------------------------------------------+
//| Short position reverse |
//| INPUT: price - price, |
//| sl - stop loss, |
//| tp - take profit. |
//| OUTPUT: true-if trade operation processed, false otherwise. |
//| REMARK: no. |
//+------------------------------------------------------------------+
bool CExpert::ReverseShort(double price,double sl,double tp)
{
//--- get lot for reverse
double lot=LotReverse(sl);
//--- check lot
if(lot==0.0) return(false);
//---
return(m_trade.Buy(lot,price,sl,tp));
}
Стандартная библиотека
© 2000-2011, MetaQuotes Software Corp.
2442
CheckTrailingStop
Проверяет необходимость модификации позиции.
virtual bool CheckTrailingStop()
Возвращаемое значение
true - выполнена торговая операция, иначе - false.
Примечание
Проверяется необходимость модификации позиции (вызов метода CheckTrailingStopLong для
длинной позиции или CheckTrailingStopShort для короткой позиции).
Реализация
//+------------------------------------------------------------------+
//| Check for trailing stop/profit position |
//| INPUT: no. |
//| OUTPUT: true-if trade operation processed, false otherwise. |
//| REMARK: no. |
//+------------------------------------------------------------------+
bool CExpert::CheckTrailingStop()
{
//--- position must be selected before call
if(m_position.Type()==POSITION_TYPE_BUY)
{
//--- check the possibility of modifying the long position
if(CheckTrailingStopLong()) return(true);
}
else
{
//--- check the possibility of modifying the short position
if(CheckTrailingStopShort()) return(true);
}
//--- return without operations
return(false);
}
Стандартная библиотека
© 2000-2011, MetaQuotes Software Corp.
2443
CheckTrailingStopLong
Проверяет необходимость модификации длинной позиции.
virtual bool CheckTrailingStopLong()
Возвращаемое значение
true - выполнена торговая операция, иначе - false.
Примечание
Проверяется необходимость модификации длинной позиции (вызов метода
CheckTrailingStopLong объекта трейлинга). В случае выполнения условия модифицирует позицию
(вызов метода TrailingStopLong).
Реализация
//+------------------------------------------------------------------+
//| Check for trailing stop/profit long position |
//| INPUT: no. |
//| OUTPUT: true-if trade operation processed, false otherwise. |
//| REMARK: no. |
//+------------------------------------------------------------------+
bool CExpert::CheckTrailingStopLong()
{
double sl=EMPTY_VALUE;
double tp=EMPTY_VALUE;
//--- check for long trailing stop operations
if(m_trailing.CheckTrailingStopLong(GetPointer(m_position),sl,tp))
{
if(sl==EMPTY_VALUE) sl=m_position.StopLoss();
if(tp==EMPTY_VALUE) tp=m_position.TakeProfit();
//--- long trailing stop operations
return(TrailingStopLong(sl,tp));
}
//--- return without operations
return(false);
}
Стандартная библиотека
© 2000-2011, MetaQuotes Software Corp.
2444
CheckTrailingStopShort
Проверяет необходимость модификации короткой позиции.
virtual bool CheckTrailingStopShort()
Возвращаемое значение
true - выполнена торговая операция, иначе - false.
Примечание
Проверяется необходимость модификации короткой позиции (вызов метода
CheckTrailingStopShort объекта трейлинга). В случае выполнения условия модифицирует
позицию (вызов метода TrailingStopShort).
Реализация
//+------------------------------------------------------------------+
//| Check for trailing stop/profit short position |
//| INPUT: no. |
//| OUTPUT: true-if trade operation processed, false otherwise. |
//| REMARK: no. |
//+------------------------------------------------------------------+
bool CExpert::CheckTrailingStopShort()
{
double sl=EMPTY_VALUE;
double tp=EMPTY_VALUE;
//--- check for short trailing stop operations
if(m_trailing.CheckTrailingStopShort(GetPointer(m_position),sl,tp))
{
if(sl==EMPTY_VALUE) sl=m_position.StopLoss();
if(tp==EMPTY_VALUE) tp=m_position.TakeProfit();
//--- short trailing stop operations
return(TrailingStopShort(sl,tp));
}
//--- return without operations
return(false);
}
Стандартная библиотека
© 2000-2011, MetaQuotes Software Corp.
2445
TrailingStopLong
Модифицирует длинную позицию.
virtual bool TrailingStopLong(
double sl, // цена Stop Loss
double tp // цена Take Profit
)
Параметры
sl
[in] Цена Stop Loss.
tp
[in] Цена Take Profit.
Возвращаемое значение
true - выполнена торговая операция, иначе - false.
Примечание
Модифицирует позицию (вызов метода PositionModify объекта торговли).
Реализация
//+------------------------------------------------------------------+
//| Trailing stop/profit long position |
//| INPUT: no. |
//| OUTPUT: true-if trade operation successful, false otherwise. |
//| REMARK: no. |
//+------------------------------------------------------------------+
bool CExpert::TrailingStopLong(double sl,double tp)
{
return(m_trade.PositionModify(m_symbol.Name(),sl,tp));
}
Стандартная библиотека
© 2000-2011, MetaQuotes Software Corp.
2446
TrailingStopShort
Модифицирует короткую позицию.
virtual bool TrailingStopShort(
double sl, // цена Stop Loss
double tp // цена Take Profit
)
Параметры
sl
[in] Цена Stop Loss.
tp
[in] Цена Take Profit.
Возвращаемое значение
true - выполнена торговая операция, иначе - false.
Примечание
Модифицирует позицию (вызов метода PositionModify объекта торговли).
Реализация
//+------------------------------------------------------------------+
//| Trailing stop/profit short position |
//| INPUT: no. |
//| OUTPUT: true-if trade operation successful, false otherwise. |
//| REMARK: no. |
//+------------------------------------------------------------------+
bool CExpert::TrailingStopShort(double sl,double tp)
{
return(m_trade.PositionModify(m_symbol.Name(),sl,tp));
}
Стандартная библиотека
© 2000-2011, MetaQuotes Software Corp.
2447
CheckTrailingOrderLong
Проверяет необходимость модификации ордеров на покупку.
virtual bool CheckTrailingOrderLong()
Возвращаемое значение
true - выполнена торговая операция, иначе - false.
Примечание
Проверяется необходимость модификации ордера на покупку (вызов метода
CheckTrailingOrderLong объекта торговых сигналов). В случае выполнения условия
модифицирует ордер (вызов метода TrailingOrderLong).
Реализация
//+------------------------------------------------------------------+
//| Check for trailing long limit/stop order |
//| INPUT: no. |
//| OUTPUT: true-if trade operation processed, false otherwise. |
//| REMARK: no. |
//+------------------------------------------------------------------+
bool CExpert::CheckTrailingOrderLong()
{
double price;
//--- check the possibility of modifying the long order
if(m_signal.CheckTrailingOrderLong(GetPointer(m_order),price))
return(TrailingOrderLong(price));
//--- return without operations
return(false);
}
Стандартная библиотека
© 2000-2011, MetaQuotes Software Corp.
2448
CheckTrailingOrderShort
Проверяет необходимость модификации ордеров на продажу.
virtual bool CheckTrailingOrderShort()
Возвращаемое значение
true - выполнена торговая операция, иначе - false.
Примечание
Проверяется необходимость модификации ордера на продажу (вызов метода
CheckTrailingOrderShort объекта торговых сигналов). В случае выполнения условия
модифицирует ордер (вызов метода TrailingOrderShort).
Реализация
//+------------------------------------------------------------------+
//| Check for trailing short limit/stop order |
//| INPUT: no. |
//| OUTPUT: true-if trade operation processed, false otherwise. |
//| REMARK: no. |
//+------------------------------------------------------------------+
bool CExpert::CheckTrailingOrderShort()
{
double price;
//--- check the possibility of modifying the short order
if(m_signal.CheckTrailingOrderShort(GetPointer(m_order),price))
return(TrailingOrderShort(price));
//--- return without operations
return(false);
}
Стандартная библиотека
© 2000-2011, MetaQuotes Software Corp.
2449
TrailingOrderLong
Модифицирует ордеры на покупку.
virtual bool TrailingOrderLong(
double delta // смещение
)
Параметры
delta
[in] Изменение цены.
Возвращаемое значение
true - выполнена торговая операция, иначе - false.
Примечание
Модифицирует ордер (вызов метода OrderModify объекта торговли).
Реализация
//+------------------------------------------------------------------+
//| Trailing long limit/stop order |
//| INPUT: no. |
//| OUTPUT: true-if trade operation successful, false otherwise. |
//| REMARK: no. |
//+------------------------------------------------------------------+
bool CExpert::TrailingOrderLong(double delta)
{
ulong ticket=m_order.Ticket();
double price =m_order.PriceOpen()-delta;
double sl =m_order.StopLoss()-delta;
double tp =m_order.TakeProfit()-delta;
//--- modifying the long order
return(m_trade.OrderModify(ticket,price,sl,tp,m_order.TypeTime(),m_order.TimeExpiration()));
}
Стандартная библиотека
© 2000-2011, MetaQuotes Software Corp.
2450
TrailingOrderShort
Модифицирует ордеры на продажу.
virtual bool TrailingOrderShort(
double delta // смещение
)
Параметры
delta
[in] Изменение цены.
Возвращаемое значение
true - выполнена торговая операция, иначе - false.
Примечание
Модифицирует ордер (вызов метода OrderModify объекта торговли).
Реализация
//+------------------------------------------------------------------+
//| Trailing short limit/stop order |
//| INPUT: no. |
//| OUTPUT: true-if trade operation successful, false otherwise. |
//| REMARK: no. |
//+------------------------------------------------------------------+
bool CExpert::TrailingOrderShort(double delta)
{
ulong ticket=m_order.Ticket();
double price =m_order.PriceOpen()-delta;
double sl =m_order.StopLoss()-delta;
double tp =m_order.TakeProfit()-delta;
//--- modifying the short order
return(m_trade.OrderModify(ticket,price,sl,tp,m_order.TypeTime(),m_order.TimeExpiration()));
}