Справочник по языку программирования MQL5
Подождите немного. Документ загружается.
Стандартная библиотека
© 2000-2011, MetaQuotes Software Corp.
2421
Refresh
Обновляет все необходимые данные.
virtual bool Refresh()
Возвращаемое значение
true - если нужна дальнейшая обработка тика, иначе - false.
Примечание
Определяет необходимость обработки тика. Если обработка не нужна, возвращает false. Если
обработка нужна, обновляет котировки и данные всех индикаторов и таймсерий и возвращает
true.
Стандартная библиотека
© 2000-2011, MetaQuotes Software Corp.
2422
Processing
Реализует основной алгоритм.
virtual bool Processing()
Возвращаемое значение
true - выполнена какая-либо торговая операция, иначе - false.
Примечание
Выполняются следующие действия:
1. Проверяется наличие открытой позиции по рабочему символу. Если позиции нет, то шаги 2, 3
и 4 пропускаются.
2. Проверяется необходимость переворота позиции (вызов метода CheckReverse). Если позиция
"перевёрнута", то уходим.
3. Проверяется необходимость закрытия позиции (вызов метода CheckClose). Если позиция
закрыта, то шаг 4 пропускается.
4. Проверяется необходимость модификации позиции (вызов метода CheckTrailingStop). Если
позиция модифицирована, то уходим.
5. Проверяется наличие отложенных ордеров по рабочему символу. Если ордеров нет, то
переходим к п.9.
6. Проверяется необходимость удалить ордер (вызов метода CheckDeleteOrderLong для ордеров
на покупку или метода CheckDeleteOrderShort для ордеров на продажу). Если ордер удалён, то
переходим к п.9.
7. Проверяется необходимость модифицировать ордер (вызов метода CheckTrailingOrderLong
для ордеров на покупку или метода CheckTrailingOrderShort для ордеров на продажу). Если
ордер модифицирован, то уходим.
8. Уходим.
9. Проверяется необходимость входа в рынок (вызов метода CheckOpen).
Реализация
//+------------------------------------------------------------------+
//| Main function |
//| INPUT: no. |
//| OUTPUT: true-if any trade operation processed, false otherwise. |
//| REMARK: no. |
//+------------------------------------------------------------------+
bool CExpert::Processing()
{
//--- check if open positions
if(m_position.Select(m_symbol.Name()))
{
//--- open position is available
//--- check the possibility of reverse the position
if(CheckReverse()) return(true);
//--- check the possibility of closing the position/delete pending orders
if(!CheckClose())
Стандартная библиотека
© 2000-2011, MetaQuotes Software Corp.
2423
{
//--- check the possibility of modifying the position
if(CheckTrailingStop()) return(true);
//--- return without operations
return(false);
}
}
//--- check if plased pending orders
int total=OrdersTotal();
if(total!=0)
{
for(int i=total-1;i>=0;i--)
{
m_order.Select(OrderGetTicket(i));
if(m_order.Symbol()!=m_symbol.Name()) continue;
if(m_order.Type()==ORDER_TYPE_BUY_LIMIT || m_order.Type()==ORDER_TYPE_BUY_STOP)
{
//--- check the ability to delete a pending order to buy
if(CheckDeleteOrderLong()) return(true);
//--- check the possibility of modifying a pending order to buy
if(CheckTrailingOrderLong()) return(true);
}
else
{
//--- check the ability to delete a pending order to sell
if(CheckDeleteOrderShort()) return(true);
//--- check the possibility of modifying a pending order to sell
if(CheckTrailingOrderShort()) return(true);
}
//--- return without operations
return(false);
}
}
//--- check the possibility of opening a position/setting pending order
if(CheckOpen()) return(true);
//--- return without operations
return(false);
}
Стандартная библиотека
© 2000-2011, MetaQuotes Software Corp.
2424
CheckOpen
Проверяет необходимость и возможность входа в рынок.
virtual bool CheckOpen()
Возвращаемое значение
true - выполнена какая-либо торговая операция, иначе - false.
Примечание
Последовательно проверяется необходимость входа в рынок в длинную позицию (вызов метода
CheckOpenLong), затем в короткую (вызов метода CheckOpenShort).
Реализация
//+------------------------------------------------------------------+
//| Check for position open or limit/stop order set |
//| INPUT: no. |
//| OUTPUT: true-if trade operation processed, false otherwise. |
//| REMARK: no. |
//+------------------------------------------------------------------+
bool CExpert::CheckOpen()
{
if(CheckOpenLong()) return(true);
if(CheckOpenShort()) return(true);
//--- return without operations
return(false);
}
Стандартная библиотека
© 2000-2011, MetaQuotes Software Corp.
2425
CheckOpenLong
Проверяет необходимость и возможность входа в рынок в длинную позицию.
virtual bool CheckOpenLong()
Возвращаемое значение
true - выполнена какая-либо торговая операция, иначе - false.
Примечание
Проверяется необходимость входа в рынок в длинную позицию (вызов метода CheckOpenLong
объекта торговых сигналов) и если условие входа выполнено, входит в рынок (вызов метода
OpenLong).
Реализация
//+------------------------------------------------------------------+
//| Check for long position open or limit/stop order set |
//| INPUT: no. |
//| OUTPUT: true-if trade operation processed, false otherwise. |
//| REMARK: no. |
//+------------------------------------------------------------------+
bool CExpert::CheckOpenLong()
{
double price,sl,tp;
datetime expiration=TimeCurrent();
//--- check signal for long enter operations
if(m_signal.CheckOpenLong(price,sl,tp,expiration))
{
if(!m_trade.SetOrderExpiration(expiration))
{
m_expiration=expiration;
}
return(OpenLong(price,sl,tp));
}
//--- return without operations
return(false);
}
Стандартная библиотека
© 2000-2011, MetaQuotes Software Corp.
2426
CheckOpenShort
Проверяет необходимость и возможность входа в рынок в короткую позицию.
virtual bool CheckOpenShort()
Возвращаемое значение
true - выполнена какая-либо торговая операция, иначе - false.
Примечание
Проверяется необходимость входа в рынок в короткую позицию (вызов метода CheckOpenShort
объекта торговых сигналов) и если условие входа выполнено, входит в рынок (вызов метода
OpenShort).
Реализация
//+------------------------------------------------------------------+
//| Check for short position open or limit/stop order set |
//| INPUT: no. |
//| OUTPUT: true-if trade operation processed, false otherwise. |
//| REMARK: no. |
//+------------------------------------------------------------------+
bool CExpert::CheckOpenShort()
{
double price,sl,tp;
datetime expiration=TimeCurrent();
//--- check signal for short enter operations
if(m_signal.CheckOpenShort(price,sl,tp,expiration))
{
if(!m_trade.SetOrderExpiration(expiration))
{
m_expiration=expiration;
}
return(OpenShort(price,sl,tp));
}
//--- return without operations
return(false);
}
Стандартная библиотека
© 2000-2011, MetaQuotes Software Corp.
2427
OpenLong
Выполняет операции для входа в рынок в длинную позицию.
virtual bool OpenLong(
double price, // цена
double sl, // Stop Loss
double tp // Take Profit
)
Параметры
price
[in] Цена входа в рынок.
sl
[in] Цена Stop Loss.
tp
[in] Цена Take Profit.
Возвращаемое значение
true - выполнена торговая операция, иначе - false.
Примечание
Определяет размер лота для входа (вызов метода LotOpenLong). Если лот не равен 0.0, входит
в рынок (вызов метода Buy объекта торговли).
Реализация
//+------------------------------------------------------------------+
//| Long position open or limit/stop order set |
//| INPUT: no. |
//| OUTPUT: true-if trade operation processed, false otherwise. |
//| REMARK: no. |
//+------------------------------------------------------------------+
bool CExpert::OpenLong(double price,double sl,double tp)
{
//--- get lot for open
double lot=LotOpenLong(price,sl);
//--- check lot for open
if(lot==0.0) return(false);
//---
return(m_trade.Buy(lot,price,sl,tp));
}
Стандартная библиотека
© 2000-2011, MetaQuotes Software Corp.
2428
OpenShort
Выполняет операции для входа в рынок в короткую позицию.
virtual bool OpenShort(
double price, // цена
double sl, // Stop Loss
double tp // Take Profit
)
Параметры
price
[in] Цена входа в рынок.
sl
[in] Цена Stop Loss.
tp
[in] Цена Take Profit.
Возвращаемое значение
true - выполнена торговая операция, иначе - false.
Примечание
Определяет размер лота для входа (вызов метода LotOpenShort). Если лот не равен 0.0, входит
в рынок (вызов метода Sell объекта торговли).
Реализация
//+------------------------------------------------------------------+
//| Short position open or limit/stop order set |
//| INPUT: no. |
//| OUTPUT: true-if trade operation successful, false otherwise. |
//| REMARK: no. |
//+------------------------------------------------------------------+
bool CExpert::OpenShort(double price,double sl,double tp)
{
//--- get lot for open
double lot=LotOpenShort(price,sl);
//--- check lot for open
if(lot==0.0) return(false);
//---
return(m_trade.Sell(lot,price,sl,tp));
}
Стандартная библиотека
© 2000-2011, MetaQuotes Software Corp.
2429
CheckClose
Проверяет необходимость выхода из рынка.
virtual bool CheckClose()
Возвращаемое значение
true - выполнена торговая операция, иначе - false.
Примечание
1. Проверяет необходимость выхода из рынка по программному Stop Out (вызов метода
CheckClose объекта управления капиталом). Если условие выполняется, закрываем позицию,
удаляем все ордеры (вызов метода CloseAll) и уходим.
2. Проверяет необходимость закрытия длинной или короткой позиции (вызов метода
CheckCloseLong или CheckCloseShort соответственно) и, если позиция закрыта, удаляет все
ордеры (вызов метода DeleteOrders).
Реализация
//+------------------------------------------------------------------+
//| Check for position close or limit/stop order delete |
//| INPUT: no. |
//| OUTPUT: true-if trade operation processed, false otherwise. |
//| REMARK: no. |
//+------------------------------------------------------------------+
bool CExpert::CheckClose()
{
double lot;
//--- position must be selected before call
if((lot=m_money.CheckClose(GetPointer(m_position)))!=0.0)
return(CloseAll(lot));
//--- check for position type
if(m_position.Type()==POSITION_TYPE_BUY)
{
//--- check the possibility of closing the long position / delete pending orders to buy
if(CheckCloseLong())
{
DeleteOrders();
return(true);
}
}
else
{
//--- check the possibility of closing the short position / delete pending orders to sell
if(CheckCloseShort())
{
DeleteOrders();
return(true);
Стандартная библиотека
© 2000-2011, MetaQuotes Software Corp.
2430
}
}
//--- return without operations
return(false);
}