Справочник по языку программирования MQL5

Подождите немного. Документ загружается.

Основы языка

Операции отношения

Логическое значение ЛОЖЬ представляется целым нулевым значением, а значение ИСТИНА

представляется любым ненулевым.

Значением выражений, содержащих операции отношения или логическиеоперации, являются

ЛОЖЬ(0) или ИСТИНА(1).

Истина, если a равно b a == b;

Истина, если a не равно b a != b;

Истина, если a меньше b a < b;

Истина, если a больше b a > b;

Истина, если a меньше или равно b a <= b;

Истина, если a больше или равно b a >= b;

Нельзя сравнивать два вещественных числа на равенство друг другу. В большинстве случаев два

вроде бы одинаковых числа могут оказаться неравными из-за разницы значения в 15-ом знаке

после запятой. Для корректного сравнения двух вещественных чисел необходимо сравнивать

нормализованную разницу этих чисел с нулевым значением.

Пример:

bool CompareDoubles(double number1,double number2)

{

if(NormalizeDouble(number1-number2,8)==0) return(true);

else return(false);

}

void OnStart()

{

double first=0.3;

double second=3.0;

double third=second-2.7;

if(first!=third)

{

if(CompareDoubles(first,third))

printf("%.16f %.16f все таки равны",first,third);

}

// Результат: 0.3000000000000000 0.2999999999999998 все таки равны

Смотри также

Приоритеты и порядок операций

Основы языка

Логические операции

Логическое отрицание НЕ(!)

Операнд операции логического отрицания НЕ(!) должен иметь арифметический тип. Результат

равен ИСТИНА(1), если значение операнда есть ЛОЖЬ(0), и равен ЛОЖЬ(0), если операнд не

равен ЛОЖЬ(0).

if(!a) Print("не 'a'");

Логическая операция ИЛИ (||)

Логическая операция ИЛИ (||) значений x и y. Значением выражения является ИСТИНА(1), если

истинно (не нуль) значение x или y. В противном случае - ЛОЖЬ(0).

if(x<0 || x>=max_bars) Print("out of range");

Логическая операция И (&&)

Логическая операция И (&&) значений x и y. Значением выражения является ИСТИНА(1), если

значения x и y истинны (не нуль). В противном случае - ЛОЖЬ(0).

Короткая оценка логических операций

К логическим выражениям применяется схема так называемой "короткой оценки", то есть,

вычисление выражения прекращается в тот момент, когда можно точно оценить результат

выражения.

//+------------------------------------------------------------------+

//| Script program start function |

//+------------------------------------------------------------------+

void OnStart()

{

//--- первый пример короткой оценки

if(func_false() && func_true())

{

Print("Операция &&: Это сообщение вы никогда не увидите");

}

else

{

Print("Операция &&: Результат первого выражения false, поэтому второе выражение не вычислялось");

}

//--- второй пример короткой оценки

if(!func_false() || !func_true())

{

Print("Операция ||: Результат первого выражения true, поэтому второе выражение не вычислялось");

}

else

Основы языка

{

Print("Операция ||: Это сообщение вы никогда не увидите");

}

//+------------------------------------------------------------------+

//| функция всегда возвращает false |

//+------------------------------------------------------------------+

bool func_false()

{

Print("Функция func_false()");

return(false);

}

//+------------------------------------------------------------------+

//| функция всегда возвращает true |

//+------------------------------------------------------------------+

bool func_true()

{

Print("Функция func_true()");

return(true);

}

Смотри также

Приоритеты и порядок операций

Основы языка

Побитовые операции

Дополнение до единицы

Дополнение до единицы значения переменной. Значение выражения содержит 1 во всех

разрядах, в которых значение переменной содержит 0, и 0 во всех разрядах, в которых значения

переменной содержит 1.

b = ~n;

Пример:

char a='a',b;

b=~a;

Print("a = ",a, " b = ",b);

// Результат будет такой:

// a= 97 b= -98

Сдвиг вправо

Двоичное представление x сдвигается вправо на y разрядов. Если сдвигаемое значение имеет

беззнаковый тип, то осуществляется логический сдвиг вправо, то есть, освобождающиеся слева

разряды будут заполняться нулями.

Если же сдвигаемое значение имеет знаковый тип, то осуществляется арифметический сдвиг

вправо, то есть освобождающиеся слева разряды будут заполняться значением знакового бита

(если число положительное, то значение знакового бита равно 0, если число отрицательное, то

значение знакового бита равно 1)

x = x >> y;

Пример:

char a='a',b='b';

Print("Before: a = ",a, " b = ",b);

//--- произведем сдвиг вправо

b=a>>1;

Print("After: a = ",a, " b = ",b);

// Результат будет такой:

// Before: a = 97 b = 98

// After: a = 97 b = 48

Сдвиг влево

Двоичное представление x сдвигается влево на y разрядов; освобождающиеся справа разряды

заполняются нулями.

x = x << y;

Пример:

Основы языка

char a='a',b='b';

Print("Before: a = ",a, " b = ",b);

//--- произведем сдвиг влево

b=a<<1;

Print("After: a = ",a, " b = ",b);

// Результат будет такой:

// Before: a = 97 b = 98

// After: a = 97 b = -62

Не рекомендуется производить сдвиг на большее или равное число битов, чем разрядность

сдвигаемой переменной, так как результат такой операции не определен.

Побитовая операция И

Побитовая операция И двоичных представлений x и y. Значение выражения содержит 1 (ИСТИНА)

во всех разрядах, в которых и x, и y содержат не ноль; и 0 (ЛОЖЬ) во всех остальных разрядах.

b = ((x & y) != 0);

Пример:

char a='a',b='b';

//--- операция И

char c=a&b;

Print("a = ",a," b = ",b);

Print("a & b = ",c);

// Результат будет такой:

// a = 97 b = 98

// a & b = 96

Побитовая операция ИЛИ

Побитовая операция ИЛИ двоичных представлений x и y. Значение выражения содержит 1 во всех

разрядах, в которых x или y не содержит 0, и 0 - во всех остальных разрядах.

b = x | y;

Пример:

char a='a',b='b';

//--- операция ИЛИ

char c=a|b;

Print("a = ",a," b = ",b);

Print("a | b = ",c);

// Результат будет такой:

// a = 97 b = 98

// a | b = 99

Побитовая операция исключающее ИЛИ

Побитовая операция исключающее ИЛИ (eXclusive OR) двоичных представлений x и y. Значение

выражения содержит 1 в тех разрядах, в которых x и y имеют разные двоичные значения, и 0 - во

всех остальных разрядах.

Основы языка

b = x ^ y;

Пример:

char a='a', b='b';

//--- операция исключающее ИЛИ

char c=a^b;

Print("a = ",a," b = ",b);

Print("a ^ b = ",c);

// Результат будет такой:

// a = 97 b = 98

// a ^ b = 99

Побитовые операции выполняются только с целымичислами.

Смотри также

Приоритеты и порядок операций

Основы языка

Другие операции

Индексирование ( [] )

При обращении к i-му элементу массива значением выражения является значение переменной с

порядковым номером i.

Пример:

array[i] = 3; // Присвоить значение 3 i-му элементу массива array.

Индексом массива может быть только целое число. Допускаются не более чем четырехмерные

массивы. Индексация каждого измерения производится от 0 до размер измерения-1. В частном

случае одномерного массива из 50 элементов обращение к первому элементу будет выглядеть как

array[0], к последнему элементу - array[49].

При доступе за пределы массива исполняющая подсистема сгенерирует критическую ошибку, и

выполнение программы будет остановлено.

Вызов функции с аргументами x1, x2,..., xn

Каждый аргумент может представлять собой константу, переменную или выражение

соответствующего типа. Передаваемые аргументы разделяются запятыми и должны находиться

внутри круглых скобок, открывающая круглая скобка должна следовать за именем вызываемой

функции.

Значением выражения является значение, возвращаемое функцией. Если тип возвращаемого

значения функции есть void, то вызов такой функции нельзя помещать справа в операции

присвоения. Обратите внимание, что порядок выполнения выражений x1,..., xn гарантируется.

Пример:

int length=1000000;

string a="a",b="b",c;

//---

int start=GetTickCount(),stop;

long i;

for(i=0;i<length;i++)

{

c=a+b;

}

stop=GetTickCount();

Print("time for 'c = a + b' = ",(stop-start)," milliseconds, i = ",i);

Операция запятая ( , )

Выражения, разделенные запятыми, вычисляются слева направо. Все побочные эффекты

вычисления левого выражения могут возникать до вычисления правого выражения. Тип и

значение результата совпадают с типом и значением правого выражения. В качестве примера

можно рассматривать список передаваемых параметров (см.выше).

Основы языка

Пример:

for(i=0,j=99; i<100; i++,j--) Print(array[i][j]);

Операция точка ( . )

Для прямого доступакпубличнымчленам структур и классов используется операция точка.

Синтаксис

Имя_переменной_типа_структуры.Имя_члена

Пример:

struct SessionTime

{

string sessionName;

int startHour;

int startMinutes;

int endHour;

int endMinutes;

} st;

st.sessionName="Asian";

st.startHour=0;

st.startMinutes=0;

st.endHour=9;

st.endMinutes=0;

Операция разрешения контекста ( :: )

Каждая функция в mql5-программе имеет свой контекст исполнения. Например, системная

функция Print() выполняется в глобальном контексте. Импортируемые функции вызываются в

контексте соответствующего импорта. Функции-методы классов имеют контекст соответствующего

класса. Синтаксис операции разрешения контекста:

[Имя_контекста]::Имя_функции(параметры)

Если имя контекста отсутствует, то это явное указание на использование глобального контекста. В

случае отсутствия операции разрешения контекста, функция ищется в ближайшем контексте. В

случае отсутствия функции в локальном контексте, поиск производится в глобальном контексте.

Также операция разрешения контекста используется для определенияфункции-члена класса.

тип Имя_класса::Имя_функции(описание_параметров)

{

// тело функции

}

Пример:

Основы языка

#property script_show_inputs

#import"kernel32.dll"

int GetLastError(void);

#import

class CCheckContext

{

int m_id;

public:

CCheckContext() { m_id=1234; }

protected:

int GetLastError() { return(m_id); }

};

class CCheckContext2 : public CCheckContext

{

int m_id2;

public:

CCheckContext2() { m_id2=5678; }

void Print();

protected:

int GetLastError() { return(m_id2); }

};

void CCheckContext2::Print()

{

::Print("Terminal GetLastError",::GetLastError());

::Print("kernel32 GetLastError",kernel32::GetLastError());

::Print("parent GetLastError",CCheckContext::GetLastError());

::Print("our GetLastError",GetLastError());

}

//+------------------------------------------------------------------+

//| Script program start function |

//+------------------------------------------------------------------+

void OnStart()

{

//---

CCheckContext2 test;

test.Print();

}

//+------------------------------------------------------------------+

Операция взятия размера типа данных или размера объекта

любого типа данных ( sizeof )

С помощью операции sizeof можно определить размер памяти которая соответствует

идентификатору или типу. Операция sizeof имеет следующий формат:

Пример:

sizeof(выражение)

В качестве выражения может быть использован любой идентификатор, либо имя типа,

заключенное в скобки. Отметим, что не может быть использовано имя типа void, а

идентификатор не может относится к полю битов или быть именем функции.

Если в качестве выражения указано имя статического массива (то есть, задана первая

размерность), то результатом является размер всего массива (т.е. произведение числа элементов

Основы языка

100

на длину типа). Если в качестве выражения указано имя динамического массива (первая

размерность не задана), то результатом будет размер объекта динамическогомассива.

Когда sizeof применяются к имени типа структуры или класса или к идентификатору имеющему

тип структуры или класса, то результатом является фактический размер структуры или класса.

Пример:

struct myStruct

{

char h;

int b;

double f;

} str;

Print("sizeof(str) =",sizeof(str));

Print("sizeof(myStruct) =",sizeof(myStruct));

Вычисления размера происходит на этапе компиляции.

Смотри также

Приоритеты и порядок операций