S7-SCL V5.1 для S7-300/S7-400. Руководство

Подождите немного. Документ загружается.

Разработка SCL программ

S7-SCL V5.1 для S7-300/S7-400

A5E00059543-01

2-15

2.10.2 Раздел деклараций функционального блока вычисления

Структура раздела деклараций

Раздел деклараций этого блока состоит из следующих подразделов:

•

Константы: между CONST и END_CONST.

•

Параметры ввода/вывода между VAR_IN_OUT и END_VAR.

•

Параметры вывода: между VAR_OUTPUT и END_VAR.

•

Временные переменные: между VAR_TEMP и END_VAR.

CONST

LIMIT := 7;

END_CONST

VAR_IN_OUT

sortbuffer : ARRAY[0..LIMIT] OF INT;

END_VAR

VAR_OUTPUT

calcbuffer : ARRAY[0..LIMIT] OF

STRUCT

squareroot : INT;

square : INT;

END_STRUCT;

END_VAR

VAR_TEMP

swap : BOOL;

index, aux : INT;

valr, resultr: REAL ;

END_VAR

Разработка SCL программ

S7-SCL V5.1 для S7-300/S7-400

2-16

A5E00059543-01

2.10.3 Раздел операторов функционального блока вычисления

Последовательность программы

Параметр ввода/вывода “sortbuffer" (буфер сортировки) связывается с

кольцевым буфером “measvals" так, что оригинальное содержание буфера

переписывается, сортируя измеряемые ве личины.

Новый массив “calcbuffer" (буфер вычисления) создается как выходной

параметр с вычисленными результатами. Структура этих элементов такова,

что они содержат квадратный корень и квадрат каждой измеряемой

величины.

На схеме ниже показаны связи между массивами.

EVALUATION

measured values

sort buffer

calculate buffer

Этот интерфейс показывает суть обмена данных для обработки измеренных

величин. В этом случае, данные загружены в блок данны х ACQUIRE_DATA,

поскольку локальный пример для функционального блока EVALUTION

создается в результате вызова блока ACQUIRE.

Раздел операторов блока EVALUATION

Во-первых, измеряемые величины в кольцевом блоке сортируются и затем

вычисляются.

•

Алгоритм сортировки

Для сортировки в буфере используется метод постоянного обмена

величин. Это значит, что величины последовательно сравниваются и

перемещаются, пока не пол учен конечный результат. Используемый

буфер является параметром ввода/выво да "sortbuffer" (буфер

сортировки).

•

Начало вычислений

Как только сортировка завершена, выполняется цикл, в котором

применяются функции SQUARE для возведения в квадрат и SQRT для

извлечения квадратного корня. Эти результаты хранятся в структурном

массиве "calcbuffer" (буфер вычисления).

Разработка SCL программ

S7-SCL V5.1 для S7-300/S7-400

A5E00059543-01

2-17

Раздел операторов блока вычисления

Этот раздел состоит из следующих логических блоков:

BEGIN

(********************************************************

Часть 1 Сортировка : Применяется мет од "пузырьковой сортировки": Замена пар

переменных пока измеряемые величины можно сортировать.

**********************************************************)

REPEAT

swap := FALSE;

FOR index := LIMIT TO 1 BY -1 DO

IF sortbuffer[index-1] > sortbuffer[index]

THEN aux :=sortbuffer[index];

sortbuffer[index] := sortbuffer[index-1];

sortbuffer[index-1] := aux;

swap := TRUE;

END_IF;

END_FOR;

UNTIL NOT swap

END_REPEAT;

(**********************************************************

Часть 2 В ычисление : Квадратный корень по стандартной функции SQRT и квадрат

по функции SQUARE.

************************************************************)

FOR index := 0 TO LIMIT BY 1 DO

valr := INT_TO_REAL(sortbuffer[index]);

resultr := SQRT(valr);

calcbuffer[index].squareroot := REAL_TO_INT(resultr);

calcbuffer[index].square := SQUARE(sortbuffer[index]);

END_FOR;

END_FUNCTION_BLOCK

Разработка SCL программ

S7-SCL V5.1 для S7-300/S7-400

2-18

A5E00059543-01

2.11 Создание функционального блока ACQUIRE

2.11.1 Диаграмма блока ACQUIRE

Следующая схема показывает алгоритм в форме диаграммы:

Начало

End

newval

да

нет

TRUE

FALSE

new code

resort

Выбор

функции?

изменена?

RECORD

Function Block

Копирование измеряемой вели -

чины в циклический буфер,

пересчет индекса

Циклический буфер

реализован с

использованием операции

MOD: когда достигается

предел, все начинается

сначала

Сортировка цикличес -

кого буфера и выпол-

нение вычислений

(заполнение массива

результатов)

Загрузка из

экземплярного DB

Сначала соответствующие

правые биты опрашиваются с

помощью операции AND

Загрузка:

Запись указывает пункты с

выходными адресами в

выходных параметрах так,

что их величины могут быть

впоследствии отображены.

Копирование выч исленных

результатов в массив

результатов

Анализ кода и вычисление

выходного адреса

Загрузка квадратного корня

Загрузка квадрата

Загрузка измеренной величины

ANALYZE

Разработка SCL программ

S7-SCL V5.1 для S7-300/S7-400

A5E00059543-01

2-19

2.11.2 Раздел операторов функционального блока ACQUIRE

Структура раздела

Структура раздела состоит из следующих подразделов:

•

Константы: между CONST и END_CONST.

•

Параметры ввода: между VAR_INPUT и END_VAR.

•

Параметры вывода: между VAR_OUTPUT и END_VAR.

•

Статические переменные: межд у VAR и END_VAR. Они также

включены в описание локального примера для блока Вычисления

CONST

LIMIT := 7;

QUANTITY := LIMIT + 1;

END_CONST

VAR_INPUT

measval_in : INT ; // Новая измеренная величина

newval : BOOL; // Измеренная величина в циклическом буфере

// "measvals"

resort : BOOL; // Сортировка измеренных величин

funct_sel : BOOL; // Выбор вычисленного результата

// корень/квадрат

newsel : BOOL; // Введенный выходной адрес

selection : WORD; // Адрес выхода

END_VAR

VAR_OUTPUT

result_out : INT; // вычисленная величина

measval_out : INT; // соответствующая измеренная

// величина

END_VAR

VAR

measvals : ARRAY[0..LIMIT] OF INT := 8(0);

resultbuffer : ARRAY[0..LIMIT] OF

STRUCT

squareroot : INT;

square : INT;

END_STRUCT;

pointer : INT := 0;

oldval : BOOL := TRUE;

oldsort : BOOL := TRUE;

oldsel : BOOL := TRUE;

address : INT := 0;//Преобразование адреса выхода

outvalues_instance: EVALUATE;//Определение локального

//экземпляра

END_VAR

Разработка SCL программ

S7-SCL V5.1 для S7-300/S7-400

2-20

A5E00059543-01

Статические пере менные

Такой тип функционального блока выбран потому, что некоторые данные

должны сохраняться от одного программного цикла к другому. Это

статические переменные, описанные в подразделе “VAR, END_VAR".

Статические переменные это локальные переменные, величины которых

сохраняются во время обработки каждого блока. Они ис пользуются для

хранения ве личин в функциональном блоке и, например, в блоке данны х.

Инициализация переменных

Имейте ввиду, что инициализация переменных проводится, когда

инициализирован блок (после загрузки на CPU). Локальный экземпляр для

блока EVALUATION также описан в подразделе“VAR, END_VAR".

Впоследствии это наименование используется для вызова и доступа

параметров вывода. Для хранения данных испо льзуется глоба льный

экземпляр ACQUIRE_DATA.

Наименова-

ние

Тип данных

Инициализа-

ция

переменных

Описание

Measvals ARRAY [..]

OF INT

8(0) Кольцевой буфер для измеряемых

величин

Resultbuffer ARRAY [..]

OF STRUCT

- Массив для структуры с

компонентами квадрат и квадрат ный

корень целого типа

Index INT 0 Индекс для кольцевого буфера,

опознающего позицию дл я

следующей измеренной величины

Oldval BOOL FALSE Предыдущая величина для чтения

измеряемой величины "newval"

Oldsort BOOL FALSE Предыдущая величина для

сортировки резул ьтатов "resort"

Oldsel BOOL FALSE Предыдущая величина для чтения

кода "newsel"

Address INT 0 Адрес для вывода измеряемой

величины или резул ьтата

eval_instance Local instance - Локальный пример для блока

EVALUTION

Разработка SCL программ

S7-SCL V5.1 для S7-300/S7-400

A5E00059543-01

2-21

2.11.3 Раздел операторов функционального блока ACQUIRE

Структура раздела

Операторы данного раздела делятся на три части:

•

Обработка измеряемых величин

Если параметр ввода "newval" отличается от "oldval", новая измеряемая

величина читается в ко льцевом буфере.

•

Начало сортировки и вычисления

Сортировка и вычисление начинаются при вызове функционального

блока Вычисления, когда параметр ввода "resort" меняется по сравнению

с "oldsort".

•

Вычисление кодирования и подготовка данных вывода

Кодирование читается слово за словом. Согласно условным

обозначениям SIMATIC, это значит, что верхняя группа переключателей

(байта 0) содержит более высокий порядок восемь битов слова ввода и

низкую группу переключателей (байта 1) с более низким порядком битов.

Схема, расположенная ниже, показывает размещение кодовых

переключателей.

Разработка SCL программ

S7-SCL V5.1 для S7-300/S7-400

2-22

A5E00059543-01

Вычисление адресов

На схеме, расположенной ниже, показано, как вычисляются адреса: биты с 12

по 14 слова ввода IW0 содержат код, который читается, когда на

переключателе кодов обнаруживается фронт сигнала (бит 15). Адрес

получается при сдвиге вправо, используя стандартную функцию SHR и

скрывая важные биты AND.

Этот адрес используется для написания массива элементов параметров

вывода (вычисленные результаты и соответствующие измеряемые

величины). Независимо от того, квадрат ли это или квадратный корень, вывод

зависит от “funct_sel".

Фронт сигнала переключателя кодирования обнаруживается, когда “Newsel"

отличается от “oldsel".

Switches

for code

number

Coding

switch

Перек лючатели

на модуле

Слово в

памяти

После SHR

на 12 бит

После м аски

AND c 0007

адрес

Байт 0

Байт 1

IW0

Разработка SCL программ

S7-SCL V5.1 для S7-300/S7-400

A5E00059543-01

2-23

Раздел операторов

Этот раздел состоит из следующих логических блоков:

BEGIN

(***********************************************************

Часть 1 : Получение измеренных величин. Если переменная

"newval" изменена, вводится измеренная величина. Операция MOD

используется для реализации кольцевого буфера измеренных

величин.

**********************************************)

IF newval <> oldval THEN

pointer := pointer MOD QUANTITY;

measvals[pointer] := measval_in;

pointer := pointer + 1;

END_IF;

oldval := newval;

(************************************************************

Часть 2 : Начало сортировки и вычислений

Если изменена переменная "resort", начинается сортировка

кольцевого буфера и выполнение вычислений с результатами

измерений. Результаты хранятся в новом массиве "calcbuffer".

************************************************************)

IF resort <> oldsort THEN

pointer := 0; //Сброс указателя кольцевого буфера

eval_instance(sortbuffer := measvals); //Вызов EVALUATE

END_IF;

oldsort := resort;

resultbuffer := eval_instance.calcbuffer;//Квадрат и

//квадратный корень

(************************************************************

Часть 3 : Анализ кодов и подготовка вывода: Если переменная

"newsel" изменилась, код для адресации элемента массива для

вывода переопределяется: Соответствующие биты переменной

"selection" выделяются маской и преобразуются в целое. Выход

выбирается в зависимости от установки ключей "funct_sel" и

"squareroot"/"square".

************************************************************)

IF newsel <> oldsel THEN

address := WORD_TO_INT(SHR(IN := selection, N := 12) AND 16#0007);

END_IF;

oldsel := newsel;

IF funct_sel THEN

result_out := resultbuffer[address].square;

ELSE

result_out := resultbuffer[address].squareroot;

END_IF;

measval_out := measvals[address];//Вывод измеренной величины

END_FUNCTION_BLOCK

Разработка SCL программ

S7-SCL V5.1 для S7-300/S7-400

2-24

A5E00059543-01

2.12 Создание циклического орга низационного блока

Задачи циклического OB

OB1 выбирается, так как он вызывается циклически. Он выпол няет

следующие зада чи в программе:

•

Вызывает и поставляет блоку ACQUIRE данные ввода и данные

управления.

•

Читает данные, которые возвращает блок ACQUIRE.

•

Выводит величины на дисплей

В начале раздела деклараций расположен массив из 20 байт временных

данных “systemdata".